git.gag.com Git - fw/altos/blob - src/stm-bringup/bringup.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) : ORIGIN = 0x08000000, LENGTH = 128K
  20         ram (!w) : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26
  27 SECTIONS {
  28         /*
  29          * Rom contents
  30          */
  31
  32         .text ORIGIN(rom) : {
  33                 __text_start__ = .;
  34                 *(.interrupt)   /* Interrupt vectors */
  35
  36                 *(.text*)       /* Executable code */
  37                 *(.rodata*)     /* Constants */
  38         } > rom
  39
  40         .ARM.exidx : {
  41                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  42                 __text_end__ = .;
  43         } > rom
  44
  45         . = ORIGIN(ram);
  46         __data_start__ = .;
  47
  48         /* Data -- relocated to RAM, but written to ROM
  49          */
  50         .data : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
  51                 *(.data)        /* initialized data */
  52                 __data_end__ = .;
  53                 __bss_start__ = .;
  54         } >ram
  55
  56         .bss : {
  57                 *(.bss)
  58                 *(COMMON)
  59                 __bss_end__ = .;
  60         } >ram
  61
  62         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  63         PROVIDE(end = .);
  64
  65 }
  66
  67 ENTRY(start);
  68
  69