git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.9.17)
  22 ANDROID_VERSION=37
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2023-08-30
  28 AC_SUBST(RELEASE_DATE)
  29
  30 DOC_DATE=`LC_ALL=C date -d $RELEASE_DATE +'%d %b %Y'`
  31
  32 AC_SUBST(DOC_DATE)
  33
  34 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  35 AC_SUBST(VERSION_DASH)
  36 AC_SUBST(ANDROID_VERSION)
  37
  38 dnl ==========================================================================
  39 dnl Java library versions
  40
  41 ALTOSUILIB_VERSION=14
  42 ALTOSLIB_VERSION=14
  43
  44 AC_SUBST(ALTOSLIB_VERSION)
  45 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  46 AC_SUBST(ALTOSUILIB_VERSION)
  47 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  48
  49 dnl ==========================================================================
  50
  51 AM_CONFIG_HEADER(config.h)
  52
  53 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  54         [Set freetts class path (default /usr/share/java)]),
  55         [FREETTS=$withval], [FREETTS=/usr/share/java])
  56
  57 AC_SUBST(FREETTS)
  58
  59 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  60         [Set jfreechart class path (default /usr/share/java)]),
  61         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  62
  63 AC_SUBST(JFREECHART)
  64
  65 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  66         [Set jcommon class path (default /usr/share/java)]),
  67         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  68
  69 AC_SUBST(JCOMMON)
  70
  71 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm=PATH],
  72         [Set jvm path for java builds (default searches in /usr/lib/jvm)]),
  73         [JVM=$withval], [JVM=auto])
  74
  75 if test "x$JVM" = "xauto"; then
  76         AC_MSG_CHECKING([JVM])
  77         for jvm in default-java java-6-openjdk java-7-openjdk java-8-openjdk java-9-openjdk java-10-openjdk java-11-openjdk java-12-openjdk java-13-openjdk java-6-sun java-8-openjdk-amd64; do
  78                 if test "x$JVM" = "xauto"; then
  79                         INCLUDE="/usr/lib/jvm/$jvm/include"
  80                         if test -f "$INCLUDE"/jni.h; then
  81                                 JVM=/usr/lib/jvm/"$jvm"
  82                         fi
  83                 fi
  84         done
  85         if test "x$JVM" = "xauto"; then
  86                 AC_MSG_ERROR([no JVM files found])
  87         fi
  88         AC_MSG_RESULT([$JVM])
  89 fi
  90
  91 AC_ARG_WITH(java-version, AS_HELP_STRING([--with-java-version=7],
  92                                          [Set java language compatibility version (default is 7)]),
  93            [JAVA_VERSION=$withval], [JAVA_VERSION=7])
  94
  95 JAVAC="$JVM"/bin/javac
  96 JAVA="$JVM"/bin/java
  97 JVM_INCLUDE="$JVM"/include
  98 JAVAC_VERSION_FLAGS="-target 1.$JAVA_VERSION -source 1.$JAVA_VERSION"
  99
 100 AC_SUBST(JAVAC)
 101 AC_SUBST(JAVA)
 102 AC_SUBST(JVM)
 103 AC_SUBST(JVM_INCLUDE)
 104 AC_SUBST(JAVAC_VERSION_FLAGS)
 105
 106
 107 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
 108         [Set android SDK path (default searches in a variety of places)]),
 109         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
 110
 111 if test "x$ANDROID_SDK" = "xauto"; then
 112         AC_MSG_CHECKING([Android SDK])
 113         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
 114                 if test "x$ANDROID_SDK" = "xauto"; then
 115                         SDK="$sdk"
 116                         if test -f "$SDK/SDK Readme.txt"; then
 117                                 ANDROID_SDK=`readlink -m "$SDK"`
 118                         fi
 119                 fi
 120         done
 121         if test "x$ANDROID_SDK" = "xauto"; then
 122                 AC_MSG_NOTICE([no Android SDK found])
 123                 ANDROID_SDK=no
 124         fi
 125         AC_MSG_RESULT([$ANDROID_SDK])
 126 fi
 127 if test "x$ANDROID_SDK" != "xno"; then
 128         AC_MSG_CHECKING([Android SDK version])
 129         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 130         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 131         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 132                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 133                 ANDROID_SDK=no
 134         else
 135                 AC_MSG_RESULT([$SDK_VERSION])
 136         fi
 137 fi
 138 if test "x$ANDROID_SDK" != "xno"; then
 139         AC_MSG_CHECKING([Android SDK API Level])
 140         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 141                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 142                 if test "$API_LEVEL" = "10"; then
 143                         AC_MSG_RESULT([$API_LEVEL])
 144                 else
 145                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 146                         ANDROID_SDK=no
 147                 fi
 148         else
 149                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 150                 ANDROID_SDK=no
 151         fi
 152 fi
 153 if test "x$ANDROID_SDK" != "xno"; then
 154         AC_MSG_CHECKING([Android SDK required extras])
 155         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 156                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 157                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 158                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 159                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 160                 else
 161                         AC_MSG_NOTICE([Google Play Services library not installed.])
 162                         ANDROID_SDK=no
 163                 fi
 164         else
 165                 AC_MSG_NOTICE([Android Support Library not installed.])
 166                 ANDROID_SDK=no
 167         fi
 168 fi
 169
 170 ANDROID_RELEASE=no
 171 if test "x$ANDROID_SDK" != "xno"; then
 172         HAVE_ANDROID_SDK="yes"
 173         ANDROID_RELEASE=yes
 174 else
 175         HAVE_ANDROID_SDK="no"
 176 fi
 177
 178 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 179 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 180
 181 AC_SUBST(ANDROID_SDK)
 182
 183 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 184             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 185             [FATDIR=$withval], [FATDIR=none])
 186
 187 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 188
 189 AC_SUBST(FATDIR)
 190
 191 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 192             [Set the file to read the AltosDroid maps API key from (defaults to ~/altusmetrumllc/google-altosdroid-maps-api-key)]),
 193             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-altosdroid-maps-api-key])
 194
 195 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 196         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 197         HAVE_GOOGLE_KEY="yes"
 198 else
 199         GOOGLEKEY='null'
 200         HAVE_GOOGLE_KEY="no"
 201 fi
 202
 203 AC_ARG_WITH(windows-key, AS_HELP_STRING([--with-windows-key=PATH],
 204             [Set the file containing the Windows installer signing key (defaults to ~/altusmetrumllc/ssl.com/altus_metrum,_llc.p12)]),
 205             [WINDOWSKEYFILE="$withval"], [WINDOWSKEYFILE=$HOME/altusmetrumllc/ssl.com/altus_metrum,_llc.p12])
 206
 207 AC_ARG_WITH(windows-key-pass, AS_HELP_STRING([--with-windows-key-pass=PATH],
 208             [Set the file containing the Windows installer signing key password (defaults to ~/altusmetrumllc/ssl.com/password)]),
 209             [WINDOWSKEYPASSFILE="$withval"], [WINDOWSKEYPASSFILE=$HOME/altusmetrumllc/ssl.com/password])
 210
 211 AC_CHECK_PROG(jsign, jsign, "yes", "no")
 212
 213 if test -s "$WINDOWSKEYFILE" -a -s "$WINDOWSKEYPASSFILE" -a "$jsign" = yes; then
 214         HAVE_WINDOWS_KEY="yes"
 215 else
 216         HAVE_WINDOWS_KEY="no"
 217 fi
 218
 219 WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
 220 AC_SUBST(WARN_CFLAGS)
 221
 222 AC_ARG_ENABLE(faketime, AS_HELP_STRING([--enable-faketime],
 223               [Use faketime program to ensure pdf files are reproducible (default=no)]),
 224               [FAKETIME=$enableval], [FAKETIME=no])
 225
 226 AM_CONDITIONAL(FAKETIME, [test x$FAKETIME = xyes])
 227
 228 AC_SUBST(GOOGLEKEY)
 229 AC_SUBST(WINDOWSKEYFILE)
 230 AC_SUBST(WINDOWSKEYPASSFILE)
 231 AC_SUBST(HAVE_WINDOWS_KEY)
 232
 233 AC_PROG_CC
 234 AC_PROG_INSTALL
 235 AC_PROG_LN_S
 236 AC_PROG_LIBTOOL
 237 PKG_PROG_PKG_CONFIG
 238
 239 WARN_CFLAGS=""
 240 if test "x$GCC" = "xyes"; then
 241         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 242         -Wmissing-prototypes -Wmissing-declarations \
 243         -Wnested-externs -fno-strict-aliasing"
 244         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 245         [Can use #warning in C files])
 246 fi
 247 AC_SUBST(WARN_CFLAGS)
 248
 249 #
 250 # Configure ARM compiler for STM32L and LPC11U14
 251 #
 252
 253 AC_ARG_WITH([arm-cc],
 254             [AS_HELP_STRING([--with-arm-cc],
 255                             [Name of ARM C compiler])],
 256             [],
 257             [with_arm_cc=auto])
 258
 259 if test "x$with_arm_cc" != "xno"; then
 260         if test "x$with_arm_cc" = "xauto"; then
 261                 with_arm_cc="arm-none-eabi-gcc"
 262                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 263         else
 264                 HAVE_ARM_CC=yes
 265         fi
 266 else
 267         HAVE_ARM_CC=no
 268 fi
 269
 270 if test "x$HAVE_ARM_CC" = "xno"; then
 271         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 272 else
 273         ARM_CC=$with_arm_cc
 274 fi
 275 AC_SUBST(HAVE_ARM_CC)
 276 AC_SUBST(ARM_CC)
 277
 278 if test "x$HAVE_ARM_CC" = "xyes"; then
 279         save_CC="$CC"
 280         save_CFLAGS="$CFLAGS"
 281         save_LIBS="$LIBS"
 282         CC="$ARM_CC"
 283         CFLAGS="-mthumb -mcpu=cortex-m0"
 284         LIBS="--specs=picolibc.specs"
 285         AC_LANG_PUSH([C])
 286
 287         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 288         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 289                           [HAVE_ARM_M0_CC=yes],
 290                           [HAVE_ARM_M0_CC=no])
 291         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 292
 293         CFLAGS="-mthumb -mcpu=cortex-m3"
 294         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 295         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 296                           [HAVE_ARM_M3_CC=yes],
 297                           [HAVE_ARM_M3_CC=no])
 298         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 299
 300         AC_LANG_POP([C])
 301         LIBS="$save_LIBS"
 302         CFLAGS="$save_CFLAGS"
 303         CC="$save_CC"
 304 else
 305         HAVE_ARM_M3_CC=no
 306         HAVE_ARM_M0_CC=no
 307 fi
 308 AC_SUBST(HAVE_ARM_M3_CC)
 309 AC_SUBST(HAVE_ARM_M0_CC)
 310
 311 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 312         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 313 fi
 314
 315 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 316         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 and STM32F0 binaries will not be built])
 317 fi
 318
 319
 320
 321 #
 322 # Configure AVR compiler
 323 #
 324
 325 AC_ARG_WITH([avr-cc],
 326             [AS_HELP_STRING([--with-avr-cc],
 327                             [Name of AVR C compiler])],
 328             [],
 329             [with_avr_cc=auto])
 330
 331 if test "x$with_avr_cc" != "xno"; then
 332         if test "x$with_avr_cc" = "xauto"; then
 333                 with_avr_cc="avr-gcc"
 334                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 335         else
 336                 HAVE_AVR_CC=yes
 337         fi
 338 else
 339         HAVE_AVR_CC=no
 340 fi
 341
 342 AC_ARG_WITH([avr-objcopy],
 343             [AS_HELP_STRING([--with-avr-objcopy],
 344                             [Name of AVR objcopy])],
 345             [],
 346             [with_avr_objcopy=auto])
 347
 348 if test "x$with_avr_objcopy" != "xno"; then
 349         if test "x$with_avr_objcopy" = "xauto"; then
 350                 with_avr_objcopy="avr-objcopy"
 351                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 352         else
 353                 HAVE_AVR_OBJCOPY=yes
 354         fi
 355 else
 356         HAVE_AVR_OBJCOPY=no
 357 fi
 358
 359 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 360         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 361         HAVE_AVR_CC=no
 362 else
 363         save_CC="$CC"
 364         save_CFLAGS="$CFLAGS"
 365         save_LIBS="$LIBS"
 366
 367         CC="$with_avr_cc"
 368         CFLAGS="-mmcu=attiny85"
 369         AC_LANG_PUSH([C])
 370         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 371         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 372                           [AVR_LINK=yes],
 373                           [AVR_LINK=no])
 374         AC_MSG_RESULT([$AVR_LINK])
 375         AC_LANG_POP([C])
 376
 377         LIBS="$save_LIBS"
 378         CFLAGS="$save_CFLAGS"
 379         CC="$save_CC"
 380
 381         if test "x$AVR_LINK" = xyes; then
 382                 AVR_CC=$with_avr_cc
 383                 AVR_OBJCOPY=$with_avr_objcopy
 384         else
 385                 HAVE_AVR_CC=no;
 386         fi
 387 fi
 388
 389 AC_SUBST(AVR_CC)
 390 AC_SUBST(AVR_OBJCOPY)
 391 AC_SUBST(HAVE_AVR_CC)
 392
 393 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 394 if test "x$HAVE_NICKLE" = "xno"; then
 395         AC_MSG_ERROR([Please install nickle to build AltOs])
 396 fi
 397
 398 AC_CHECK_PROG([HAVE_ASCIIDOCTOR_PDF], [asciidoctor-pdf], yes, no)
 399 if test "x$HAVE_ASCIIDOCTOR_PDF" = "xno"; then
 400         AC_MSG_WARN([asciidoctor-pdf not found, PDF docs will not be built])
 401 fi
 402 AM_CONDITIONAL([ASCIIDOCTOR_PDF], [test x$HAVE_ASCIIDOCTOR_PDF != xno])
 403
 404 AC_ARG_WITH([strip-nondeterminism],
 405             [AS_HELP_STRING([--with-strip-nondeterminism],
 406                             [Name of non-deterministic build data stripping tool])],
 407             [],
 408             [with_strip_nondeterminism=auto])
 409
 410 if test "x$with_strip_nondeterminism" != "xno"; then
 411         if test "x$with_strip_nondeterminism" = "xauto"; then
 412                 with_strip_nondeterminism="strip-nondeterminism"
 413                 AC_CHECK_PROG([HAVE_STRIP_NONDETERMINISM],[$with_strip_nondeterminism], yes, no)
 414         else
 415                 HAVE_STRIP_NONDETERMINISM=yes
 416         fi
 417 else
 418         HAVE_STRIP_NONDETERMINISM=no
 419 fi
 420 AM_CONDITIONAL([STRIP_NONDETERMINISM], [test x$HAVE_STRIP_NONDETERMINISM != xno])
 421 AC_SUBST(STRIP_NONDETERMINISM, "$with_strip_nondeterminism")
 422
 423 PKG_CHECK_MODULES([JANSSON], [jansson])
 424
 425 AC_ARG_WITH([readline],
 426             [AS_HELP_STRING([--with-readline],
 427                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 428               [],
 429               [with_readline=auto])
 430
 431 LIBREADLINE_LIBS=
 432
 433 if test x"$with_readline" != "xno"; then
 434         AC_CHECK_LIB([readline], [main],
 435                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 436                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 437                          [Define if you have libreadline])],
 438                       [if test "x$with_readline" != xauto; then
 439                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 440                        fi],
 441                        -lncurses)
 442 fi
 443
 444 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 445
 446 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 447 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 448
 449 AC_ARG_WITH([stlink],
 450             [AS_HELP_STRING([--with-stlink],
 451                             [Build tools that use the stlink library (default: auto)])],
 452             [],
 453             [with_stlink=auto])
 454
 455 if test x"$with_stlink" != "xno"; then
 456         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 457         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 458                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 459         fi
 460 else
 461         HAVE_STLINK=no
 462 fi
 463
 464 if test x"$HAVE_STLINK" = "xyes"; then
 465         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 466 fi
 467
 468 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 469
 470 AC_ARG_ENABLE([multi-arch],
 471               [AS_HELP_STRING([--enable-multi-arch],
 472                               [enable building both i386 and amd64 libraries (default=auto)])],
 473               [MULTI_ARCH=$enableval],
 474               [MULTI_ARCH=auto])
 475
 476 case x"$MULTI_ARCH" in
 477 xauto)
 478         MULTI_ARCH=yes
 479         for arch in i686-linux-gnu x86_64-linux-gnu aarch64-linux-gnu arm-linux-gnueabi arm-linux-gnueabihf; do
 480                 crossgcc="$arch"-gcc
 481                 AC_CHECK_PROG(ARCH_SUPPORTED,$crossgcc,yes,no)
 482                 case "$ARCH_SUPPORTED" in
 483                 yes)
 484                         ;;
 485                 *)
 486                         MULTI_ARCH=no
 487                         ;;
 488                 esac
 489         done
 490         AC_MSG_CHECKING([MULTI_ARCH])
 491         AC_MSG_RESULT([$MULTI_ARCH])
 492         ;;
 493 xyes|xno)
 494         ;;
 495 *)
 496         MULTI_ARCH="no"
 497         ;;
 498 esac
 499
 500 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 501
 502 AC_ARG_ENABLE([install-shared-mime-info],
 503               [AS_HELP_STRING([--disable-install-shared-mime-info],
 504                               [disable installing shared mime info files (default=yes)])],
 505               [INSTALL_SHARED_MIME_INFO=$enableval],
 506               [INSTALL_SHARED_MIME_INFO=yes])
 507
 508 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 509
 510 AC_OUTPUT([
 511 Makefile
 512 src/Makedefs
 513 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 514 doc/Makefile
 515 altoslib/Makefile
 516 altoslib/AltosVersion.java
 517 icon/Makefile
 518 altosuilib/Makefile
 519 altosui/Makefile
 520 altosui/Info.plist
 521 altosui/altos-windows.nsi
 522 libaltos/Makefile
 523 micropeak/Makefile
 524 micropeak/Info.plist
 525 micropeak/micropeak-windows.nsi
 526 telegps/Makefile
 527 telegps/Info.plist
 528 telegps/telegps-windows.nsi
 529 altosdroid/Makefile
 530 altosdroid/local.properties
 531 altosdroid/app/src/main/AndroidManifest.xml
 532 altosdroid/app/build.gradle
 533 ao-tools/Makefile
 534 ao-tools/lib/Makefile
 535 ao-tools/ao-rawload/Makefile
 536 ao-tools/ao-dbg/Makefile
 537 ao-tools/ao-bitbang/Makefile
 538 ao-tools/ao-eeprom/Makefile
 539 ao-tools/ao-list/Makefile
 540 ao-tools/ao-load/Makefile
 541 ao-tools/ao-telem/Makefile
 542 ao-tools/ao-stmload/Makefile
 543 ao-tools/ao-send-telem/Makefile
 544 ao-tools/ao-sky-flash/Makefile
 545 ao-tools/ao-dumpflash/Makefile
 546 ao-tools/ao-edit-telem/Makefile
 547 ao-tools/ao-dump-up/Makefile
 548 ao-tools/ao-elftohex/Makefile
 549 ao-tools/ao-usbload/Makefile
 550 ao-tools/ao-flash/Makefile
 551 ao-tools/ao-test-igniter/Makefile
 552 ao-tools/ao-test-baro/Makefile
 553 ao-tools/ao-test-flash/Makefile
 554 ao-tools/ao-test-pressure/Makefile
 555 ao-tools/ao-cal-accel/Makefile
 556 ao-tools/ao-cal-freq/Makefile
 557 ao-tools/ao-test-gps/Makefile
 558 ao-tools/ao-usbtrng/Makefile
 559 ao-tools/ao-makebin/Makefile
 560 ao-utils/Makefile
 561 map-server/Makefile
 562 map-server/altos-mapd/Makefile
 563 map-server/altos-map/Makefile
 564 map-server/altos-mapj/Makefile
 565 ])
 566
 567 echo ""
 568 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 569 echo ""
 570 echo "  Configuration"
 571 echo "    Arm compiler................: ${ARM_CC}"
 572 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 573 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 574 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 575 echo "    AVR support.................: ${HAVE_AVR_CC}"
 576 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 577 echo "    Android release support.....: ${ANDROID_RELEASE}"
 578 echo "    STlink support..............: ${HAVE_STLINK}"
 579 echo "    multi-arch libaltos.........: ${MULTI_ARCH}"
 580 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 581 echo "    Strip jar timestamps........: ${STRIP_NONDETERMINISM}"
 582 echo ""
 583 echo "  Java"
 584 echo "    freetts.....................: ${FREETTS}"
 585 echo "    jfreechart..................: ${JFREECHART}"
 586 echo "    jcommon.....................: ${JCOMMON}"
 587 echo "    JVM include.................: ${JVM_INCLUDE}"
 588 echo "    AltosDroid maps API key.....: ${HAVE_GOOGLE_KEY}"
 589 echo "    Windows installer key.......: ${HAVE_WINDOWS_KEY}"
 590 if test x${ANDROID_SDK} != "xno"; then
 591 echo ""
 592 echo "  Android path"
 593 echo "    Android SDK.................: ${ANDROID_SDK}"
 594 fi
 595 echo ""