git.gag.com Git - fw/altos/blob - src/stm/altos.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) : ORIGIN = 0x08001000, LENGTH = 124K
  20         ram (!w) : ORIGIN = 0x20000000, LENGTH = 15872
  21         stack (!w) : ORIGIN = 0x20003e00, LENGTH = 512
  22 }
  23
  24 INCLUDE registers.ld
  25
  26 EXTERN (stm_interrupt_vector)
  27
  28 SECTIONS {
  29         /*
  30          * Rom contents
  31          */
  32
  33         .text ORIGIN(rom) : {
  34                 __text_start__ = .;
  35                 *(.interrupt)   /* Interrupt vectors */
  36
  37                 . = ORIGIN(rom) + 0x100;
  38
  39
  40                 /* Ick. What I want is to specify the
  41                  * addresses of some global constants so
  42                  * that I can find them across versions
  43                  * of the application. I can't figure out
  44                  * how to make gnu ld do that, so instead
  45                  * we just load the two files that include
  46                  * these defines in the right order here and
  47                  * expect things to 'just work'. Don't change
  48                  * the contents of those files, ok?
  49                  */
  50                 ao_romconfig.o(.romconfig*)
  51                 ao_product.o(.romconfig*)
  52                 *(.text*)       /* Executable code */
  53                 *(.rodata*)     /* Constants */
  54
  55         } > rom
  56
  57         .ARM.exidx : {
  58                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  59         } > rom
  60         __text_end__ = .;
  61
  62         /* Boot data which must live at the start of ram so that
  63          * the application and bootloader share the same addresses.
  64          * This must be all uninitialized data
  65          */
  66         .boot (NOLOAD) : {
  67                 __boot_start__ = .;
  68                 *(.boot)
  69                 . = ALIGN(4);
  70                 __boot_end__ = .;
  71         } >ram
  72
  73         /* Data -- relocated to RAM, but written to ROM
  74          */
  75         .data : {
  76                 __data_start__ = .;
  77                 *(.data)        /* initialized data */
  78                 . = ALIGN(4);
  79                 __data_end__ = .;
  80         } >ram AT>rom
  81
  82         .bss : {
  83                 __bss_start__ = .;
  84                 *(.bss)
  85                 *(COMMON)
  86                 . = ALIGN(4);
  87                 __bss_end__ = .;
  88         } >ram
  89
  90         PROVIDE(end = .);
  91
  92         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  93 }
  94
  95 ENTRY(start);
  96
  97