git.gag.com Git - fw/altos/blob - src/stmf0/altos.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) :   ORIGIN = 0x08001000, LENGTH = 28K
  20         ram (!w) :   ORIGIN = 0x20000000, LENGTH = 6k - 128
  21         stack (!w) : ORIGIN = 0x20000000 + 6k - 128, LENGTH = 128
  22 }
  23
  24 INCLUDE registers.ld
  25
  26 EXTERN (stm_interrupt_vector)
  27
  28 SECTIONS {
  29         /*
  30          * Rom contents
  31          */
  32
  33         .interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
  34                 __interrupt_start__ = .;
  35                 __interrupt_rom__ = ORIGIN(rom);
  36                 *(.interrupt)   /* Interrupt vectors */
  37                 __interrupt_end__ = .;
  38         } > ram
  39
  40         .text ORIGIN(rom) + 0x100 : {
  41                 __text_start__ = .;
  42
  43                 /* Ick. What I want is to specify the
  44                  * addresses of some global constants so
  45                  * that I can find them across versions
  46                  * of the application. I can't figure out
  47                  * how to make gnu ld do that, so instead
  48                  * we just load the two files that include
  49                  * these defines in the right order here and
  50                  * expect things to 'just work'. Don't change
  51                  * the contents of those files, ok?
  52                  */
  53                 ao_romconfig.o(.romconfig*)
  54                 ao_product.o(.romconfig*)
  55
  56                 *(.text*)       /* Executable code */
  57                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  58                 *(.rodata*)     /* Constants */
  59
  60         } > rom
  61         __text_end__ = .;
  62
  63         /* Boot data which must live at the start of ram so that
  64          * the application and bootloader share the same addresses.
  65          * This must be all uninitialized data
  66          */
  67         .boot (NOLOAD) : {
  68                 __boot_start__ = .;
  69                 *(.boot)
  70                 . = ALIGN(4);
  71                 __boot_end__ = .;
  72         } >ram
  73
  74         /* Data -- relocated to RAM, but written to ROM
  75          */
  76         .data : {
  77                 __data_start__ = .;
  78                 *(.data)        /* initialized data */
  79                 . = ALIGN(4);
  80                 __data_end__ = .;
  81         } >ram AT>rom
  82
  83         .bss : {
  84                 __bss_start__ = .;
  85                 *(.bss)
  86                 *(COMMON)
  87                 . = ALIGN(4);
  88                 __bss_end__ = .;
  89         } >ram
  90
  91         PROVIDE(end = .);
  92
  93         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  94 }
  95
  96 ENTRY(start);
  97
  98