git.gag.com Git - fw/altos/blob - src/lambdakey-v1.0/lambda.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom (rx) :   ORIGIN = 0x08001000, LENGTH = 28K
  21         ram (!w) :   ORIGIN = 0x20000000, LENGTH = 6k - 1k
  22         stack (!w) : ORIGIN = 0x20000000 + 6k - 1k, LENGTH = 1k
  23 }
  24
  25 INCLUDE registers.ld
  26
  27 EXTERN (stm_interrupt_vector)
  28
  29 SECTIONS {
  30         /*
  31          * Rom contents
  32          */
  33
  34         .interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
  35                 __interrupt_start__ = .;
  36                 __interrupt_rom__ = ORIGIN(rom);
  37                 *(.interrupt)   /* Interrupt vectors */
  38                 __interrupt_end__ = .;
  39         } > ram
  40
  41         .text ORIGIN(rom) + 0x100 : {
  42                 __text_start__ = .;
  43
  44                 /* Ick. What I want is to specify the
  45                  * addresses of some global constants so
  46                  * that I can find them across versions
  47                  * of the application. I can't figure out
  48                  * how to make gnu ld do that, so instead
  49                  * we just load the two files that include
  50                  * these defines in the right order here and
  51                  * expect things to 'just work'. Don't change
  52                  * the contents of those files, ok?
  53                  */
  54                 ao_romconfig.o(.romconfig*)
  55                 ao_product.o(.romconfig*)
  56
  57                 *(.text*)       /* Executable code */
  58                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  59                 *(.rodata*)     /* Constants */
  60
  61         } > rom
  62         __text_end__ = .;
  63
  64
  65         /* Boot data which must live at the start of ram so that
  66          * the application and bootloader share the same addresses.
  67          * This must be all uninitialized data
  68          */
  69         .boot (NOLOAD) : {
  70                 __boot_start__ = .;
  71                 *(.boot)
  72                 . = ALIGN(4);
  73                 __boot_end__ = .;
  74         } >ram
  75
  76         /* Functions placed in RAM (required for flashing)
  77          *
  78          * Align to 8 bytes as that's what the ARM likes text
  79          * segment alignments to be, and if we don't, then
  80          * we end up with a mismatch between the location in
  81          * ROM and the desired location in RAM. I don't
  82          * entirely understand this, but at least this appears
  83          * to work...
  84          */
  85
  86         .textram BLOCK(8): {
  87                 __data_start__ = .;
  88                 __text_ram_start__ = .;
  89                 *(.ramtext)
  90                 __text_ram_end = .;
  91         } >ram AT>rom
  92
  93         /* Data -- relocated to RAM, but written to ROM
  94          */
  95         .data BLOCK(8): {
  96                 *(.data)        /* initialized data */
  97                 . = ALIGN(8);
  98                 __data_end__ = .;
  99         } >ram AT>rom
 100
 101         .bss : {
 102                 __bss_start__ = .;
 103                 *(.bss)
 104                 *(COMMON)
 105                 . = ALIGN(4);
 106                 __bss_end__ = .;
 107         } >ram
 108
 109         PROVIDE(end = .);
 110
 111         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
 112 }
 113
 114 ENTRY(start);