git.gag.com Git - fw/openocd/blob - configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.11.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5 AC_CONFIG_AUX_DIR([.])
   6
   7 m4_include([config_subdir.m4])dnl
   8
   9 # check for makeinfo before calling AM_INIT_AUTOMAKE
  10 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  11 AS_IF([test "x$MAKEINFO" = "x"], [
  12   MAKEINFO='echo makeinfo missing; true'
  13   AC_MSG_WARN([Info documentation will not be built.])
  14 ])
  15 AC_SUBST([MAKEINFO])
  16
  17 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20 AH_BOTTOM([
  21 #include <helper/system.h>
  22 #include <helper/types.h>
  23 #include <helper/replacements.h>
  24 ])
  25
  26 AC_LANG([C])
  27 AC_PROG_CC
  28 # autoconf 2.70 obsoletes AC_PROG_CC_C99 and includes it in AC_PROG_CC
  29 m4_version_prereq([2.70],[],[AC_PROG_CC_C99])
  30 AM_PROG_CC_C_O
  31 AC_PROG_RANLIB
  32 PKG_PROG_PKG_CONFIG([0.23])
  33
  34 dnl disable checks for C++, Fortran and GNU Java Compiler
  35 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  36 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  37 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  38 AC_DISABLE_SHARED
  39 LT_INIT
  40 AC_SUBST([LIBTOOL_DEPS])
  41
  42 dnl configure checks required for Jim files (these are obsolete w/ C99)
  43 AC_C_CONST
  44 AC_TYPE_LONG_LONG_INT
  45
  46 AC_SEARCH_LIBS([ioperm], [ioperm])
  47 AC_SEARCH_LIBS([dlopen], [dl])
  48 AC_SEARCH_LIBS([openpty], [util])
  49
  50 AC_CHECK_HEADERS([sys/socket.h])
  51 AC_CHECK_HEADERS([elf.h])
  52 AC_CHECK_HEADERS([dirent.h])
  53 AC_CHECK_HEADERS([fcntl.h])
  54 AC_CHECK_HEADERS([malloc.h])
  55 AC_CHECK_HEADERS([netdb.h])
  56 AC_CHECK_HEADERS([poll.h])
  57 AC_CHECK_HEADERS([pthread.h])
  58 AC_CHECK_HEADERS([strings.h])
  59 AC_CHECK_HEADERS([sys/ioctl.h])
  60 AC_CHECK_HEADERS([sys/param.h])
  61 AC_CHECK_HEADERS([sys/select.h])
  62 AC_CHECK_HEADERS([sys/stat.h])
  63 AC_CHECK_HEADERS([sys/sysctl.h])
  64 AC_CHECK_HEADERS([sys/time.h])
  65 AC_CHECK_HEADERS([sys/types.h])
  66 AC_CHECK_HEADERS([unistd.h])
  67 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  68 #include <stdio.h>
  69 #ifdef STDC_HEADERS
  70 # include <stdlib.h>
  71 # include <stddef.h>
  72 #else
  73 # ifdef HAVE_STDLIB_H
  74 #  include <stdlib.h>
  75 # endif
  76 #endif
  77 #ifdef HAVE_SYS_SOCKET_H
  78 # include <sys/socket.h>
  79 #endif
  80 ])
  81
  82 AC_HEADER_ASSERT
  83 AC_HEADER_STDBOOL
  84
  85 AC_C_BIGENDIAN
  86
  87 AC_CHECK_FUNCS([strndup])
  88 AC_CHECK_FUNCS([strnlen])
  89 AC_CHECK_FUNCS([gettimeofday])
  90 AC_CHECK_FUNCS([usleep])
  91 AC_CHECK_FUNCS([vasprintf])
  92 AC_CHECK_FUNCS([realpath])
  93
  94 # guess-rev.sh only exists in the repository, not in the released archives
  95 AC_MSG_CHECKING([whether to build a release])
  96 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  97   build_release=no
  98 ], [
  99   build_release=yes
 100 ])
 101 AC_MSG_RESULT([$build_release])
 102
 103 # Adapter drivers
 104 # 1st column -- configure option
 105 # 2nd column -- description
 106 # 3rd column -- symbol used for both config.h and automake
 107 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 108 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 109 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 110 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 111 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 112
 113 m4_define([USB1_ADAPTERS],
 114         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 115         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 116         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 117         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 118         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 119         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 120         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 121         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 122         [[cmsis_dap_v2], [CMSIS-DAP v2 Compliant Debugger], [CMSIS_DAP_USB]],
 123         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 124         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 125         [[aice], [Andes JTAG Programmer], [AICE]]])
 126
 127 m4_define([USB0_ADAPTERS],
 128         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 129         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 130         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 131
 132 m4_define([HIDAPI_ADAPTERS],
 133         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP_HID]],
 134         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 135
 136 m4_define([HIDAPI_USB1_ADAPTERS],
 137         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 138
 139 m4_define([LIBFTDI_ADAPTERS],
 140         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 141         [[presto], [ASIX Presto Adapter], [PRESTO]]])
 142
 143 m4_define([LIBFTDI_USB1_ADAPTERS],
 144         [[[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 145
 146 m4_define([LIBGPIOD_ADAPTERS],
 147         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 148
 149 m4_define([LIBJAYLINK_ADAPTERS],
 150         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 151
 152 m4_define([PCIE_ADAPTERS],
 153         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 154
 155 m4_define([OPTIONAL_LIBRARIES],
 156         [[[capstone], [Use Capstone disassembly framework], []]])
 157
 158 AC_ARG_ENABLE([doxygen-html],
 159   AS_HELP_STRING([--disable-doxygen-html],
 160     [Disable building Doxygen manual as HTML.]),
 161   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 162 AC_SUBST([doxygen_as_html])
 163 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 164 AC_MSG_RESULT([$doxygen_as_html])
 165
 166 AC_ARG_ENABLE([doxygen-pdf],
 167   AS_HELP_STRING([--enable-doxygen-pdf],
 168     [Enable building Doxygen manual as PDF.]),
 169   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 170 AC_SUBST([doxygen_as_pdf])
 171 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 172 AC_MSG_RESULT([$doxygen_as_pdf])
 173
 174 AC_ARG_ENABLE([gccwarnings],
 175   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 176   [gcc_warnings=$enableval], [gcc_warnings=yes])
 177
 178 AC_ARG_ENABLE([wextra],
 179   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 180   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 181
 182 AC_ARG_ENABLE([werror],
 183   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 184   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 185
 186 # set default verbose options, overridden by following options
 187 debug_usb_io=no
 188 debug_usb_comms=no
 189
 190 AC_ARG_ENABLE([verbose],
 191   AS_HELP_STRING([--enable-verbose],
 192       [Enable verbose JTAG I/O messages (for debugging).]),
 193   [
 194   debug_usb_io=$enableval
 195   debug_usb_comms=$enableval
 196   ], [])
 197
 198 AC_ARG_ENABLE([verbose_usb_io],
 199   AS_HELP_STRING([--enable-verbose-usb-io],
 200       [Enable verbose USB I/O messages (for debugging)]),
 201   [debug_usb_io=$enableval], [])
 202
 203 AC_ARG_ENABLE([verbose_usb_comms],
 204   AS_HELP_STRING([--enable-verbose-usb-comms],
 205       [Enable verbose USB communication messages (for debugging)]),
 206   [debug_usb_comms=$enableval], [])
 207
 208 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 209 AC_MSG_RESULT([$debug_usb_io])
 210 AS_IF([test "x$debug_usb_io" = "xyes"], [
 211   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 212 ])
 213
 214 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 215 AC_MSG_RESULT([$debug_usb_comms])
 216 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 217   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 218 ])
 219
 220 debug_malloc=no
 221 AC_ARG_ENABLE([malloc_logging],
 222   AS_HELP_STRING([--enable-malloc-logging],
 223       [Include free space in logging messages (requires malloc.h).]),
 224   [debug_malloc=$enableval], [])
 225
 226 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 227 AC_MSG_RESULT([$debug_malloc])
 228 AS_IF([test "x$debug_malloc" = "xyes"], [
 229   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 230 ])
 231
 232 AC_ARG_ENABLE([dummy],
 233   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 234   [build_dummy=$enableval], [build_dummy=no])
 235
 236 AC_ARG_ENABLE([rshim],
 237   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 238   [build_rshim=$enableval], [build_rshim=no])
 239
 240 m4_define([AC_ARG_ADAPTERS], [
 241   m4_foreach([adapter], [$1],
 242         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 243                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 244                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 245                 [], [ADAPTER_VAR([adapter])=$2])
 246   ])
 247 ])
 248
 249 AC_ARG_ADAPTERS([
 250   USB1_ADAPTERS,
 251   USB0_ADAPTERS,
 252   HIDAPI_ADAPTERS,
 253   HIDAPI_USB1_ADAPTERS,
 254   LIBFTDI_ADAPTERS,
 255   LIBFTDI_USB1_ADAPTERS
 256   LIBGPIOD_ADAPTERS,
 257   LIBJAYLINK_ADAPTERS
 258   ],[auto])
 259
 260 AC_ARG_ENABLE([parport],
 261   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 262   [build_parport=$enableval], [build_parport=no])
 263
 264 AC_ARG_ENABLE([parport_ppdev],
 265   AS_HELP_STRING([--disable-parport-ppdev],
 266       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 267     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 268
 269 AC_ARG_ENABLE([parport_giveio],
 270     AS_HELP_STRING([--enable-parport-giveio],
 271       [Enable use of giveio for parport (for CygWin only)]),
 272     [parport_use_giveio=$enableval], [parport_use_giveio=])
 273
 274 AC_ARG_ENABLE([jtag_vpi],
 275   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 276   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 277
 278 AC_ARG_ENABLE([jtag_dpi],
 279   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 280   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 281
 282 AC_ARG_ENABLE([amtjtagaccel],
 283   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 284   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 285
 286 AC_ARG_ENABLE([zy1000_master],
 287   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 288   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 289
 290 AC_ARG_ENABLE([zy1000],
 291   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 292   [build_zy1000=$enableval], [build_zy1000=no])
 293
 294 AC_ARG_ENABLE([ioutil],
 295   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 296   [build_ioutil=$enableval], [build_ioutil=no])
 297
 298 AS_CASE(["${host_cpu}"],
 299   [arm*|aarch64], [
 300     AC_ARG_ENABLE([bcm2835gpio],
 301       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 302       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 303     AC_ARG_ENABLE([imx_gpio],
 304       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 305       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 306   ],
 307   [
 308     build_bcm2835gpio=no
 309     build_imx_gpio=no
 310 ])
 311
 312 AS_CASE(["${host_cpu}"],
 313   [arm*], [
 314     AC_ARG_ENABLE([ep93xx],
 315       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 316       [build_ep93xx=$enableval], [build_ep93xx=no])
 317
 318     AC_ARG_ENABLE([at91rm9200],
 319       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 320       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 321   ],
 322   [
 323     build_ep93xx=no
 324     build_at91rm9200=no
 325 ])
 326
 327 AC_ARG_ENABLE([gw16012],
 328   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 329   [build_gw16012=$enableval], [build_gw16012=no])
 330
 331 AC_ARG_ENABLE([oocd_trace],
 332   AS_HELP_STRING([--enable-oocd_trace],
 333   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 334   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 335
 336 AC_ARG_ENABLE([buspirate],
 337   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 338   [build_buspirate=$enableval], [build_buspirate=no])
 339
 340 AC_ARG_ENABLE([sysfsgpio],
 341   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 342   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 343
 344 AC_ARG_ENABLE([xlnx_pcie_xvc],
 345   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 346   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 347
 348 AS_CASE([$host_os],
 349   [linux*], [],
 350   [
 351     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 352       AC_MSG_ERROR([sysfsgpio is only available on linux])
 353     ])
 354
 355     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 356       AC_MSG_ERROR([linuxgpiod is only available on linux])
 357     ])
 358
 359     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 360       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 361     ])
 362
 363     AS_CASE([$host_os], [freebsd*], [],
 364     [
 365       AS_IF([test "x$build_rshim" = "xyes"], [
 366         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 367       ])
 368     ])
 369 ])
 370
 371 AC_ARG_ENABLE([minidriver_dummy],
 372   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 373   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 374
 375 AC_ARG_ENABLE([internal-jimtcl],
 376   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 377   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 378
 379 AC_ARG_ENABLE([internal-libjaylink],
 380   AS_HELP_STRING([--disable-internal-libjaylink],
 381   [Disable building internal libjaylink]),
 382   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 383
 384 build_minidriver=no
 385 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 386 AS_IF([test "x$build_zy1000" = "xyes"], [
 387   AS_IF([test "x$build_minidriver" = "xyes"], [
 388     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 389   ])
 390   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 391       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 392   build_minidriver=yes
 393 ])
 394 AC_MSG_RESULT([$build_zy1000])
 395
 396 AC_ARG_ENABLE([remote-bitbang],
 397   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 398   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 399
 400 AC_MSG_CHECKING([whether to enable dummy minidriver])
 401 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 402   AS_IF([test "x$build_minidriver" = "xyes"], [
 403     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 404   ])
 405   build_minidriver=yes
 406   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 407   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 408       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 409 ])
 410 AC_MSG_RESULT([$build_minidriver_dummy])
 411
 412 AC_MSG_CHECKING([whether standard drivers can be built])
 413 AS_IF([test "x$build_minidriver" = "xyes"], [
 414   AC_MSG_RESULT([no])
 415   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 416   sleep 2
 417 ], [
 418   AC_MSG_RESULT([yes])
 419 ])
 420
 421 AS_CASE(["${host_cpu}"],
 422   [i?86|x86*], [],
 423   [
 424     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 425       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 426     ])
 427     parport_use_ppdev=yes
 428 ])
 429
 430 AS_CASE([$host],
 431   [*-cygwin*], [
 432     is_win32=yes
 433     parport_use_ppdev=no
 434
 435     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 436       [is_mingw=yes],[is_mingw=no])
 437     AS_IF([test "x$is_mingw" = "xyes"], [
 438       AS_IF([test "x$parport_use_giveio" = "xno"], [
 439         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 440       ])
 441       parport_use_giveio=yes
 442       is_cygwin=no
 443     ], [
 444       is_cygwin=yes
 445       # sys/io.h needed under cygwin for parport access
 446       AS_IF([test "x$build_parport" = "xyes"], [
 447         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 448       ])
 449     ])
 450   ],
 451   [*-mingw* | *-msys*], [
 452     is_mingw=yes
 453     is_win32=yes
 454     parport_use_ppdev=no
 455
 456     AS_IF([test "x$parport_use_giveio" = "xno"], [
 457       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 458     ])
 459     parport_use_giveio=yes
 460
 461     AS_IF([test "x$build_buspirate" = "xyes"], [
 462       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 463     ])
 464
 465     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 466   ],
 467   [*darwin*], [
 468     is_darwin=yes
 469
 470     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 471       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 472     ])
 473     parport_use_giveio=no
 474   ],
 475   [
 476     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 477       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 478     ])
 479     parport_use_giveio=no
 480 ])
 481
 482 AS_IF([test "x$is_cygwin" = "xyes"], [
 483     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 484 ], [
 485     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 486 ])
 487
 488 AS_IF([test "x$is_mingw" = "xyes"], [
 489     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 490 ], [
 491     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 492 ])
 493
 494 AS_IF([test "x$is_win32" = "xyes"], [
 495     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 496 ], [
 497     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 498 ])
 499
 500 AS_IF([test "x$is_darwin" = "xyes"], [
 501     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 502 ], [
 503     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 504 ])
 505
 506 AS_IF([test "x$build_parport" = "xyes"], [
 507   build_bitbang=yes
 508   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 509 ], [
 510   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 511 ])
 512
 513 AS_IF([test "x$build_rshim" = "xyes"], [
 514   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 515 ], [
 516   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 517 ])
 518
 519 AS_IF([test "x$build_dummy" = "xyes"], [
 520   build_bitbang=yes
 521   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 522 ], [
 523   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 524 ])
 525
 526 AS_IF([test "x$build_ep93xx" = "xyes"], [
 527   build_bitbang=yes
 528   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 529 ], [
 530   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 531 ])
 532
 533 AS_IF([test "x$build_zy1000" = "xyes"], [
 534   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 535 ], [
 536   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 537 ])
 538
 539 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 540   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 541 ], [
 542   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 543 ])
 544
 545 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 546   build_bitbang=yes
 547   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 548 ], [
 549   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 550 ])
 551
 552 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 553   build_bitbang=yes
 554   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 555 ], [
 556   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 557 ])
 558
 559 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 560   build_bitbang=yes
 561   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 562 ], [
 563   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 564 ])
 565
 566 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 567   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 568 ], [
 569   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 570 ])
 571
 572 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 573   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 574 ], [
 575   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 576 ])
 577
 578 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 579   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 580 ], [
 581   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 582 ])
 583
 584 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 585   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 586 ], [
 587   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 588 ])
 589
 590
 591 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 592   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 593 ], [
 594   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 595 ])
 596
 597 AS_IF([test "x$build_gw16012" = "xyes"], [
 598   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 599 ], [
 600   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 601 ])
 602
 603 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 604   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 605 ], [
 606   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 607 ])
 608
 609 AS_IF([test "x$build_buspirate" = "xyes"], [
 610   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 611 ], [
 612   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 613 ])
 614
 615 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 616   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 617     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 618   ], [
 619     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 620   ])
 621 ])
 622
 623 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 624   build_bitbang=yes
 625   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 626 ], [
 627   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 628 ])
 629
 630 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 631   build_bitbang=yes
 632   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 633 ], [
 634   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 635 ])
 636
 637 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 638   build_xlnx_pcie_xvc=yes
 639   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 640 ], [
 641   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 642 ])
 643
 644 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 645         use_libusb1=yes
 646         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 647         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 648                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 649                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 650         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 651         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 652         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 653                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 654   ], [
 655         use_libusb1=no
 656         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 657 ])
 658
 659 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 660
 661 AC_ARG_WITH([capstone],
 662                 AS_HELP_STRING([--with-capstone], [Use Capstone disassembly library (default=auto)])
 663         , [
 664                 enable_capstone=$withval
 665         ], [
 666                 enable_capstone=auto
 667 ])
 668
 669 AS_IF([test "x$enable_capstone" != xno], [
 670         PKG_CHECK_MODULES([CAPSTONE], [capstone], [
 671                 AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have Capstone disassembly framework.])
 672         ], [
 673                 AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have Capstone disassembly framework.])
 674                 if test "x$enable_capstone" != xauto; then
 675                         AC_MSG_ERROR([--with-capstone was given, but test for Capstone failed])
 676                 fi
 677                 enable_capstone=no
 678         ])
 679 ])
 680
 681 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 682         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 683                 use_hidapi=yes
 684                 break
 685         ],[
 686                 use_hidapi=no
 687         ])
 688 done
 689
 690 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
 691         use_libftdi=yes
 692         PKG_CHECK_EXISTS([libftdi1 >= 1.5],
 693                 [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
 694   ], [
 695         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 696 ])
 697
 698 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 699
 700 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 701         [use_libjaylink=yes], [use_libjaylink=no])
 702
 703 m4_define([PROCESS_ADAPTERS], [
 704   m4_foreach([adapter], [$1], [
 705         AS_IF([test "x$build_zy1000" = "xyes"], [
 706                 ADAPTER_VAR([adapter])=no
 707         ])
 708         AS_IF([test $2], [
 709                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 710                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 711                 ], [
 712                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 713                 ])
 714         ], [
 715                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 716                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 717                 ])
 718                 ADAPTER_VAR([adapter])=no
 719         ])
 720         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 721   ])
 722 ])
 723
 724 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 725 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 726 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 727 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 728 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 729 PROCESS_ADAPTERS([LIBFTDI_USB1_ADAPTERS], ["x$use_libftdi" = "xyes" -a "x$use_libusb1" = "xyes"], [libftdi and libusb-1.x])
 730 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 731 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 732
 733 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 734   build_bitbang=yes
 735 ])
 736
 737 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 738         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 739         AM_CONDITIONAL([HLADAPTER], [true])
 740 ], [
 741         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 742         AM_CONDITIONAL([HLADAPTER], [false])
 743 ])
 744 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 745 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 746 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 747
 748 AS_IF([test "x$enable_jlink" != "xno"], [
 749   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 750     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 751       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 752                 [--enable-subproject-build])
 753     ], [
 754       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 755     ])
 756   ])
 757 ])
 758
 759 # Presto needs the bitq module
 760 AS_IF([test "x$enable_presto" != "xno"], [
 761   build_bitq=yes
 762 ])
 763
 764 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 765 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 766 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 767 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 768 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 769 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 770 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 771 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 772 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 773 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 774 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 775 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 776 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 777 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
 778 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 779 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 780 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 781 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 782 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 783 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 784 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 785 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 786 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 787 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 788 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 789 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 790 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 791 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 792 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 793 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 794 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 795 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 796 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 797 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 798 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$enable_capstone" != "xno"])
 799
 800 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 801 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 802
 803 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 804 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 805
 806 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 807 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 808 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 809 #define _GNU_SOURCE
 810 #include <unistd.h>
 811 #include <stdlib.h>
 812   ]], [[char **ep = environ;]]
 813   )], [
 814     AC_MSG_RESULT([yes])
 815     has_environ=yes
 816   ], [
 817     AC_MSG_RESULT([no])
 818
 819     # Possibility #2: can environ be found in an available library?
 820     AC_MSG_CHECKING([for extern environ])
 821     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 822     extern char **environ;
 823     ]], [[char **ep = environ;]]
 824       )], [
 825         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 826         has_environ=yes
 827       ], [
 828         has_environ=no
 829       ])
 830     AC_MSG_RESULT([${has_environ}])
 831   ])
 832
 833 AS_IF([test "x${has_environ}" != "xyes" ], [
 834   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 835 ])
 836
 837 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 838
 839 # set default gcc warnings
 840 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 841 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 842   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 843   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 844   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 845   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 846   GCC_WARNINGS="${GCC_WARNINGS} -Wpointer-arith"
 847 ])
 848 AS_IF([test "x${gcc_werror}" = "xyes"], [
 849   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 850 ])
 851
 852 # override default gcc cflags
 853 AS_IF([test "x$gcc_warnings" = "xyes"], [
 854   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 855 ])
 856
 857 AC_SUBST(EXTRA_DIST_NEWS, ["$(echo $srcdir/NEWS-*)"])
 858
 859 AC_CONFIG_FILES([
 860   Makefile
 861 ])
 862 AC_OUTPUT
 863
 864 echo
 865 echo
 866 echo OpenOCD configuration summary
 867 echo --------------------------------------------------
 868 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 869         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 870         LIBFTDI_USB1_ADAPTERS,
 871         LIBGPIOD_ADAPTERS,
 872         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS,
 873         OPTIONAL_LIBRARIES],
 874         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 875         AS_CASE([$ADAPTER_VAR([adapter])],
 876                 [auto], [
 877                         echo "$s"yes '(auto)'
 878                 ],
 879                 [yes], [
 880                         echo "$s"yes
 881                 ],
 882                 [no], [
 883                         echo "$s"no
 884         ])
 885 ])
 886 echo
 887
 888 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 889   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 890   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 891   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 892   echo
 893 ])
 894
 895 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 896   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 897   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 898   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 899   echo 'Mailing List.'
 900   echo
 901 ])
 902
 903 AS_IF([test "x$build_ioutil" = "xyes"], [
 904   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 905   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 906   echo 'release. If you regularly depend on this functionality, please report to the'
 907   echo 'OpenOCD Mailing List.'
 908   echo
 909 ])