git.gag.com Git - fw/altos/blob - src/stmf0/altos.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom (rx) :   ORIGIN = 0x08001000, LENGTH = 28K
  21         ram (!w) :   ORIGIN = 0x20000000, LENGTH = 6k - 128
  22         stack (!w) : ORIGIN = 0x20000000 + 6k - 128, LENGTH = 128
  23 }
  24
  25 INCLUDE registers.ld
  26
  27 EXTERN (stm_interrupt_vector)
  28
  29 SECTIONS {
  30         /*
  31          * Rom contents
  32          */
  33
  34         .interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
  35                 __interrupt_start__ = .;
  36                 __interrupt_rom__ = ORIGIN(rom);
  37                 *(.interrupt)   /* Interrupt vectors */
  38                 __interrupt_end__ = .;
  39         } > ram
  40
  41         .text ORIGIN(rom) + 0x100 : {
  42                 __text_start__ = .;
  43
  44                 /* Ick. What I want is to specify the
  45                  * addresses of some global constants so
  46                  * that I can find them across versions
  47                  * of the application. I can't figure out
  48                  * how to make gnu ld do that, so instead
  49                  * we just load the two files that include
  50                  * these defines in the right order here and
  51                  * expect things to 'just work'. Don't change
  52                  * the contents of those files, ok?
  53                  */
  54                 ao_romconfig.o(.romconfig*)
  55                 ao_product.o(.romconfig*)
  56
  57                 *(.text*)       /* Executable code */
  58                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  59                 *(.rodata*)     /* Constants */
  60
  61         } > rom
  62         __text_end__ = .;
  63
  64         /* Boot data which must live at the start of ram so that
  65          * the application and bootloader share the same addresses.
  66          * This must be all uninitialized data
  67          */
  68         .boot (NOLOAD) : {
  69                 __boot_start__ = .;
  70                 *(.boot)
  71                 . = ALIGN(4);
  72                 __boot_end__ = .;
  73         } >ram
  74
  75         /* Data -- relocated to RAM, but written to ROM
  76          */
  77         .data : {
  78                 __data_start__ = .;
  79                 *(.data)        /* initialized data */
  80                 . = ALIGN(4);
  81                 __data_end__ = .;
  82         } >ram AT>rom
  83
  84         .bss : {
  85                 __bss_start__ = .;
  86                 *(.bss)
  87                 *(COMMON)
  88                 . = ALIGN(4);
  89                 __bss_end__ = .;
  90         } >ram
  91
  92         PROVIDE(end = .);
  93
  94         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  95 }
  96
  97 ENTRY(start);
  98
  99