altos/stm: Fix typo in stm32l.h
[fw/altos] / configure.ac
1 dnl
2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
3 dnl
4 dnl  This program is free software; you can redistribute it and/or modify
5 dnl  it under the terms of the GNU General Public License as published by
6 dnl  the Free Software Foundation; either version 2 of the License, or
7 dnl  (at your option) any later version.
8 dnl
9 dnl  This program is distributed in the hope that it will be useful, but
10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12 dnl  General Public License for more details.
13 dnl
14 dnl  You should have received a copy of the GNU General Public License along
15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
17 dnl
18 dnl Process this file with autoconf to create configure.
19
20 AC_PREREQ(2.57)
21 AC_INIT([altos], 1.5.9.1)
22 AC_CONFIG_SRCDIR([src/kernel/ao.h])
23 AM_INIT_AUTOMAKE([foreign dist-bzip2])
24 AM_MAINTAINER_MODE
25
26 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
27 AC_SUBST(VERSION_DASH)
28
29 dnl ==========================================================================
30 dnl Java library versions
31
32 ALTOSUILIB_VERSION=3
33 ALTOSLIB_VERSION=5
34
35 AC_SUBST(ALTOSLIB_VERSION)
36 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
37 AC_SUBST(ALTOSUILIB_VERSION)
38 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
39
40 dnl ==========================================================================
41
42 AM_CONFIG_HEADER(config.h)
43
44 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
45         [Set freetts class path (default /usr/share/java)]),
46         [FREETTS=$withval], [FREETTS=/usr/share/java])
47
48 AC_SUBST(FREETTS)
49
50 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
51         [Set jfreechart class path (default /usr/share/java)]),
52         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
53
54 AC_SUBST(JFREECHART)
55
56 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
57         [Set jcommon class path (default /usr/share/java)]),
58         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
59
60 AC_SUBST(JCOMMON)
61
62 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
63         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
64         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
65
66 if test "x$JVM_INCLUDE" = "xauto"; then
67         AC_MSG_CHECKING([JVM include files])
68         for jvm in default-java java-6-openjdk java-6-sun; do
69                 if test "x$JVM_INCLUDE" = "xauto"; then
70                         INCLUDE="/usr/lib/jvm/$jvm/include"
71                         if test -f "$INCLUDE"/jni.h; then
72                                 JVM_INCLUDE="$INCLUDE"
73                         fi
74                 fi
75         done
76         if test "x$JVM_INCLUDE" = "xauto"; then
77                 AC_MSG_ERROR([no JVM include files found])
78         fi
79         AC_MSG_RESULT([$JVM_INCLUDE])
80 fi
81
82 AC_SUBST(JVM_INCLUDE)
83
84 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
85         [Set android SDK path (default searches in a variety of places)]),
86         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
87
88 if test "x$ANDROID_SDK" = "xauto"; then
89         AC_MSG_CHECKING([Android SDK])
90         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
91                 if test "x$ANDROID_SDK" = "xauto"; then
92                         SDK="$sdk"
93                         if test -f "$SDK/SDK Readme.txt"; then
94                                 ANDROID_SDK=`readlink -m "$SDK"`
95                         fi
96                 fi
97         done
98         if test "x$ANDROID_SDK" = "xauto"; then
99                 AC_MSG_NOTICE([no Android SDK found])
100                 ANDROID_SDK=no
101         fi
102         AC_MSG_RESULT([$ANDROID_SDK])
103 fi
104 if test "x$ANDROID_SDK" != "xno"; then
105         AC_MSG_CHECKING([Android SDK version])
106         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
107         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
108         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
109                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
110                 ANDROID_SDK=no
111         else
112                 AC_MSG_RESULT([$SDK_VERSION])
113         fi
114 fi
115 if test "x$ANDROID_SDK" != "xno"; then
116         AC_MSG_CHECKING([Android SDK API Level])
117         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
118                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
119                 if test "$API_LEVEL" = "10"; then
120                         AC_MSG_RESULT([$API_LEVEL])
121                 else
122                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
123                         ANDROID_SDK=no
124                 fi
125         else
126                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
127                 ANDROID_SDK=no
128         fi
129 fi
130 if test "x$ANDROID_SDK" != "xno"; then
131         AC_MSG_CHECKING([Android SDK required extras])
132         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
133                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
134                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
135                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
136                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
137                 else
138                         AC_MSG_NOTICE([Google Play Services library not installed.])
139                         ANDROID_SDK=no
140                 fi
141         else
142                 AC_MSG_NOTICE([Android Support Library not installed.])
143                 ANDROID_SDK=no
144         fi
145 fi
146
147 ANDROID_RELEASE=no
148 if test "x$ANDROID_SDK" != "xno"; then
149         HAVE_ANDROID_SDK="yes"
150         if test -f "$HOME/altusmetrumllc/release.keystore" -a -f "$HOME/altusmetrumllc/Passphrase"; then
151                 ANDROID_RELEASE=yes
152         fi
153 else
154         HAVE_ANDROID_SDK="no"
155 fi
156
157 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
158 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
159
160 AC_SUBST(ANDROID_SDK)
161
162 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
163             [Set the directory to install the 'fat' distribution files to (defaults to not installing)]),
164             [FATDIR=$withval], [FATDIR=none])
165
166 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
167
168 AC_SUBST(FATDIR)
169
170 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
171             [Set the file to read the google maps API key from (defaults to ~/altusmetrumllc/google-maps-api-key)]),
172             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-maps-api-key])
173
174 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
175         GOOGLEKEY='"'`cat "$GOOGLEKEYFILE"`'"'
176         HAVE_GOOGLE_KEY="yes"
177 else
178         GOOGLEKEY='null'
179         HAVE_GOOGLE_KEY="no"
180 fi
181
182 AC_SUBST(GOOGLEKEY)
183
184 AC_PROG_CC
185 AC_PROG_INSTALL
186 AC_PROG_LN_S
187 AC_PROG_LIBTOOL
188 PKG_PROG_PKG_CONFIG
189
190 CFLAGS="-g"
191 WARN_CFLAGS=""
192 if test "x$GCC" = "xyes"; then
193         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
194         -Wmissing-prototypes -Wmissing-declarations \
195         -Wnested-externs -fno-strict-aliasing"
196         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
197         [Can use #warning in C files])
198 fi
199 AC_SUBST(WARN_CFLAGS)
200
201 #
202 # Configure SDCC
203 #
204
205 AC_ARG_WITH([sdcc],
206             [AS_HELP_STRING([--with-sdcc],
207                             [Name of SDCC])],
208             [],
209             [with_sdcc=auto])
210
211 if test "x$with_sdcc" != "xno"; then        
212         if test "x$with_sdcc" = "xauto"; then
213                 with_sdcc="sdcc"
214                 AC_CHECK_PROG([HAVE_SDCC],[$with_sdcc], yes, no)
215         else
216                 HAVE_SDCC=yes
217         fi
218 else
219         HAVE_SDCC=no
220 fi
221
222 if test "x$HAVE_SDCC" = "xno"; then
223         AC_MSG_WARN([SDCC not found, cc1111 binaries will not be built])
224 else
225         SDCC=$with_sdcc
226 fi
227
228 AC_SUBST(SDCC)
229 AC_SUBST(HAVE_SDCC)
230
231 #
232 # Configure ARM compiler for STM32L and LPC11U14
233 #
234
235 AC_ARG_WITH([arm-cc],
236             [AS_HELP_STRING([--with-arm-cc],
237                             [Name of ARM C compiler])],
238             [],
239             [with_arm_cc=auto])
240
241 if test "x$with_arm_cc" != "xno"; then      
242         if test "x$with_arm_cc" = "xauto"; then
243                 with_arm_cc="arm-none-eabi-gcc"
244                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
245         else
246                 HAVE_ARM_CC=yes
247         fi
248 else
249         HAVE_ARM_CC=no
250 fi
251
252 if test "x$HAVE_ARM_CC" = "xno"; then
253         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
254 else
255         ARM_CC=$with_arm_cc
256 fi
257 AC_SUBST(HAVE_ARM_CC)
258 AC_SUBST(ARM_CC)
259
260 if test -d pdclib -a x"$HAVE_ARM_CC" = xyes; then
261         PDCLIB_ROOT='$(TOPDIR)/../pdclib-root'
262         PDCLIB_INCLUDES='-I$(TOPDIR)/../pdclib-root/include'
263         PDCLIB_LIBS_M0='-L$(TOPDIR)/../pdclib-root/lib -lpdclib-cortex-m0'
264         PDCLIB_LIBS_M3='-L$(TOPDIR)/../pdclib-root/lib -lpdclib-cortex-m3'
265         HAVE_PDCLIB=yes
266 else
267         PDCLIB_INCLUDES=''
268         PDCLIB_LIBS_M0='-lpdclib-cortex-m0'
269         PDCLIB_LIBS_M3='-lpdclib-cortex-m3'
270         HAVE_PDCLIB=no
271 fi
272
273 AM_CONDITIONAL(PDCLIB, [test x$HAVE_PDCLIB = xyes])
274
275 AC_SUBST(PDCLIB_INCLUDES)
276 AC_SUBST(PDCLIB_LIBS_M0)
277 AC_SUBST(PDCLIB_LIBS_M3)
278 AC_SUBST(PDCLIB_ROOT)
279 AC_SUBST(HAVE_PDCLIB)
280
281 if test "x$HAVE_ARM_CC" = "xyes"; then
282         save_CC="$CC"
283         save_CFLAGS="$CFLAGS"
284         save_LIBS="$LIBS"
285         CC="$ARM_CC"
286         CFLAGS="-mthumb -mcpu=cortex-m0"
287         LIBS="-ffreestanding -nostdlib"
288         AC_LANG_PUSH([C])
289
290         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
291         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
292                           [HAVE_ARM_M0_CC=yes],
293                           [HAVE_ARM_M0_CC=no])
294         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
295
296         CFLAGS="-mthumb -mcpu=cortex-m3"
297         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
298         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
299                           [HAVE_ARM_M3_CC=yes],
300                           [HAVE_ARM_M3_CC=no])
301         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
302
303         if test x$HAVE_PDCLIB != xyes; then
304                 AC_CHECK_LIB(pdclib-cortex-m0,memcpy,
305                              [],
306                              [HAVE_ARM_M0_CC=no])
307
308                 AC_CHECK_LIB(pdclib-cortex-m3,memcpy,
309                              [],
310                              [HAVE_ARM_M3_CC=no])
311         fi
312
313         AC_LANG_POP([C])
314         LIBS="$save_LIBS"
315         CFLAGS="$save_CFLAGS"
316         CC="$save_CC"
317 else
318         HAVE_ARM_M3_CC=no
319         HAVE_ARM_M0_CC=no
320 fi
321 AC_SUBST(HAVE_ARM_M3_CC)
322 AC_SUBST(HAVE_ARM_M0_CC)
323         
324 if test "x$HAVE_ARM_M3_CC" = "xno"; then
325         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
326 fi
327
328 if test "x$HAVE_ARM_M0_CC" = "xno"; then
329         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
330 fi
331
332 #
333 # Configure AVR compiler
334 #
335
336 AC_ARG_WITH([avr-cc],
337             [AS_HELP_STRING([--with-avr-cc],
338                             [Name of AVR C compiler])],
339             [],
340             [with_avr_cc=auto])
341
342 if test "x$with_avr_cc" != "xno"; then      
343         if test "x$with_avr_cc" = "xauto"; then
344                 with_avr_cc="avr-gcc"
345                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
346         else
347                 HAVE_AVR_CC=yes
348         fi
349 else
350         HAVE_AVR_CC=no
351 fi
352
353 AC_ARG_WITH([avr-objcopy],
354             [AS_HELP_STRING([--with-avr-objcopy],
355                             [Name of AVR objcopy])],
356             [],
357             [with_avr_objcopy=auto])
358
359 if test "x$with_avr_objcopy" != "xno"; then         
360         if test "x$with_avr_objcopy" = "xauto"; then
361                 with_avr_objcopy="avr-objcopy"
362                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
363         else
364                 HAVE_AVR_OBJCOPY=yes
365         fi
366 else
367         HAVE_AVR_OBJCOPY=no
368 fi
369
370 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
371         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
372         HAVE_AVR_CC=no
373 else
374         save_CC="$CC"
375         save_CFLAGS="$CFLAGS"
376         save_LIBS="$LIBS"
377
378         CC="$with_avr_cc"
379         CFLAGS="-mmcu=attiny85"
380         AC_LANG_PUSH([C])
381         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
382         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
383                           [AVR_LINK=yes],
384                           [AVR_LINK=no])
385         AC_MSG_RESULT([$AVR_LINK])
386         AC_LANG_POP([C])
387
388         LIBS="$save_LIBS"
389         CFLAGS="$save_CFLAGS"
390         CC="$save_CC"
391
392         if test "x$AVR_LINK" = xyes; then
393                 AVR_CC=$with_avr_cc
394                 AVR_OBJCOPY=$with_avr_objcopy
395         else
396                 HAVE_AVR_CC=no;
397         fi
398 fi
399
400 AC_SUBST(AVR_CC)
401 AC_SUBST(AVR_OBJCOPY)
402 AC_SUBST(HAVE_AVR_CC)
403
404 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
405 if test "x$HAVE_NICKLE" = "xno"; then
406         AC_MSG_ERROR([Please install nickle to build AltOs])
407 fi
408
409 AC_ARG_WITH([readline],
410             [AS_HELP_STRING([--with-readline],
411                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
412               [],
413               [with_readline=auto])
414                               
415 LIBREADLINE_LIBS=
416
417 if test x"$with_readline" != "xno"; then
418         AC_CHECK_LIB([readline], [main],
419                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
420                        AC_DEFINE([HAVE_LIBREADLINE], [1],
421                          [Define if you have libreadline])],
422                       [if test "x$with_readline" != xauto; then
423                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
424                        fi],
425                        -lncurses)
426 fi
427
428 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
429
430 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
431 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
432
433 AC_ARG_WITH([stlink],
434             [AS_HELP_STRING([--with-stlink],
435                             [Build tools that use the stlink library (default: auto)])],
436             [],
437             [with_stlink=auto])
438
439 if test x"$with_stlink" != "xno"; then
440         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
441         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
442                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
443         fi
444 else
445         HAVE_STLINK=no
446 fi
447
448 if test x"$HAVE_STLINK" = "xyes"; then
449         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
450 fi
451
452 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
453
454 AC_ARG_ENABLE([multi-arch],
455               [AS_HELP_STRING([--enable-multi-arch],
456                               [enable building both i386 and amd64 libraries (default=auto)])],
457               [MULTI_ARCH=$enableval],
458               [MULTI_ARCH=auto])
459
460 case x"$MULTI_ARCH" in
461 xauto)
462         arch=`uname -m`
463         case x"$arch" in
464         xx86_64|xi*86)
465                 save_CFLAGS="$CFLAGS"
466                 save_LIBS="$LIBS"
467                 LIBS="-ldl"
468                 CFLAGS="-m64"
469                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
470                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
471                                 [M64_LINK=yes],
472                                 [M64_LINK=no])
473                 AC_MSG_RESULT([$M64_LINK])
474                 CFLAGS="-m32"
475                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
476                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
477                                 [M32_LINK=yes],
478                                 [M32_LINK=no])
479                 AC_MSG_RESULT([$M32_LINK])
480                 CFLAGS="$save_CFLAGS"
481                 LIBS="$save_LIBS"
482                 case x"$M64_LINK"x"$M32_LINK" in
483                 xyesxyes)
484                         MULTI_ARCH=yes
485                         ;;
486                 *)
487                         MULTI_ARCH=no
488                         ;;
489                 esac
490                 ;;
491         *)
492                 MULTI_ARCH=no
493                 ;;
494         esac
495         ;;
496 xyes|xno)
497         ;;
498 *)
499         MULTI_ARCH="no"
500         ;;
501 esac
502         
503 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
504
505 AC_ARG_ENABLE([install-shared-mime-info],
506               [AS_HELP_STRING([--disable-install-shared-mime-info],
507                               [disable installing shared mime info files (default=yes)])],
508               [INSTALL_SHARED_MIME_INFO=$enableval],
509               [INSTALL_SHARED_MIME_INFO=yes])
510
511 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
512
513 AC_OUTPUT([
514 Makefile
515 src/Makedefs
516 altoslib/Makefile
517 icon/Makefile
518 altosuilib/Makefile
519 altosuilib/AltosUIVersion.java
520 altosui/Makefile
521 altosui/Info.plist
522 altosui/altos-windows.nsi
523 libaltos/Makefile
524 micropeak/Makefile
525 micropeak/Info.plist
526 micropeak/micropeak-windows.nsi
527 telegps/Makefile
528 telegps/Info.plist
529 telegps/telegps-windows.nsi
530 altosdroid/Makefile
531 altosdroid/local.properties
532 ao-tools/Makefile
533 ao-tools/lib/Makefile
534 ao-tools/ao-rawload/Makefile
535 ao-tools/ao-dbg/Makefile
536 ao-tools/ao-bitbang/Makefile
537 ao-tools/ao-eeprom/Makefile
538 ao-tools/ao-list/Makefile
539 ao-tools/ao-load/Makefile
540 ao-tools/ao-telem/Makefile
541 ao-tools/ao-stmload/Makefile
542 ao-tools/ao-send-telem/Makefile
543 ao-tools/ao-sky-flash/Makefile
544 ao-tools/ao-dumpflash/Makefile
545 ao-tools/ao-edit-telem/Makefile
546 ao-tools/ao-dump-up/Makefile
547 ao-tools/ao-elftohex/Makefile
548 ao-tools/ao-usbload/Makefile
549 ao-tools/ao-flash/Makefile
550 ao-tools/ao-test-igniter/Makefile
551 ao-tools/ao-test-baro/Makefile
552 ao-tools/ao-test-flash/Makefile
553 ao-tools/ao-cal-accel/Makefile
554 ao-tools/ao-test-gps/Makefile
555 ao-utils/Makefile
556 src/Version
557 ])
558
559 echo ""
560 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
561 echo ""
562 echo "  Configuration"
563 echo "    Arm compiler................: ${ARM_CC}"
564 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
565 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
566 echo "    SDCC........................: ${SDCC}"
567 echo "    CC1111 support..............: ${HAVE_SDCC}"
568 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
569 echo "    AVR support.................: ${HAVE_AVR_CC}"
570 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
571 echo "    Android release support.....: ${ANDROID_RELEASE}"
572 echo "    STlink support..............: ${HAVE_STLINK}"
573 echo "    Local pdclib................: ${HAVE_PDCLIB}"
574 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
575 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
576 echo ""
577 echo "  Java"
578 echo "    freetts.....................: ${FREETTS}"
579 echo "    jfreechart..................: ${JFREECHART}"
580 echo "    jcommon.....................: ${JCOMMON}"
581 echo "    JVM include.................: ${JVM_INCLUDE}"
582 echo "    Google maps API key.........: ${HAVE_GOOGLE_KEY}"
583 if test x${ANDROID_SDK} != "xno"; then
584 echo ""
585 echo "  Android path"
586 echo "    Android SDK.................: ${ANDROID_SDK}"
587 fi
588 echo ""