git.gag.com Git - fw/altos/blob - src/lpc/altos-standalone.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) : ORIGIN = 0x00000000, LENGTH = 32K
  20         ram (!w) : ORIGIN = 0x10000000, LENGTH = 4K - 128 - 32
  21         usb (!x) : ORIGIN = 0x20004000 + 2K - 256, LENGTH = 256
  22         stack (!w) : ORIGIN = 0x10000000 + 4K - 128 - 32, LENGTH = 128
  23 }
  24
  25 INCLUDE registers.ld
  26
  27 EXTERN (lpc_interrupt_vector)
  28
  29 SECTIONS {
  30         /*
  31          * Rom contents
  32          */
  33
  34         .text ORIGIN(rom) : {
  35                 __text_start__ = .;
  36                 *(.interrupt)   /* Interrupt vectors */
  37
  38                 . = ORIGIN(rom) + 0x100;
  39
  40                 ao_romconfig.o(.romconfig*)
  41                 ao_product.o(.romconfig*)
  42
  43                 *(.text*)       /* Executable code */
  44                 *(.rodata*)     /* Constants */
  45
  46         } > rom
  47
  48         .ARM.exidx : {
  49                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  50                 __text_end__ = .;
  51         } > rom
  52
  53         /* Boot data which must live at the start of ram so that
  54          * the application and bootloader share the same addresses.
  55          * This must be all uninitialized data
  56          */
  57         .boot (NOLOAD) : {
  58                 __boot_start__ = .;
  59                 *(.boot)
  60                 . = ALIGN(4);
  61                 __boot_end__ = .;
  62         } >ram
  63
  64         /* Data -- relocated to RAM, but written to ROM
  65          */
  66         .data ORIGIN(ram) : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
  67                 __data_start__ = .;
  68                 *(.data)        /* initialized data */
  69                 __data_end__ = .;
  70                 __bss_start__ = .;
  71         } >ram
  72
  73         .bss : {
  74                 *(.bss)
  75                 *(COMMON)
  76                 __bss_end__ = .;
  77         } >ram
  78         PROVIDE(end = .);
  79
  80         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  81 }
  82
  83 ENTRY(start);
  84
  85