git.gag.com Git - fw/altos/blob - src/stmf0/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom : ORIGIN = 0x08000000, LENGTH = 4K
  20         ram : ORIGIN = 0x20000000, LENGTH = 6K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26
  27 SECTIONS {
  28         /*
  29          * Rom contents
  30          */
  31
  32         .interrupt : {
  33                 __text_start__ = .;
  34                 *(.interrupt)   /* Interrupt vectors */
  35         } > rom
  36
  37         .text ORIGIN(rom) + 0x100 : {
  38                 ao_romconfig.o(.romconfig*)
  39                 ao_product.o(.romconfig*)
  40
  41                 *(.text*)       /* Executable code */
  42                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  43                 *(.rodata*)     /* Constants */
  44         } > rom
  45         __text_end__ = .;
  46
  47         /* Boot data which must live at the start of ram so that
  48          * the application and bootloader share the same addresses.
  49          * This must be all uninitialized data
  50          */
  51         .boot ORIGIN(ram) + SIZEOF(.interrupt) (NOLOAD) : {
  52                 __boot_start__ = .;
  53                 *(.boot)
  54                 __boot_end__ = .;
  55         } >ram
  56
  57         /* Functions placed in RAM (required for flashing)
  58          *
  59          * Align to 8 bytes as that's what the ARM likes text
  60          * segment alignments to be, and if we don't, then
  61          * we end up with a mismatch between the location in
  62          * ROM and the desired location in RAM. I don't
  63          * entirely understand this, but at least this appears
  64          * to work...
  65          */
  66
  67         .textram BLOCK(8): {
  68                 __data_start__ = .;
  69                 __text_ram_start__ = .;
  70                 *(.ramtext)
  71                 __text_ram_end = .;
  72         } >ram AT>rom
  73
  74         /* Data -- relocated to RAM, but written to ROM
  75          */
  76         .data : {
  77                 *(.data)        /* initialized data */
  78                 __data_end__ = .;
  79         } >ram AT>rom
  80
  81
  82         .bss : {
  83                 __bss_start__ = .;
  84                 *(.bss)
  85                 *(COMMON)
  86                 __bss_end__ = .;
  87         } >ram
  88
  89         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  90         PROVIDE(end = .);
  91 }
  92
  93 ENTRY(start);
  94
  95