git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.9.1f)
  22 ANDROID_VERSION=26
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2019-12-05
  28 AC_SUBST(RELEASE_DATE)
  29
  30 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  31 AC_SUBST(VERSION_DASH)
  32 AC_SUBST(ANDROID_VERSION)
  33
  34 dnl ==========================================================================
  35 dnl Java library versions
  36
  37 ALTOSUILIB_VERSION=13
  38 ALTOSLIB_VERSION=13
  39
  40 AC_SUBST(ALTOSLIB_VERSION)
  41 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  42 AC_SUBST(ALTOSUILIB_VERSION)
  43 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  44
  45 dnl ==========================================================================
  46
  47 AM_CONFIG_HEADER(config.h)
  48
  49 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  50         [Set freetts class path (default /usr/share/java)]),
  51         [FREETTS=$withval], [FREETTS=/usr/share/java])
  52
  53 AC_SUBST(FREETTS)
  54
  55 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  56         [Set jfreechart class path (default /usr/share/java)]),
  57         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  58
  59 AC_SUBST(JFREECHART)
  60
  61 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  62         [Set jcommon class path (default /usr/share/java)]),
  63         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  64
  65 AC_SUBST(JCOMMON)
  66
  67 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm=PATH],
  68         [Set jvm path for java builds (default searches in /usr/lib/jvm)]),
  69         [JVM=$withval], [JVM=auto])
  70
  71 if test "x$JVM" = "xauto"; then
  72         AC_MSG_CHECKING([JVM])
  73         for jvm in default-java java-6-openjdk java-7-openjdk java-8-openjdk java-9-openjdk java-10-openjdk java-11-openjdk java-12-openjdk java-13-openjdk java-6-sun java-8-openjdk-amd64; do
  74                 if test "x$JVM" = "xauto"; then
  75                         INCLUDE="/usr/lib/jvm/$jvm/include"
  76                         if test -f "$INCLUDE"/jni.h; then
  77                                 JVM=/usr/lib/jvm/"$jvm"
  78                         fi
  79                 fi
  80         done
  81         if test "x$JVM" = "xauto"; then
  82                 AC_MSG_ERROR([no JVM files found])
  83         fi
  84         AC_MSG_RESULT([$JVM])
  85 fi
  86
  87 AC_ARG_WITH(java-version, AS_HELP_STRING([--with-java-version=7],
  88                                          [Set java language compatibility version (default is 7)]),
  89            [JAVA_VERSION=$withval], [JAVA_VERSION=7])
  90
  91 JAVAC="$JVM"/bin/javac
  92 JAVA="$JVM"/bin/java
  93 JVM_INCLUDE="$JVM"/include
  94 JAVAC_VERSION_FLAGS="-target 1.$JAVA_VERSION -source 1.$JAVA_VERSION"
  95
  96 AC_SUBST(JAVAC)
  97 AC_SUBST(JAVA)
  98 AC_SUBST(JVM)
  99 AC_SUBST(JVM_INCLUDE)
 100 AC_SUBST(JAVAC_VERSION_FLAGS)
 101
 102
 103 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
 104         [Set android SDK path (default searches in a variety of places)]),
 105         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
 106
 107 if test "x$ANDROID_SDK" = "xauto"; then
 108         AC_MSG_CHECKING([Android SDK])
 109         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
 110                 if test "x$ANDROID_SDK" = "xauto"; then
 111                         SDK="$sdk"
 112                         if test -f "$SDK/SDK Readme.txt"; then
 113                                 ANDROID_SDK=`readlink -m "$SDK"`
 114                         fi
 115                 fi
 116         done
 117         if test "x$ANDROID_SDK" = "xauto"; then
 118                 AC_MSG_NOTICE([no Android SDK found])
 119                 ANDROID_SDK=no
 120         fi
 121         AC_MSG_RESULT([$ANDROID_SDK])
 122 fi
 123 if test "x$ANDROID_SDK" != "xno"; then
 124         AC_MSG_CHECKING([Android SDK version])
 125         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 126         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 127         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 128                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 129                 ANDROID_SDK=no
 130         else
 131                 AC_MSG_RESULT([$SDK_VERSION])
 132         fi
 133 fi
 134 if test "x$ANDROID_SDK" != "xno"; then
 135         AC_MSG_CHECKING([Android SDK API Level])
 136         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 137                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 138                 if test "$API_LEVEL" = "10"; then
 139                         AC_MSG_RESULT([$API_LEVEL])
 140                 else
 141                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 142                         ANDROID_SDK=no
 143                 fi
 144         else
 145                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 146                 ANDROID_SDK=no
 147         fi
 148 fi
 149 if test "x$ANDROID_SDK" != "xno"; then
 150         AC_MSG_CHECKING([Android SDK required extras])
 151         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 152                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 153                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 154                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 155                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 156                 else
 157                         AC_MSG_NOTICE([Google Play Services library not installed.])
 158                         ANDROID_SDK=no
 159                 fi
 160         else
 161                 AC_MSG_NOTICE([Android Support Library not installed.])
 162                 ANDROID_SDK=no
 163         fi
 164 fi
 165
 166 ANDROID_RELEASE=no
 167 if test "x$ANDROID_SDK" != "xno"; then
 168         HAVE_ANDROID_SDK="yes"
 169         ANDROID_RELEASE=yes
 170 else
 171         HAVE_ANDROID_SDK="no"
 172 fi
 173
 174 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 175 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 176
 177 AC_SUBST(ANDROID_SDK)
 178
 179 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 180             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 181             [FATDIR=$withval], [FATDIR=none])
 182
 183 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 184
 185 AC_SUBST(FATDIR)
 186
 187 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 188             [Set the file to read the AltosDroid maps API key from (defaults to ~/altusmetrumllc/google-altosdroid-maps-api-key)]),
 189             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-altosdroid-maps-api-key])
 190
 191 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 192         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 193         HAVE_GOOGLE_KEY="yes"
 194 else
 195         GOOGLEKEY='null'
 196         HAVE_GOOGLE_KEY="no"
 197 fi
 198
 199 WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
 200 AC_SUBST(WARN_CFLAGS)
 201
 202 AC_ARG_ENABLE(faketime, AS_HELP_STRING([--enable-faketime],
 203               [Use faketime program to ensure pdf files are reproducible (default=no)]),
 204               [FAKETIME=$enableval], [FAKETIME=no])
 205
 206 AM_CONDITIONAL(FAKETIME, [test x$FAKETIME = xyes])
 207
 208 AC_SUBST(GOOGLEKEY)
 209
 210 AC_PROG_CC
 211 AC_PROG_INSTALL
 212 AC_PROG_LN_S
 213 AC_PROG_LIBTOOL
 214 PKG_PROG_PKG_CONFIG
 215
 216 WARN_CFLAGS=""
 217 if test "x$GCC" = "xyes"; then
 218         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 219         -Wmissing-prototypes -Wmissing-declarations \
 220         -Wnested-externs -fno-strict-aliasing"
 221         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 222         [Can use #warning in C files])
 223 fi
 224 AC_SUBST(WARN_CFLAGS)
 225
 226 #
 227 # Configure ARM compiler for STM32L and LPC11U14
 228 #
 229
 230 AC_ARG_WITH([arm-cc],
 231             [AS_HELP_STRING([--with-arm-cc],
 232                             [Name of ARM C compiler])],
 233             [],
 234             [with_arm_cc=auto])
 235
 236 if test "x$with_arm_cc" != "xno"; then
 237         if test "x$with_arm_cc" = "xauto"; then
 238                 with_arm_cc="arm-none-eabi-gcc"
 239                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 240         else
 241                 HAVE_ARM_CC=yes
 242         fi
 243 else
 244         HAVE_ARM_CC=no
 245 fi
 246
 247 if test "x$HAVE_ARM_CC" = "xno"; then
 248         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 249 else
 250         ARM_CC=$with_arm_cc
 251 fi
 252 AC_SUBST(HAVE_ARM_CC)
 253 AC_SUBST(ARM_CC)
 254
 255 if test "x$HAVE_ARM_CC" = "xyes"; then
 256         save_CC="$CC"
 257         save_CFLAGS="$CFLAGS"
 258         save_LIBS="$LIBS"
 259         CC="$ARM_CC"
 260         CFLAGS="-mthumb -mcpu=cortex-m0"
 261         LIBS="-ffreestanding -nostdlib"
 262         AC_LANG_PUSH([C])
 263
 264         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 265         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 266                           [HAVE_ARM_M0_CC=yes],
 267                           [HAVE_ARM_M0_CC=no])
 268         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 269
 270         CFLAGS="-mthumb -mcpu=cortex-m3"
 271         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 272         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 273                           [HAVE_ARM_M3_CC=yes],
 274                           [HAVE_ARM_M3_CC=no])
 275         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 276
 277         AC_LANG_POP([C])
 278         LIBS="$save_LIBS"
 279         CFLAGS="$save_CFLAGS"
 280         CC="$save_CC"
 281 else
 282         HAVE_ARM_M3_CC=no
 283         HAVE_ARM_M0_CC=no
 284 fi
 285 AC_SUBST(HAVE_ARM_M3_CC)
 286 AC_SUBST(HAVE_ARM_M0_CC)
 287
 288 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 289         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 290 fi
 291
 292 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 293         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 294 fi
 295
 296 AC_ARG_WITH([newlib-nano],
 297             [AS_HELP_STRING([--with-newlib-nano],
 298                             [Root of newlib nano install])],
 299             [],
 300             [with_newlib_nano=auto])
 301
 302 HAVE_NEWLIB_NANO=no
 303 if test "x$with_newlib_nano" != "xno"; then
 304         if test "x$with_newlib_nano" = "xauto"; then
 305                 for d in /usr/local/lib/newlib-nano /usr/lib/newlib-nano; do
 306                         if test "x$with_newlib_nano" = "xauto" -a -d "$d"; then
 307                                 with_newlib_nano="$d"
 308                                 HAVE_NEWLIB_NANO=yes
 309                         fi
 310                 done
 311         else
 312                 HAVE_NEWLIB_NANO=yes
 313         fi
 314 fi
 315
 316 if test "x$HAVE_NEWLIB_NANO" = "xno"; then
 317         AC_MSG_WARN([No newlib-nano library found, ARM binaries will not be built])
 318         HAVE_ARM_M3_CC=no
 319         HAVE_ARM_M0_CC=no
 320 else
 321         NEWLIB_NANO="$with_newlib_nano"
 322 fi
 323
 324 AC_SUBST(HAVE_NEWLIB_NANO)
 325 AC_SUBST(NEWLIB_NANO)
 326
 327 #
 328 # Configure AVR compiler
 329 #
 330
 331 AC_ARG_WITH([avr-cc],
 332             [AS_HELP_STRING([--with-avr-cc],
 333                             [Name of AVR C compiler])],
 334             [],
 335             [with_avr_cc=auto])
 336
 337 if test "x$with_avr_cc" != "xno"; then
 338         if test "x$with_avr_cc" = "xauto"; then
 339                 with_avr_cc="avr-gcc"
 340                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 341         else
 342                 HAVE_AVR_CC=yes
 343         fi
 344 else
 345         HAVE_AVR_CC=no
 346 fi
 347
 348 AC_ARG_WITH([avr-objcopy],
 349             [AS_HELP_STRING([--with-avr-objcopy],
 350                             [Name of AVR objcopy])],
 351             [],
 352             [with_avr_objcopy=auto])
 353
 354 if test "x$with_avr_objcopy" != "xno"; then
 355         if test "x$with_avr_objcopy" = "xauto"; then
 356                 with_avr_objcopy="avr-objcopy"
 357                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 358         else
 359                 HAVE_AVR_OBJCOPY=yes
 360         fi
 361 else
 362         HAVE_AVR_OBJCOPY=no
 363 fi
 364
 365 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 366         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 367         HAVE_AVR_CC=no
 368 else
 369         save_CC="$CC"
 370         save_CFLAGS="$CFLAGS"
 371         save_LIBS="$LIBS"
 372
 373         CC="$with_avr_cc"
 374         CFLAGS="-mmcu=attiny85"
 375         AC_LANG_PUSH([C])
 376         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 377         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 378                           [AVR_LINK=yes],
 379                           [AVR_LINK=no])
 380         AC_MSG_RESULT([$AVR_LINK])
 381         AC_LANG_POP([C])
 382
 383         LIBS="$save_LIBS"
 384         CFLAGS="$save_CFLAGS"
 385         CC="$save_CC"
 386
 387         if test "x$AVR_LINK" = xyes; then
 388                 AVR_CC=$with_avr_cc
 389                 AVR_OBJCOPY=$with_avr_objcopy
 390         else
 391                 HAVE_AVR_CC=no;
 392         fi
 393 fi
 394
 395 AC_SUBST(AVR_CC)
 396 AC_SUBST(AVR_OBJCOPY)
 397 AC_SUBST(HAVE_AVR_CC)
 398
 399 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 400 if test "x$HAVE_NICKLE" = "xno"; then
 401         AC_MSG_ERROR([Please install nickle to build AltOs])
 402 fi
 403
 404 AC_CHECK_PROG([HAVE_ASCIIDOCTOR_PDF], [asciidoctor-pdf], yes, no)
 405 if test "x$HAVE_ASCIIDOCTOR_PDF" = "xno"; then
 406         AC_MSG_WARN([asciidoctor-pdf not found, PDF docs will not be built])
 407 fi
 408 AM_CONDITIONAL([ASCIIDOCTOR_PDF], [test x$HAVE_ASCIIDOCTOR_PDF != xno])
 409
 410 AC_ARG_WITH([strip-nondeterminism],
 411             [AS_HELP_STRING([--with-strip-nondeterminism],
 412                             [Name of non-deterministic build data stripping tool])],
 413             [],
 414             [with_strip_nondeterminism=auto])
 415
 416 if test "x$with_strip_nondeterminism" != "xno"; then
 417         if test "x$with_strip_nondeterminism" = "xauto"; then
 418                 with_strip_nondeterminism="strip-nondeterminism"
 419                 AC_CHECK_PROG([HAVE_STRIP_NONDETERMINISM],[$with_strip_nondeterminism], yes, no)
 420         else
 421                 HAVE_STRIP_NONDETERMINISM=yes
 422         fi
 423 else
 424         HAVE_STRIP_NONDETERMINISM=no
 425 fi
 426 AM_CONDITIONAL([STRIP_NONDETERMINISM], [test x$HAVE_STRIP_NONDETERMINISM != xno])
 427 AC_SUBST(STRIP_NONDETERMINISM, "$with_strip_nondeterminism")
 428
 429 PKG_CHECK_MODULES([JANSSON], [jansson])
 430
 431 AC_ARG_WITH([readline],
 432             [AS_HELP_STRING([--with-readline],
 433                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 434               [],
 435               [with_readline=auto])
 436
 437 LIBREADLINE_LIBS=
 438
 439 if test x"$with_readline" != "xno"; then
 440         AC_CHECK_LIB([readline], [main],
 441                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 442                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 443                          [Define if you have libreadline])],
 444                       [if test "x$with_readline" != xauto; then
 445                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 446                        fi],
 447                        -lncurses)
 448 fi
 449
 450 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 451
 452 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 453 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 454
 455 AC_ARG_WITH([stlink],
 456             [AS_HELP_STRING([--with-stlink],
 457                             [Build tools that use the stlink library (default: auto)])],
 458             [],
 459             [with_stlink=auto])
 460
 461 if test x"$with_stlink" != "xno"; then
 462         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 463         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 464                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 465         fi
 466 else
 467         HAVE_STLINK=no
 468 fi
 469
 470 if test x"$HAVE_STLINK" = "xyes"; then
 471         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 472 fi
 473
 474 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 475
 476 AC_ARG_ENABLE([multi-arch],
 477               [AS_HELP_STRING([--enable-multi-arch],
 478                               [enable building both i386 and amd64 libraries (default=auto)])],
 479               [MULTI_ARCH=$enableval],
 480               [MULTI_ARCH=auto])
 481
 482 case x"$MULTI_ARCH" in
 483 xauto)
 484         arch=`uname -m`
 485         case x"$arch" in
 486         xx86_64|xi*86)
 487                 save_CFLAGS="$CFLAGS"
 488                 save_LIBS="$LIBS"
 489                 LIBS="-ldl"
 490                 CFLAGS="-m64"
 491                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 492                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 493                                 [M64_LINK=yes],
 494                                 [M64_LINK=no])
 495                 AC_MSG_RESULT([$M64_LINK])
 496                 CFLAGS="-m32"
 497                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 498                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 499                                 [M32_LINK=yes],
 500                                 [M32_LINK=no])
 501                 AC_MSG_RESULT([$M32_LINK])
 502                 CFLAGS="$save_CFLAGS"
 503                 LIBS="$save_LIBS"
 504                 case x"$M64_LINK"x"$M32_LINK" in
 505                 xyesxyes)
 506                         MULTI_ARCH=yes
 507                         ;;
 508                 *)
 509                         MULTI_ARCH=no
 510                         ;;
 511                 esac
 512                 ;;
 513         *)
 514                 MULTI_ARCH=no
 515                 ;;
 516         esac
 517         ;;
 518 xyes|xno)
 519         ;;
 520 *)
 521         MULTI_ARCH="no"
 522         ;;
 523 esac
 524
 525 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 526
 527 AC_ARG_ENABLE([install-shared-mime-info],
 528               [AS_HELP_STRING([--disable-install-shared-mime-info],
 529                               [disable installing shared mime info files (default=yes)])],
 530               [INSTALL_SHARED_MIME_INFO=$enableval],
 531               [INSTALL_SHARED_MIME_INFO=yes])
 532
 533 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 534
 535 AC_OUTPUT([
 536 Makefile
 537 src/Makedefs
 538 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 539 doc/Makefile
 540 altoslib/Makefile
 541 altoslib/AltosVersion.java
 542 icon/Makefile
 543 altosuilib/Makefile
 544 altosui/Makefile
 545 altosui/Info.plist
 546 altosui/altos-windows.nsi
 547 libaltos/Makefile
 548 micropeak/Makefile
 549 micropeak/Info.plist
 550 micropeak/micropeak-windows.nsi
 551 telegps/Makefile
 552 telegps/Info.plist
 553 telegps/telegps-windows.nsi
 554 altosdroid/Makefile
 555 altosdroid/local.properties
 556 altosdroid/app/src/main/AndroidManifest.xml
 557 altosdroid/app/build.gradle
 558 ao-tools/Makefile
 559 ao-tools/lib/Makefile
 560 ao-tools/ao-rawload/Makefile
 561 ao-tools/ao-dbg/Makefile
 562 ao-tools/ao-bitbang/Makefile
 563 ao-tools/ao-eeprom/Makefile
 564 ao-tools/ao-list/Makefile
 565 ao-tools/ao-load/Makefile
 566 ao-tools/ao-telem/Makefile
 567 ao-tools/ao-stmload/Makefile
 568 ao-tools/ao-send-telem/Makefile
 569 ao-tools/ao-sky-flash/Makefile
 570 ao-tools/ao-dumpflash/Makefile
 571 ao-tools/ao-edit-telem/Makefile
 572 ao-tools/ao-dump-up/Makefile
 573 ao-tools/ao-elftohex/Makefile
 574 ao-tools/ao-usbload/Makefile
 575 ao-tools/ao-flash/Makefile
 576 ao-tools/ao-test-igniter/Makefile
 577 ao-tools/ao-test-baro/Makefile
 578 ao-tools/ao-test-flash/Makefile
 579 ao-tools/ao-cal-accel/Makefile
 580 ao-tools/ao-cal-freq/Makefile
 581 ao-tools/ao-test-gps/Makefile
 582 ao-tools/ao-usbtrng/Makefile
 583 ao-tools/ao-makebin/Makefile
 584 ao-utils/Makefile
 585 map-server/Makefile
 586 map-server/altos-mapd/Makefile
 587 map-server/altos-map/Makefile
 588 map-server/altos-mapj/Makefile
 589 ])
 590
 591 echo ""
 592 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 593 echo ""
 594 echo "  Configuration"
 595 echo "    Arm compiler................: ${ARM_CC}"
 596 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 597 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 598 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 599 echo "    AVR support.................: ${HAVE_AVR_CC}"
 600 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 601 echo "    Android release support.....: ${ANDROID_RELEASE}"
 602 echo "    STlink support..............: ${HAVE_STLINK}"
 603 echo "    Newlib-nano support.........: ${NEWLIB_NANO}"
 604 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 605 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 606 echo "    Strip jar timestamps........: ${STRIP_NONDETERMINISM}"
 607 echo ""
 608 echo "  Java"
 609 echo "    freetts.....................: ${FREETTS}"
 610 echo "    jfreechart..................: ${JFREECHART}"
 611 echo "    jcommon.....................: ${JCOMMON}"
 612 echo "    JVM include.................: ${JVM_INCLUDE}"
 613 echo "    AltosDroid maps API key.....: ${HAVE_GOOGLE_KEY}"
 614 if test x${ANDROID_SDK} != "xno"; then
 615 echo ""
 616 echo "  Android path"
 617 echo "    Android SDK.................: ${ANDROID_SDK}"
 618 fi
 619 echo ""