git.gag.com Git - fw/stlink/blob - CMakeLists.txt

   1 project(stlink C)
   2 cmake_minimum_required(VERSION 2.8.7)
   3
   4 include(CheckCCompilerFlag)
   5 find_package(PkgConfig)
   6
   7 set(CMAKE_MODULE_PATH "${CMAKE_MODULE_PATH};${CMAKE_SOURCE_DIR}/cmake/modules")
   8
   9 find_package(LibUSB REQUIRED)
  10 pkg_check_modules(gtk gtk+-3.0)
  11
  12 function(add_cflag_if_supported flag)
  13     string(REPLACE "-" "_" flagclean ${flag})
  14     string(REPLACE "=" "_" flagclean ${flagclean})
  15     string(REPLACE "+" "_" flagclean ${flagclean})
  16     string(REPLACE "," "_" flagclean ${flagclean})
  17     string(TOUPPER ${flagclean} flagclean)
  18
  19     check_c_compiler_flag(${flag} C_SUPPORTS${flagclean})
  20
  21     if (C_SUPPORTS${flagclean})
  22         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
  23     endif()
  24 endfunction()
  25
  26 add_cflag_if_supported("-std=gnu99")
  27 add_cflag_if_supported("-Wall")
  28 add_cflag_if_supported("-Wextra")
  29 add_cflag_if_supported("-Wshadow")
  30 add_cflag_if_supported("-D_FORTIFY_SOURCE=2")
  31 add_cflag_if_supported("-fstrict-aliasing")
  32 add_cflag_if_supported("-Wformat")
  33 add_cflag_if_supported("-Wformat-security")
  34 add_cflag_if_supported("-Wmaybe-uninitialized")
  35 add_cflag_if_supported("-Wmissing-variable-declarations")
  36 add_cflag_if_supported("-Wshorten-64-to-32")
  37 add_cflag_if_supported("-Wimplicit-function-declaration")
  38 add_cflag_if_supported("-Wredundant-decls")
  39 add_cflag_if_supported("-Wundef")
  40 add_cflag_if_supported("-fPIC")
  41
  42 if(${CMAKE_BUILD_TYPE} MATCHES "Debug")
  43     include(CTest)
  44     add_cflag_if_supported("-ggdb")
  45     add_cflag_if_supported("-O0")
  46 elseif()
  47     add_cflag_if_supported("-O2")
  48 endif()
  49
  50 set(HFILES src/stlink-common.h
  51            src/stlink-usb.h
  52            src/stlink-sg.h
  53            src/uglylogging.h
  54            src/mmap.h)
  55
  56 set(CFILES src/stlink-common.c
  57            src/stlink-usb.c
  58            src/stlink-sg.c
  59            src/uglylogging.c
  60            )
  61
  62 include_directories(${LIBUSB_INCLUDE_DIR})
  63 include_directories(src)
  64 include_directories(mingw)
  65
  66 add_library(${PROJECT_NAME} STATIC
  67             ${HFILES} # header files for ide projects generated by cmake
  68             ${CFILES})
  69 target_link_libraries(${PROJECT_NAME} ${LIBUSB_LIBRARIES})
  70
  71 add_executable(st-flash flash/main.c)
  72 target_link_libraries(st-flash ${PROJECT_NAME})
  73
  74 add_executable(st-info src/st-info.c)
  75 target_link_libraries(st-info ${PROJECT_NAME})
  76
  77 add_executable(st-util gdbserver/gdb-remote.c
  78                        gdbserver/gdb-remote.h
  79                        gdbserver/gdb-server.c
  80                        gdbserver/gdb-server.h)
  81 target_link_libraries(st-util ${PROJECT_NAME})
  82
  83 install(TARGETS ${PROJECT_NAME} st-flash st-util st-info
  84         RUNTIME DESTINATION bin
  85         ARCHIVE DESTINATION lib
  86 )
  87
  88 if(NOT MINGW)
  89   list(APPEND CFILES src/st-term.c)
  90   add_executable(st-term src/st-term.c)
  91   target_link_libraries(st-term ${PROJECT_NAME})
  92
  93   install(TARGETS st-term
  94           RUNTIME DESTINATION bin)
  95 endif()
  96
  97 if(gtk_FOUND)
  98   include_directories(${gtk_INCLUDE_DIRS})
  99   set(GUI_SOURCES gui/stlink-gui.c
 100                   gui/stlink-gui.h)
 101
 102   add_executable(stlink-gui-local ${GUI_SOURCES})
 103   set_target_properties(stlink-gui-local PROPERTIES
 104                         COMPILE_FLAGS -DSTLINK_UI_DIR=\\"${CMAKE_CURRENT_SOURCE_DIR}/gui\\")
 105   target_link_libraries(stlink-gui-local stlink ${gtk_LDFLAGS})
 106
 107   set(INSTALLED_UI_DIR ${CMAKE_INSTALL_PREFIX}/share)
 108   add_executable(stlink-gui ${GUI_SOURCES})
 109   set_target_properties(stlink-gui PROPERTIES
 110                         COMPILE_FLAGS -DSTLINK_UI_DIR=\\"${INSTALLED_UI_DIR}\\")
 111   target_link_libraries(stlink-gui stlink ${gtk_LDFLAGS})
 112
 113   install(TARGETS stlink-gui
 114           RUNTIME DESTINATION bin)
 115   install(FILES gui/stlink-gui.ui
 116           DESTINATION ${INSTALLED_UI_DIR})
 117 endif()