git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.2)
  22 AC_CONFIG_SRCDIR([src/core/ao.h])
  23 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  24 AM_MAINTAINER_MODE
  25
  26 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  27 AC_SUBST(VERSION_DASH)
  28
  29
  30 dnl ==========================================================================
  31 dnl Java library versions
  32
  33 ALTOSUILIB_VERSION=1
  34 ALTOSLIB_VERSION=1
  35
  36 AC_SUBST(ALTOSLIB_VERSION)
  37 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  38 AC_SUBST(ALTOSUILIB_VERSION)
  39 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  40
  41 dnl ==========================================================================
  42
  43 AM_CONFIG_HEADER(config.h)
  44
  45 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  46         [Set freetts class path (default /usr/share/java)]),
  47         [FREETTS=$withval], [FREETTS=/usr/share/java])
  48
  49 AC_SUBST(FREETTS)
  50
  51 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  52         [Set jfreechart class path (default /usr/share/java)]),
  53         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  54
  55 AC_SUBST(JFREECHART)
  56
  57 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  58         [Set jcommon class path (default /usr/share/java)]),
  59         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  60
  61 AC_SUBST(JCOMMON)
  62
  63 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  64         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  65         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  66
  67 if test "x$JVM_INCLUDE" = "xauto"; then
  68         AC_MSG_CHECKING([JVM include files])
  69         for jvm in default-java java-6-openjdk java-6-sun; do
  70                 if test "x$JVM_INCLUDE" = "xauto"; then
  71                         INCLUDE="/usr/lib/jvm/$jvm/include"
  72                         if test -f "$INCLUDE"/jni.h; then
  73                                 JVM_INCLUDE="$INCLUDE"
  74                         fi
  75                 fi
  76         done
  77         if test "x$JVM_INCLUDE" = "xauto"; then
  78                 AC_MSG_ERROR([no JVM include files found])
  79         fi
  80         AC_MSG_RESULT([$JVM_INCLUDE])
  81 fi
  82
  83 AC_SUBST(JVM_INCLUDE)
  84
  85 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
  86         [Set android SDK path (default searches in a variety of places)]),
  87         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
  88
  89 if test "x$ANDROID_SDK" = "xauto"; then
  90         AC_MSG_CHECKING([Android SDK])
  91         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
  92                 if test "x$ANDROID_SDK" = "xauto"; then
  93                         SDK="$sdk"
  94                         if test -f "$SDK/SDK Readme.txt"; then
  95                                 ANDROID_SDK=`readlink -m "$SDK"`
  96                         fi
  97                 fi
  98         done
  99         if test "x$ANDROID_SDK" = "xauto"; then
 100                 AC_MSG_NOTICE([no Android SDK found])
 101                 ANDROID_SDK=no
 102         fi
 103         AC_MSG_RESULT([$ANDROID_SDK])
 104 fi
 105 if test "x$ANDROID_SDK" != "xno"; then
 106         AC_MSG_CHECKING([Android SDK version])
 107         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 108         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 109         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 110                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 111                 ANDROID_SDK=no
 112         else
 113                 AC_MSG_RESULT([$SDK_VERSION])
 114         fi
 115 fi
 116 if test "x$ANDROID_SDK" != "xno"; then
 117         AC_MSG_CHECKING([Android SDK API Level])
 118         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 119                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 120                 if test "$API_LEVEL" = "10"; then
 121                         AC_MSG_RESULT([$API_LEVEL])
 122                 else
 123                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 124                         ANDROID_SDK=no
 125                 fi
 126         else
 127                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 128                 ANDROID_SDK=no
 129         fi
 130 fi
 131 if test "x$ANDROID_SDK" != "xno"; then
 132         AC_MSG_CHECKING([Android SDK required extras])
 133         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 134                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 135                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 136                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 137                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 138                 else
 139                         AC_MSG_NOTICE([Google Play Services library not installed.])
 140                         ANDROID_SDK=no
 141                 fi
 142         else
 143                 AC_MSG_NOTICE([Android Support Library not installed.])
 144                 ANDROID_SDK=no
 145         fi
 146 fi
 147
 148 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 149
 150 AC_SUBST(ANDROID_SDK)
 151
 152 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 153             [Set the directory to install the 'fat' distribution files to (defaults to not installing)]),
 154             [FATDIR=$withval], [FATDIR=none])
 155
 156 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 157
 158 AC_SUBST(FATDIR)
 159
 160 AC_PROG_CC
 161 AC_PROG_INSTALL
 162 AC_PROG_LN_S
 163 AC_PROG_LIBTOOL
 164 PKG_PROG_PKG_CONFIG
 165
 166 CFLAGS="-g"
 167 WARN_CFLAGS=""
 168 if test "x$GCC" = "xyes"; then
 169         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 170         -Wmissing-prototypes -Wmissing-declarations \
 171         -Wnested-externs -fno-strict-aliasing"
 172         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 173         [Can use #warning in C files])
 174 fi
 175 AC_SUBST(WARN_CFLAGS)
 176
 177 AC_CHECK_PROG([HAVE_SDCC], [sdcc], yes, no)
 178 if test "x$HAVE_SDCC" = "xno"; then
 179         AC_MSG_ERROR([Please install sdcc to build AltOs])
 180 fi
 181
 182 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 183 if test "x$HAVE_NICKLE" = "xno"; then
 184         AC_MSG_ERROR([Please install nickle to build AltOs])
 185 fi
 186
 187 AC_CHECK_LIB(readline, readline)
 188
 189 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 190
 191 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 192 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 193
 194 PKG_CHECK_MODULES([LIBSTLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 195
 196 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK != xno])
 197
 198 AC_OUTPUT([
 199 Makefile
 200 altoslib/Makefile
 201 altosuilib/Makefile
 202 altosuilib/AltosUIVersion.java
 203 altosui/Makefile
 204 altosui/Info.plist
 205 altosui/altos-windows.nsi
 206 libaltos/Makefile
 207 micropeak/Makefile
 208 micropeak/Info.plist
 209 micropeak/micropeak-windows.nsi
 210 altosdroid/Makefile
 211 altosdroid/local.properties
 212 ao-tools/Makefile
 213 ao-tools/lib/Makefile
 214 ao-tools/ao-rawload/Makefile
 215 ao-tools/ao-dbg/Makefile
 216 ao-tools/ao-bitbang/Makefile
 217 ao-tools/ao-eeprom/Makefile
 218 ao-tools/ao-list/Makefile
 219 ao-tools/ao-load/Makefile
 220 ao-tools/ao-telem/Makefile
 221 ao-tools/ao-stmload/Makefile
 222 ao-tools/ao-send-telem/Makefile
 223 ao-tools/ao-sky-flash/Makefile
 224 ao-tools/ao-dumpflash/Makefile
 225 ao-tools/ao-edit-telem/Makefile
 226 ao-tools/ao-dump-up/Makefile
 227 ao-utils/Makefile
 228 src/Version
 229 ])