git.gag.com Git - fw/altos/blob - src/stm/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom : ORIGIN = 0x08000000, LENGTH = 4K
  20         ram : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26
  27 SECTIONS {
  28         /*
  29          * Rom contents
  30          */
  31
  32         .text : {
  33                 __text_start__ = .;
  34                 *(.interrupt)   /* Interrupt vectors */
  35
  36                 . = ORIGIN(rom) + 0x100;
  37
  38                 ao_romconfig.o(.romconfig*)
  39                 ao_product.o(.romconfig*)
  40                 *(.text*)       /* Executable code */
  41                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  42                 *(.rodata*)     /* Constants */
  43         } > rom
  44         __text_end__ = .;
  45
  46         /* Boot data which must live at the start of ram so that
  47          * the application and bootloader share the same addresses.
  48          * This must be all uninitialized data
  49          */
  50         .boot (NOLOAD) : {
  51                 __boot_start__ = .;
  52                 *(.boot)
  53                 __boot_end__ = .;
  54         } >ram
  55
  56         /* Functions placed in RAM (required for flashing)
  57          *
  58          * Align to 8 bytes as that's what the ARM likes text
  59          * segment alignments to be, and if we don't, then
  60          * we end up with a mismatch between the location in
  61          * ROM and the desired location in RAM. I don't
  62          * entirely understand this, but at least this appears
  63          * to work...
  64          */
  65
  66         .textram BLOCK(8): {
  67                 __data_start__ = .;
  68                 __text_ram_start__ = .;
  69                 *(.ramtext)
  70                 __text_ram_end = .;
  71         } >ram AT>rom
  72
  73         /* Data -- relocated to RAM, but written to ROM
  74          */
  75         .data : {
  76                 *(.data)        /* initialized data */
  77                 __data_end__ = .;
  78         } >ram AT>rom
  79
  80
  81         .bss : {
  82                 __bss_start__ = .;
  83                 *(.bss)
  84                 *(COMMON)
  85                 __bss_end__ = .;
  86         } >ram
  87
  88         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  89         PROVIDE(end = .);
  90 }
  91
  92 ENTRY(start);
  93
  94