git.gag.com Git - fw/altos/blob - src/lpc/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom : ORIGIN = 0x00000000, LENGTH = 4K
  21         ram : ORIGIN = 0x10000000, LENGTH = 4k - 128 - 32
  22         usb (!x) : ORIGIN = 0x20004000 + 2K - 256, LENGTH = 256
  23         stack (!w) : ORIGIN = 0x10000000 + 4K - 128 - 32, LENGTH = 128
  24 }
  25
  26 INCLUDE registers.ld
  27
  28 EXTERN (lpc_interrupt_vector)
  29
  30 SECTIONS {
  31         /*
  32          * Rom contents
  33          */
  34
  35         .interrupt : {
  36                 __text_start__ = .;
  37                 *(.interrupt)   /* Interrupt vectors */
  38
  39         } > rom
  40
  41         .text ORIGIN(rom) + 0x100 : {
  42                 ao_romconfig.o(.romconfig*)
  43                 ao_product.o(.romconfig*)
  44
  45                 *(.text*)       /* Executable code */
  46                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  47                 *(.rodata*)     /* Constants */
  48                 __text_end__ = .;
  49         } > rom
  50
  51         /* Boot data which must live at the start of ram so that
  52          * the application and bootloader share the same addresses.
  53          * This must be all uninitialized data
  54          */
  55         .boot ORIGIN(ram) + SIZEOF(.interrupt) (NOLOAD) : {
  56                 __boot_start__ = .;
  57                 *(.boot*)
  58                 __boot_end__ = .;
  59         } >ram
  60
  61         /* Data -- relocated to RAM, but written to ROM
  62          */
  63         .data : {
  64                 _start__ = .;
  65                 *(.data*)       /* initialized data */
  66                 _end__ = .;
  67         } >ram AT>rom
  68
  69
  70         .bss : {
  71                 __bss_start__ = .;
  72                 *(.bss*)
  73                 *(COMMON*)
  74                 __bss_end__ = .;
  75         } >ram
  76
  77         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  78         PROVIDE(end = .);
  79 }
  80
  81 ENTRY(start);