git.gag.com Git - fw/altos/blob - src/stm/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom : ORIGIN = 0x08000000, LENGTH = 8K
  20         ram : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26
  27 SECTIONS {
  28         /*
  29          * Rom contents
  30          */
  31
  32         .text : {
  33                 __text_start__ = .;
  34                 *(.interrupt)   /* Interrupt vectors */
  35
  36                 . = ORIGIN(rom) + 0x100;
  37
  38                 /* Ick. What I want is to specify the
  39                  * addresses of some global constants so
  40                  * that I can find them across versions
  41                  * of the application. I can't figure out
  42                  * how to make gnu ld do that, so instead
  43                  * we just load the two files that include
  44                  * these defines in the right order here and
  45                  * expect things to 'just work'. Don't change
  46                  * the contents of those files, ok?
  47                  */
  48                 ao_romconfig.o(.romconfig*)
  49                 ao_product.o(.romconfig*)
  50                 *(.text)        /* Executable code */
  51                 *(.rodata)      /* Constants */
  52
  53         } > rom
  54
  55         .ARM.exidx : {
  56                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  57         } > rom
  58         __text_end__ = .;
  59
  60         /* Boot data which must live at the start of ram so that
  61          * the application and bootloader share the same addresses.
  62          * This must be all uninitialized data
  63          */
  64         .boot (NOLOAD) : {
  65                 __boot_start__ = .;
  66                 *(.boot)
  67                 . = ALIGN(4);
  68                 __boot_end__ = .;
  69         } >ram
  70
  71         /* Functions placed in RAM (required for flashing) */
  72         .textram : {
  73                 __text_ram_start__ = .;
  74                 __data_start__ = .;
  75                 *(.text.ram)
  76                 . = ALIGN(4);
  77         } >ram AT>rom
  78         __text_ram_end = .;
  79
  80         /* Data -- relocated to RAM, but written to ROM
  81          */
  82         .data : {
  83                 *(.data)        /* initialized data */
  84                 . = ALIGN (4);
  85         } >ram AT>rom
  86         __data_end__ = .;
  87
  88         .bss : {
  89                 __bss_start__ = .;
  90                 *(.bss)
  91                 *(COMMON)
  92                 __bss_end__ = .;
  93         } >ram
  94
  95         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  96         PROVIDE(end = .);
  97 }
  98
  99 ENTRY(start);
 100
 101