git.gag.com Git - fw/altos/blob - src/stm/altos-512.ld

   1 /*
   2  * Copyright © 2017 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom (rx) : ORIGIN = 0x08001000, LENGTH = 508K
  21         ram (!w) : ORIGIN = 0x20000000, LENGTH = 81408
  22         stack (!w) : ORIGIN = 0x20013e00, LENGTH = 512
  23 }
  24
  25 INCLUDE registers.ld
  26
  27 EXTERN (stm_interrupt_vector)
  28
  29 SECTIONS {
  30         /*
  31          * Rom contents
  32          */
  33
  34         .text ORIGIN(rom) : {
  35                 __text_start__ = .;
  36                 *(.interrupt)   /* Interrupt vectors */
  37
  38                 . = ORIGIN(rom) + 0x100;
  39
  40
  41                 /* Ick. What I want is to specify the
  42                  * addresses of some global constants so
  43                  * that I can find them across versions
  44                  * of the application. I can't figure out
  45                  * how to make gnu ld do that, so instead
  46                  * we just load the two files that include
  47                  * these defines in the right order here and
  48                  * expect things to 'just work'. Don't change
  49                  * the contents of those files, ok?
  50                  */
  51                 ao_romconfig.o(.romconfig*)
  52                 ao_product.o(.romconfig*)
  53                 *(.text*)       /* Executable code */
  54                 *(.rodata*)     /* Constants */
  55
  56         } > rom
  57
  58         .ARM.exidx : {
  59                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  60         } > rom
  61         __text_end__ = .;
  62
  63         /* Boot data which must live at the start of ram so that
  64          * the application and bootloader share the same addresses.
  65          * This must be all uninitialized data
  66          */
  67         .boot (NOLOAD) : {
  68                 __boot_start__ = .;
  69                 *(.boot)
  70                 . = ALIGN(4);
  71                 __boot_end__ = .;
  72         } >ram
  73
  74         /* Data -- relocated to RAM, but written to ROM
  75          */
  76         .data : {
  77                 _start__ = .;
  78                 *(.data)        /* initialized data */
  79                 . = ALIGN(4);
  80                 _end__ = .;
  81         } >ram AT>rom
  82
  83         .bss : {
  84                 __bss_start__ = .;
  85                 *(.bss)
  86                 *(COMMON)
  87                 . = ALIGN(4);
  88                 __bss_end__ = .;
  89         } >ram
  90
  91         PROVIDE(end = .);
  92
  93         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  94 }
  95
  96 ENTRY(start);
  97
  98