altosdroid: Use single object to pass data to UI
[fw/altos] / configure.ac
1 dnl
2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
3 dnl
4 dnl  This program is free software; you can redistribute it and/or modify
5 dnl  it under the terms of the GNU General Public License as published by
6 dnl  the Free Software Foundation; either version 2 of the License, or
7 dnl  (at your option) any later version.
8 dnl
9 dnl  This program is distributed in the hope that it will be useful, but
10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12 dnl  General Public License for more details.
13 dnl
14 dnl  You should have received a copy of the GNU General Public License along
15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
17 dnl
18 dnl Process this file with autoconf to create configure.
19
20 AC_PREREQ(2.57)
21 AC_INIT([altos], 1.4.9.2)
22 AC_CONFIG_SRCDIR([src/kernel/ao.h])
23 AM_INIT_AUTOMAKE([foreign dist-bzip2])
24 AM_MAINTAINER_MODE
25
26 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
27 AC_SUBST(VERSION_DASH)
28
29 dnl ==========================================================================
30 dnl Java library versions
31
32 ALTOSUILIB_VERSION=3
33 ALTOSLIB_VERSION=5
34
35 AC_SUBST(ALTOSLIB_VERSION)
36 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
37 AC_SUBST(ALTOSUILIB_VERSION)
38 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
39
40 dnl ==========================================================================
41
42 AM_CONFIG_HEADER(config.h)
43
44 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
45         [Set freetts class path (default /usr/share/java)]),
46         [FREETTS=$withval], [FREETTS=/usr/share/java])
47
48 AC_SUBST(FREETTS)
49
50 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
51         [Set jfreechart class path (default /usr/share/java)]),
52         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
53
54 AC_SUBST(JFREECHART)
55
56 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
57         [Set jcommon class path (default /usr/share/java)]),
58         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
59
60 AC_SUBST(JCOMMON)
61
62 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
63         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
64         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
65
66 if test "x$JVM_INCLUDE" = "xauto"; then
67         AC_MSG_CHECKING([JVM include files])
68         for jvm in default-java java-6-openjdk java-6-sun; do
69                 if test "x$JVM_INCLUDE" = "xauto"; then
70                         INCLUDE="/usr/lib/jvm/$jvm/include"
71                         if test -f "$INCLUDE"/jni.h; then
72                                 JVM_INCLUDE="$INCLUDE"
73                         fi
74                 fi
75         done
76         if test "x$JVM_INCLUDE" = "xauto"; then
77                 AC_MSG_ERROR([no JVM include files found])
78         fi
79         AC_MSG_RESULT([$JVM_INCLUDE])
80 fi
81
82 AC_SUBST(JVM_INCLUDE)
83
84 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
85         [Set android SDK path (default searches in a variety of places)]),
86         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
87
88 if test "x$ANDROID_SDK" = "xauto"; then
89         AC_MSG_CHECKING([Android SDK])
90         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
91                 if test "x$ANDROID_SDK" = "xauto"; then
92                         SDK="$sdk"
93                         if test -f "$SDK/SDK Readme.txt"; then
94                                 ANDROID_SDK=`readlink -m "$SDK"`
95                         fi
96                 fi
97         done
98         if test "x$ANDROID_SDK" = "xauto"; then
99                 AC_MSG_NOTICE([no Android SDK found])
100                 ANDROID_SDK=no
101         fi
102         AC_MSG_RESULT([$ANDROID_SDK])
103 fi
104 if test "x$ANDROID_SDK" != "xno"; then
105         AC_MSG_CHECKING([Android SDK version])
106         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
107         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
108         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
109                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
110                 ANDROID_SDK=no
111         else
112                 AC_MSG_RESULT([$SDK_VERSION])
113         fi
114 fi
115 if test "x$ANDROID_SDK" != "xno"; then
116         AC_MSG_CHECKING([Android SDK API Level])
117         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
118                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
119                 if test "$API_LEVEL" = "10"; then
120                         AC_MSG_RESULT([$API_LEVEL])
121                 else
122                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
123                         ANDROID_SDK=no
124                 fi
125         else
126                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
127                 ANDROID_SDK=no
128         fi
129 fi
130 if test "x$ANDROID_SDK" != "xno"; then
131         AC_MSG_CHECKING([Android SDK required extras])
132         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
133                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
134                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
135                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
136                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
137                 else
138                         AC_MSG_NOTICE([Google Play Services library not installed.])
139                         ANDROID_SDK=no
140                 fi
141         else
142                 AC_MSG_NOTICE([Android Support Library not installed.])
143                 ANDROID_SDK=no
144         fi
145 fi
146
147 if test "x$ANDROID_SDK" != "xno"; then
148         HAVE_ANDROID_SDK="yes"
149 else
150         HAVE_ANDROID_SDK="no"
151 fi
152
153 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
154
155 AC_SUBST(ANDROID_SDK)
156
157 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
158             [Set the directory to install the 'fat' distribution files to (defaults to not installing)]),
159             [FATDIR=$withval], [FATDIR=none])
160
161 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
162
163 AC_SUBST(FATDIR)
164
165 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
166             [Set the file to read the google maps API key from (defaults to ~/altusmetrumllc/google-maps-api-key)]),
167             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-maps-api-key])
168
169 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
170         GOOGLEKEY='"'`cat "$GOOGLEKEYFILE"`'"'
171         HAVE_GOOGLE_KEY="yes"
172 else
173         GOOGLEKEY='null'
174         HAVE_GOOGLE_KEY="no"
175 fi
176
177 AC_SUBST(GOOGLEKEY)
178
179 AC_PROG_CC
180 AC_PROG_INSTALL
181 AC_PROG_LN_S
182 AC_PROG_LIBTOOL
183 PKG_PROG_PKG_CONFIG
184
185 CFLAGS="-g"
186 WARN_CFLAGS=""
187 if test "x$GCC" = "xyes"; then
188         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
189         -Wmissing-prototypes -Wmissing-declarations \
190         -Wnested-externs -fno-strict-aliasing"
191         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
192         [Can use #warning in C files])
193 fi
194 AC_SUBST(WARN_CFLAGS)
195
196 #
197 # Configure SDCC
198 #
199
200 AC_ARG_WITH([sdcc],
201             [AS_HELP_STRING([--with-sdcc],
202                             [Name of SDCC])],
203             [],
204             [with_sdcc=auto])
205
206 if test "x$with_sdcc" != "xno"; then        
207         if test "x$with_sdcc" = "xauto"; then
208                 with_sdcc="sdcc"
209                 AC_CHECK_PROG([HAVE_SDCC],[$with_sdcc], yes, no)
210         else
211                 HAVE_SDCC=yes
212         fi
213 else
214         HAVE_SDCC=no
215 fi
216
217 if test "x$HAVE_SDCC" = "xno"; then
218         AC_MSG_WARN([SDCC not found, cc1111 binaries will not be built])
219 else
220         SDCC=$with_sdcc
221 fi
222
223 AC_SUBST(SDCC)
224 AC_SUBST(HAVE_SDCC)
225
226 #
227 # Configure ARM compiler for STM32L and LPC11U14
228 #
229
230 AC_ARG_WITH([arm-cc],
231             [AS_HELP_STRING([--with-arm-cc],
232                             [Name of ARM C compiler])],
233             [],
234             [with_arm_cc=auto])
235
236 if test "x$with_arm_cc" != "xno"; then      
237         if test "x$with_arm_cc" = "xauto"; then
238                 with_arm_cc="arm-none-eabi-gcc"
239                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
240         else
241                 HAVE_ARM_CC=yes
242         fi
243 else
244         HAVE_ARM_CC=no
245 fi
246
247 if test "x$HAVE_ARM_CC" = "xno"; then
248         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
249 else
250         ARM_CC=$with_arm_cc
251 fi
252 AC_SUBST(HAVE_ARM_CC)
253 AC_SUBST(ARM_CC)
254
255 if test -d pdclib -a x"$HAVE_ARM_CC" = xyes; then
256         PDCLIB_ROOT='$(TOPDIR)/../pdclib-root'
257         PDCLIB_INCLUDES='-I$(TOPDIR)/../pdclib-root/include'
258         PDCLIB_LIBS_M0='-L$(TOPDIR)/../pdclib-root/lib -lpdclib-cortex-m0'
259         PDCLIB_LIBS_M3='-L$(TOPDIR)/../pdclib-root/lib -lpdclib-cortex-m3'
260         HAVE_PDCLIB=yes
261 else
262         PDCLIB_INCLUDES=''
263         PDCLIB_LIBS_M0='-lpdclib-cortex-m0'
264         PDCLIB_LIBS_M3='-lpdclib-cortex-m3'
265         HAVE_PDCLIB=no
266 fi
267
268 AM_CONDITIONAL(PDCLIB, [test x$HAVE_PDCLIB = xyes])
269
270 AC_SUBST(PDCLIB_INCLUDES)
271 AC_SUBST(PDCLIB_LIBS_M0)
272 AC_SUBST(PDCLIB_LIBS_M3)
273 AC_SUBST(PDCLIB_ROOT)
274 AC_SUBST(HAVE_PDCLIB)
275
276 if test "x$HAVE_ARM_CC" = "xyes"; then
277         save_CC="$CC"
278         save_CFLAGS="$CFLAGS"
279         save_LIBS="$LIBS"
280         CC="$ARM_CC"
281         CFLAGS="-mthumb -mcpu=cortex-m0"
282         LIBS="-ffreestanding -nostdlib"
283         AC_LANG_PUSH([C])
284
285         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
286         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
287                           [HAVE_ARM_M0_CC=yes],
288                           [HAVE_ARM_M0_CC=no])
289         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
290
291         CFLAGS="-mthumb -mcpu=cortex-m3"
292         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
293         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
294                           [HAVE_ARM_M3_CC=yes],
295                           [HAVE_ARM_M3_CC=no])
296         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
297
298         if test x$HAVE_PDCLIB != xyes; then
299                 AC_CHECK_LIB(pdclib-cortex-m0,memcpy,
300                              [],
301                              [HAVE_ARM_M0_CC=no])
302
303                 AC_CHECK_LIB(pdclib-cortex-m3,memcpy,
304                              [],
305                              [HAVE_ARM_M3_CC=no])
306         fi
307
308         AC_LANG_POP([C])
309         LIBS="$save_LIBS"
310         CFLAGS="$save_CFLAGS"
311         CC="$save_CC"
312 else
313         HAVE_ARM_M3_CC=no
314         HAVE_ARM_M0_CC=no
315 fi
316 AC_SUBST(HAVE_ARM_M3_CC)
317 AC_SUBST(HAVE_ARM_M0_CC)
318         
319 if test "x$HAVE_ARM_M3_CC" = "xno"; then
320         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
321 fi
322
323 if test "x$HAVE_ARM_M0_CC" = "xno"; then
324         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
325 fi
326
327 #
328 # Configure AVR compiler
329 #
330
331 AC_ARG_WITH([avr-cc],
332             [AS_HELP_STRING([--with-avr-cc],
333                             [Name of AVR C compiler])],
334             [],
335             [with_avr_cc=auto])
336
337 if test "x$with_avr_cc" != "xno"; then      
338         if test "x$with_avr_cc" = "xauto"; then
339                 with_avr_cc="avr-gcc"
340                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
341         else
342                 HAVE_AVR_CC=yes
343         fi
344 else
345         HAVE_AVR_CC=no
346 fi
347
348 AC_ARG_WITH([avr-objcopy],
349             [AS_HELP_STRING([--with-avr-objcopy],
350                             [Name of AVR objcopy])],
351             [],
352             [with_avr_objcopy=auto])
353
354 if test "x$with_avr_objcopy" != "xno"; then         
355         if test "x$with_avr_objcopy" = "xauto"; then
356                 with_avr_objcopy="avr-objcopy"
357                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
358         else
359                 HAVE_AVR_OBJCOPY=yes
360         fi
361 else
362         HAVE_AVR_OBJCOPY=no
363 fi
364
365 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
366         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
367         HAVE_AVR_CC=no
368 else
369         save_CC="$CC"
370         save_CFLAGS="$CFLAGS"
371         save_LIBS="$LIBS"
372
373         CC="$with_avr_cc"
374         CFLAGS="-mmcu=attiny85"
375         AC_LANG_PUSH([C])
376         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
377         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
378                           [AVR_LINK=yes],
379                           [AVR_LINK=no])
380         AC_MSG_RESULT([$AVR_LINK])
381         AC_LANG_POP([C])
382
383         LIBS="$save_LIBS"
384         CFLAGS="$save_CFLAGS"
385         CC="$save_CC"
386
387         if test "x$AVR_LINK" = xyes; then
388                 AVR_CC=$with_avr_cc
389                 AVR_OBJCOPY=$with_avr_objcopy
390         else
391                 HAVE_AVR_CC=no;
392         fi
393 fi
394
395 AC_SUBST(AVR_CC)
396 AC_SUBST(AVR_OBJCOPY)
397 AC_SUBST(HAVE_AVR_CC)
398
399 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
400 if test "x$HAVE_NICKLE" = "xno"; then
401         AC_MSG_ERROR([Please install nickle to build AltOs])
402 fi
403
404 AC_ARG_WITH([readline],
405             [AS_HELP_STRING([--with-readline],
406                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
407               [],
408               [with_readline=auto])
409                               
410 LIBREADLINE_LIBS=
411
412 if test x"$with_readline" != "xno"; then
413         AC_CHECK_LIB([readline], [main],
414                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
415                        AC_DEFINE([HAVE_LIBREADLINE], [1],
416                          [Define if you have libreadline])],
417                       [if test "x$with_readline" != xauto; then
418                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
419                        fi],
420                        -lncurses)
421 fi
422
423 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
424
425 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
426 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
427
428 AC_ARG_WITH([stlink],
429             [AS_HELP_STRING([--with-stlink],
430                             [Build tools that use the stlink library (default: auto)])],
431             [],
432             [with_stlink=auto])
433
434 if test x"$with_stlink" != "xno"; then
435         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
436         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
437                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
438         fi
439 else
440         HAVE_STLINK=no
441 fi
442
443 if test x"$HAVE_STLINK" = "xyes"; then
444         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
445 fi
446
447 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
448
449 AC_ARG_ENABLE([multi-arch],
450               [AS_HELP_STRING([--enable-multi-arch],
451                               [enable building both i386 and amd64 libraries (default=auto)])],
452               [MULTI_ARCH=$enableval],
453               [MULTI_ARCH=auto])
454
455 case x"$MULTI_ARCH" in
456 xauto)
457         arch=`uname -m`
458         case x"$arch" in
459         xx86_64|xi*86)
460                 save_CFLAGS="$CFLAGS"
461                 save_LIBS="$LIBS"
462                 LIBS="-ldl"
463                 CFLAGS="-m64"
464                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
465                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
466                                 [M64_LINK=yes],
467                                 [M64_LINK=no])
468                 AC_MSG_RESULT([$M64_LINK])
469                 CFLAGS="-m32"
470                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
471                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
472                                 [M32_LINK=yes],
473                                 [M32_LINK=no])
474                 AC_MSG_RESULT([$M32_LINK])
475                 CFLAGS="$save_CFLAGS"
476                 LIBS="$save_LIBS"
477                 case x"$M64_LINK"x"$M32_LINK" in
478                 xyesxyes)
479                         MULTI_ARCH=yes
480                         ;;
481                 *)
482                         MULTI_ARCH=no
483                         ;;
484                 esac
485                 ;;
486         *)
487                 MULTI_ARCH=no
488                 ;;
489         esac
490         ;;
491 xyes|xno)
492         ;;
493 *)
494         MULTI_ARCH="no"
495         ;;
496 esac
497         
498 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
499
500 AC_OUTPUT([
501 Makefile
502 src/Makedefs
503 altoslib/Makefile
504 icon/Makefile
505 altosuilib/Makefile
506 altosuilib/AltosUIVersion.java
507 altosui/Makefile
508 altosui/Info.plist
509 altosui/altos-windows.nsi
510 libaltos/Makefile
511 micropeak/Makefile
512 micropeak/Info.plist
513 micropeak/micropeak-windows.nsi
514 telegps/Makefile
515 telegps/Info.plist
516 telegps/telegps-windows.nsi
517 altosdroid/Makefile
518 altosdroid/local.properties
519 ao-tools/Makefile
520 ao-tools/lib/Makefile
521 ao-tools/ao-rawload/Makefile
522 ao-tools/ao-dbg/Makefile
523 ao-tools/ao-bitbang/Makefile
524 ao-tools/ao-eeprom/Makefile
525 ao-tools/ao-list/Makefile
526 ao-tools/ao-load/Makefile
527 ao-tools/ao-telem/Makefile
528 ao-tools/ao-stmload/Makefile
529 ao-tools/ao-send-telem/Makefile
530 ao-tools/ao-sky-flash/Makefile
531 ao-tools/ao-dumpflash/Makefile
532 ao-tools/ao-edit-telem/Makefile
533 ao-tools/ao-dump-up/Makefile
534 ao-tools/ao-elftohex/Makefile
535 ao-tools/ao-usbload/Makefile
536 ao-tools/ao-flash/Makefile
537 ao-tools/ao-test-igniter/Makefile
538 ao-tools/ao-test-baro/Makefile
539 ao-tools/ao-test-flash/Makefile
540 ao-tools/ao-cal-accel/Makefile
541 ao-utils/Makefile
542 src/Version
543 ])
544
545 echo ""
546 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
547 echo ""
548 echo "  Configuration"
549 echo "    Arm compiler................: ${ARM_CC}"
550 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
551 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
552 echo "    SDCC........................: ${SDCC}"
553 echo "    CC1111 support..............: ${HAVE_SDCC}"
554 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
555 echo "    AVR support.................: ${HAVE_AVR_CC}"
556 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
557 echo "    STlink support..............: ${HAVE_STLINK}"
558 echo "    Local pdclib................: ${HAVE_PDCLIB}"
559 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
560 echo ""
561 echo "  Java"
562 echo "    freetts.....................: ${FREETTS}"
563 echo "    jfreechart..................: ${JFREECHART}"
564 echo "    jcommon.....................: ${JCOMMON}"
565 echo "    JVM include.................: ${JVM_INCLUDE}"
566 echo "    Google maps API key.........: ${HAVE_GOOGLE_KEY}"
567 if test x${ANDROID_SDK} != "xno"; then
568 echo ""
569 echo "  Android path"
570 echo "    Android SDK.................: ${ANDROID_SDK}"
571 fi
572 echo ""