git.gag.com Git - fw/altos/blob - src/lpc/altos.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) : ORIGIN = 0x00000000, LENGTH = 32K
  20         ram (!w) : ORIGIN = 0x10000000, LENGTH = 4K - 128
  21         usb (!x) : ORIGIN = 0x20004000 + 2K - 256, LENGTH = 256
  22         stack (!w) : ORIGIN = 0x10000000 + 4K - 128, LENGTH = 128
  23 }
  24
  25 INCLUDE registers.ld
  26
  27 EXTERN (lpc_interrupt_vector)
  28
  29 SECTIONS {
  30         /*
  31          * Rom contents
  32          */
  33
  34         .text ORIGIN(rom) : {
  35                 __text_start__ = .;
  36                 *(.interrupt)   /* Interrupt vectors */
  37
  38                 . = ORIGIN(rom) + 0x100;
  39
  40                 ao_romconfig.o(.romconfig*)
  41                 ao_product.o(.romconfig*)
  42
  43                 *(.text*)       /* Executable code */
  44                 *(.rodata*)     /* Constants */
  45
  46         } > rom
  47
  48         .ARM.exidx : {
  49                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  50                 __text_end__ = .;
  51         } > rom
  52
  53         /* Data -- relocated to RAM, but written to ROM
  54          */
  55         .data ORIGIN(ram) : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
  56                 __data_start__ = .;
  57                 *(.data)        /* initialized data */
  58                 __data_end__ = .;
  59                 __bss_start__ = .;
  60         } >ram
  61
  62         .bss : {
  63                 *(.bss)
  64                 *(COMMON)
  65                 __bss_end__ = .;
  66         } >ram
  67         PROVIDE(end = .);
  68
  69         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  70 }
  71
  72 ENTRY(start);
  73
  74