git.gag.com Git - fw/altos/blob - src/stm/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom : ORIGIN = 0x08000000, LENGTH = 4K
  20         ram : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26
  27 SECTIONS {
  28         /*
  29          * Rom contents
  30          */
  31
  32         .text : {
  33                 __text_start__ = .;
  34                 *(.interrupt)   /* Interrupt vectors */
  35                 *(.romconfig*)
  36                 *(.text)        /* Executable code */
  37                 . = ALIGN(4);
  38                 *(.rodata*)     /* Constants */
  39                 . = ALIGN(4);
  40         } > rom
  41
  42         .ARM.exidx : {
  43                 . = ALIGN(4);
  44                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  45                 . = ALIGN(4);
  46         } > rom
  47         __text_end__ = .;
  48
  49         /* Boot data which must live at the start of ram so that
  50          * the application and bootloader share the same addresses.
  51          * This must be all uninitialized data
  52          */
  53         .boot (NOLOAD) : {
  54                 __boot_start__ = .;
  55                 *(.boot)
  56                 . = ALIGN(4);
  57                 __boot_end__ = .;
  58         } >ram
  59
  60         /* Functions placed in RAM (required for flashing) */
  61         .textram : {
  62                 __data_start__ = .;
  63                 __text_ram_start__ = .;
  64                 *(.text.ram)
  65                 __text_ram_end = .;
  66         } >ram AT>rom
  67
  68         /* Data -- relocated to RAM, but written to ROM
  69          */
  70         .data : {
  71                 *(.data)        /* initialized data */
  72                 __data_end__ = .;
  73         } >ram AT>rom
  74
  75
  76         .bss : {
  77                 __bss_start__ = .;
  78                 *(.bss)
  79                 *(COMMON)
  80                 __bss_end__ = .;
  81         } >ram
  82
  83         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  84         PROVIDE(end = .);
  85 }
  86
  87 ENTRY(start);
  88
  89