git.gag.com Git - fw/altos/blob - ao-bringup/stm/altos.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) : ORIGIN = 0x08000000, LENGTH = 128K
  20         ram (!w) : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 C_STACK_SIZE = 512;
  26
  27 SECTIONS {
  28         . = ORIGIN(rom);
  29
  30         /*
  31          * Rom contents
  32          */
  33
  34         __text_start__ = .;
  35
  36         .text : {
  37                 *(.interrupt)   /* Interrupt vectors */
  38                 *(.text)        /* Executable code */
  39                 *(.rodata)      /* Constants */
  40         } > rom
  41
  42         .ARM.exidx : {
  43                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  44                 __text_end__ = .;
  45         } > rom
  46
  47         . = ORIGIN(ram);
  48         __data_start__ = .;
  49
  50         /* Data -- relocated to RAM, but written to ROM
  51          */
  52         .data : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
  53                 *(.data)        /* initialized data */
  54                 __data_end__ = .;
  55                 __bss_start__ = .;
  56         } >ram
  57
  58         .bss : {
  59                 *(.bss)
  60                 *(COMMON)
  61                 __bss_end__ = .;
  62         } >ram
  63
  64         PROVIDE(__stack__ = . + C_STACK_SIZE);
  65         PROVIDE(end = .);
  66
  67 }
  68
  69 ENTRY(start);
  70
  71