git.gag.com Git - fw/altos/blob - src/stm32f4/altos.ld

   1 /*
   2  * Copyright © 2018 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom (rx) :   ORIGIN = 0x08001000, LENGTH = 1M - 4k
  21         ram (!w) :   ORIGIN = 0x20000000, LENGTH = 256k - 256
  22         stack (!w) : ORIGIN = 0x20000000 + 256k - 256, LENGTH = 256
  23 }
  24
  25 INCLUDE registers.ld
  26
  27 EXTERN (stm_interrupt_vector)
  28
  29 SECTIONS {
  30         /*
  31          * Rom contents
  32          */
  33
  34         .interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
  35                 __interrupt_start__ = .;
  36                 __interrupt_rom__ = ORIGIN(rom);
  37                 *(.interrupt)   /* Interrupt vectors */
  38                 __interrupt_end__ = .;
  39         } > ram
  40
  41         .text ORIGIN(rom) + 0x100 : {
  42                 __text_start__ = .;
  43
  44                 /* Ick. What I want is to specify the
  45                  * addresses of some global constants so
  46                  * that I can find them across versions
  47                  * of the application. I can't figure out
  48                  * how to make gnu ld do that, so instead
  49                  * we just load the two files that include
  50                  * these defines in the right order here and
  51                  * expect things to 'just work'. Don't change
  52                  * the contents of those files, ok?
  53                  */
  54                 ao_romconfig.o(.romconfig*)
  55                 ao_product.o(.romconfig*)
  56
  57                 *(.text*)       /* Executable code */
  58         } > rom
  59
  60         .ARM.exidx : {
  61                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  62         } > rom
  63
  64         .rodata : {
  65                 *(.rodata*)     /* Constants */
  66         } > rom
  67
  68         __text_end__ = .;
  69
  70         /* Boot data which must live at the start of ram so that
  71          * the application and bootloader share the same addresses.
  72          * This must be all uninitialized data
  73          */
  74         .boot (NOLOAD) : {
  75                 __boot_start__ = .;
  76                 *(.boot)
  77                 . = ALIGN(4);
  78                 __boot_end__ = .;
  79         } >ram
  80
  81         /* Data -- relocated to RAM, but written to ROM
  82          */
  83         .data : {
  84                 _start__ = .;
  85                 *(.data)        /* initialized data */
  86                 . = ALIGN(4);
  87                 _end__ = .;
  88         } >ram AT>rom
  89
  90         .bss : {
  91                 __bss_start__ = .;
  92                 *(.bss)
  93                 *(COMMON)
  94                 . = ALIGN(4);
  95                 __bss_end__ = .;
  96         } >ram
  97
  98         PROVIDE(end = .);
  99
 100         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
 101 }
 102
 103 ENTRY(start);
 104
 105