git.gag.com Git - fw/altos/blob - src/stm/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom : ORIGIN = 0x08000000, LENGTH = 8K
  20         ram : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26
  27 SECTIONS {
  28         /*
  29          * Rom contents
  30          */
  31
  32         .text : {
  33                 __text_start__ = .;
  34                 *(.interrupt)   /* Interrupt vectors */
  35                 *(.romconfig)
  36                 *(.text)        /* Executable code */
  37                 *(.rodata)      /* Constants */
  38
  39         } > rom
  40
  41         .ARM.exidx : {
  42                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  43         } > rom
  44         __text_end__ = .;
  45
  46         /* Boot data which must live at the start of ram so that
  47          * the application and bootloader share the same addresses.
  48          * This must be all uninitialized data
  49          */
  50         .boot (NOLOAD) : {
  51                 __boot_start__ = .;
  52                 *(.boot)
  53                 . = ALIGN(4);
  54                 __boot_end__ = .;
  55         } >ram
  56
  57         /* Functions placed in RAM (required for flashing) */
  58         .textram : {
  59                 __text_ram_start__ = .;
  60                 __data_start__ = .;
  61                 *(.text.ram)
  62                 . = ALIGN(4);
  63         } >ram AT>rom
  64         __text_ram_end = .;
  65
  66         /* Data -- relocated to RAM, but written to ROM
  67          */
  68         .data : {
  69                 *(.data)        /* initialized data */
  70                 . = ALIGN (4);
  71         } >ram AT>rom
  72         __data_end__ = .;
  73
  74         .bss : {
  75                 __bss_start__ = .;
  76                 *(.bss)
  77                 *(COMMON)
  78                 __bss_end__ = .;
  79         } >ram
  80
  81         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  82         PROVIDE(end = .);
  83 }
  84
  85 ENTRY(start);
  86
  87