git.gag.com Git - fw/altos/blob - src/cortexelf-v1/cortexelf.ld

   1 /*
   2  * Copyright © 2017 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom (rx) :      ORIGIN = 0x08001000, LENGTH = 492K
  21         flash (r) :     ORIGIN = 0x0807c000, LENGTH = 16K
  22         ram (!w) :      ORIGIN = 0x20000000, LENGTH = 81408
  23         stack (!w) :    ORIGIN = 0x20013e00, LENGTH = 512
  24 }
  25
  26 INCLUDE registers.ld
  27
  28 EXTERN (stm_interrupt_vector)
  29
  30 SECTIONS {
  31         /*
  32          * Rom contents
  33          */
  34
  35         .text ORIGIN(rom) : {
  36                 __text_start__ = .;
  37                 *(.interrupt)   /* Interrupt vectors */
  38
  39                 . = ORIGIN(rom) + 0x100;
  40
  41
  42                 /* Ick. What I want is to specify the
  43                  * addresses of some global constants so
  44                  * that I can find them across versions
  45                  * of the application. I can't figure out
  46                  * how to make gnu ld do that, so instead
  47                  * we just load the two files that include
  48                  * these defines in the right order here and
  49                  * expect things to 'just work'. Don't change
  50                  * the contents of those files, ok?
  51                  */
  52                 ao_romconfig.o(.romconfig*)
  53                 ao_product.o(.romconfig*)
  54                 *(.text*)       /* Executable code */
  55                 *(.rodata*)     /* Constants */
  56
  57         } > rom
  58
  59         .ARM.exidx : {
  60                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  61         } > rom
  62         __text_end__ = .;
  63
  64         /* Boot data which must live at the start of ram so that
  65          * the application and bootloader share the same addresses.
  66          * This must be all uninitialized data
  67          */
  68         .boot (NOLOAD) : {
  69                 __boot_start__ = .;
  70                 *(.boot)
  71                 . = ALIGN(4);
  72                 __boot_end__ = .;
  73         } >ram
  74
  75         /* Data -- relocated to RAM, but written to ROM
  76          */
  77         .data : {
  78                 _start__ = .;
  79                 *(.data)        /* initialized data */
  80                 . = ALIGN(4);
  81                 _end__ = .;
  82         } >ram AT>rom
  83
  84         .bss : {
  85                 __bss_start__ = .;
  86                 *(.bss)
  87                 *(COMMON)
  88                 . = ALIGN(4);
  89                 __bss_end__ = .;
  90         } >ram
  91
  92         PROVIDE(end = .);
  93
  94         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  95
  96         __flash__ = ORIGIN(flash);
  97 }
  98
  99 ENTRY(start);
 100
 101