git.gag.com Git - fw/sdcc/blob - support/scripts/sdcc.nsi

   1 # sdcc.nsi - NSIS installer script for SDCC
   2 #
   3 # Copyright (c) 2003,2004 Borut Razem
   4 #
   5 # This file is part of sdcc.
   6 #
   7 #  This software is provided 'as-is', without any express or implied
   8 #  warranty.  In no event will the authors be held liable for any damages
   9 #  arising from the use of this software.
  10 #
  11 #  Permission is granted to anyone to use this software for any purpose,
  12 #  including commercial applications, and to alter it and redistribute it
  13 #  freely, subject to the following restrictions:
  14 #
  15 #  1. The origin of this software must not be misrepresented; you must not
  16 #     claim that you wrote the original software. If you use this software
  17 #     in a product, an acknowledgment in the product documentation would be
  18 #     appreciated but is not required.
  19 #  2. Altered source versions must be plainly marked as such, and must not be
  20 #     misrepresented as being the original software.
  21 #  3. This notice may not be removed or altered from any source distribution.
  22 #
  23 #  Borut Razem
  24 #  borut.razem@siol.net
  25
  26 # How to create WIN32 setup.exe
  27 #
  28 # - unpack WIN32 mingw daily snapshot sdcc-snapshot-i586-mingw32msvc-yyyymmdd.zip
  29 #   to a clean directory (the option to create directories should be enambled).
  30 #   A sub directory sdcc is created (referenced as PKGDIR in continuation).
  31 # - copy files sdcc/support/scripts/sdcc.ico and sdcc/support/scripts/sdcc.nsi
  32 #   (this file) from the sdcc CVS snapshot to the PKGDIR directory
  33 # - copy file COPYING from the sdcc CVS snapshot to the PKGDIR directory,
  34 #   rename it to COPYING.TXT and convert file COPYING to DOS format:
  35 #   unix2dos COPYING.TXT
  36 # - run NSIS installer from PKGDIR directory:
  37 #   "c:\Program Files\NSIS\makensis.exe" sdcc.nsi
  38 # - A setup file setup.exe is created in PKGDIR directory.
  39 #   Rename it to sdcc_yyyymmdd_setup.exe and upload it
  40 #   to sdcc download repository at sourceforge.net
  41 #
  42 #
  43 # How to upload secc setup.exe tosourceforge.net
  44 #
  45 # Execute following commands from the cmd prompt:
  46 # - sftp sdcc.sourceforge.net
  47 # - cd /home/groups/s/sd/sdcc/htdocs/snapshots/i586-mingw32msvc-setup
  48 # - put sdcc_yyyymmdd_setup.exe
  49 # - quit
  50
  51
  52 !include "MUI.nsh"
  53
  54 SetCompressor lzma
  55
  56 !define SDCC_ROOT "."
  57
  58 !define FROM_SNAPSHOT
  59
  60 !ifdef FROM_SNAPSHOT
  61 !system "dir ${SDCC_ROOT}\device > NUL" <> 0
  62 !define DEV_ROOT "${SDCC_ROOT}"
  63 !else
  64 !system "dir ${SDCC_ROOT}\device > NUL" = 0
  65 !define DEV_ROOT "${SDCC_ROOT}\device"
  66 !endif
  67
  68 !system "unix2dos ${SDCC_ROOT}\doc\ChangeLog_head.txt" = 0
  69 !system "unix2dos ${SDCC_ROOT}\doc\README.TXT" = 0
  70
  71 InstType "Full (Bin, Doc, Lib, Src)"
  72 InstType "Medium (Bin, Doc, Lib)"
  73 InstType "Compact (Bin, Doc)"
  74
  75 ;--------------------------------
  76 ;Variables
  77
  78 Var MUI_STARTMENUPAGE_VARIABLE
  79
  80 ;--------------------------------
  81 !define MUI_ABORTWARNING
  82
  83 !insertmacro MUI_PAGE_WELCOME
  84 !insertmacro MUI_PAGE_LICENSE "${SDCC_ROOT}\COPYING.TXT"
  85 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "SDCC"
  86 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKLM"
  87 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC"
  88 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "NSIS:StartMenuDir"
  89 !define MUI_STARTMENUPAGE_NODISABLE
  90 !insertmacro MUI_PAGE_STARTMENU Application $MUI_STARTMENUPAGE_VARIABLE
  91 !insertmacro MUI_PAGE_COMPONENTS
  92 !insertmacro MUI_PAGE_DIRECTORY
  93 !insertmacro MUI_PAGE_INSTFILES
  94 !insertmacro MUI_PAGE_FINISH
  95
  96 !insertmacro MUI_UNPAGE_INSTFILES
  97
  98 !insertmacro MUI_LANGUAGE "English"
  99
 100 Name "SDCC"
 101 BrandingText ""
 102 OutFile "setup.exe"
 103 InstallDir "$PROGRAMFILES\SDCC"
 104 ShowInstDetails show
 105 ShowUnInstDetails show
 106
 107 Function .onInit
 108   ;Uninstall the old version, if present
 109   ReadRegStr $R0 HKLM \
 110   "Software\Microsoft\Windows\CurrentVersion\Uninstall\$(^Name)" \
 111   "UninstallString"
 112   StrCmp $R0 "" inst
 113
 114   MessageBox MB_OKCANCEL|MB_ICONEXCLAMATION \
 115   "$(^Name) is already installed. $\n$\nClick 'OK' to remove the \
 116   previous version or 'Cancel' to cancel this upgrade." \
 117   IDOK uninst
 118   Abort
 119
 120 uninst:
 121   ; Run the uninstaller
 122   ClearErrors
 123   ExecWait '$R0 _?=$INSTDIR' ;Do not copy the uninstaller to a temp file
 124
 125   ;IfErrors no_remove_uninstaller
 126   ;  ;You can either use Delete /REBOOTOK in the uninstaller or add some code
 127   ;  ;here to remove to remove the uninstaller. Use a registry key to check
 128   ;  ;whether the user has chosen to uninstall. If you are using an uninstaller
 129   ;  ;components page, make sure all sections are uninstalled.
 130   ;no_remove_uninstaller:
 131
 132   Goto done
 133 inst:
 134
 135   ; Install the new version
 136   MessageBox MB_YESNO|MB_ICONQUESTION "This will install $(^Name). Do you wish to continue?" IDYES +2
 137   Abort
 138
 139 done:
 140 FunctionEnd
 141
 142 Section -Common
 143   SetOutPath "$INSTDIR"
 144   File ".\sdcc.ico"
 145   File "${SDCC_ROOT}\COPYING.TXT"
 146 SectionEnd
 147
 148 Section "SDCC application files"
 149   SectionIn 1 2 3 RO
 150   SetOutPath "$INSTDIR\bin"
 151   File "${SDCC_ROOT}\bin\*.exe"
 152 SectionEnd
 153
 154 Section "SDCC documentation"
 155   SectionIn 1 2 3
 156   SetOutPath "$INSTDIR\doc"
 157   File "${SDCC_ROOT}\doc\ChangeLog_head.txt"
 158   File "${SDCC_ROOT}\doc\README.TXT"
 159 SectionEnd
 160
 161 Section "SDCC include files"
 162   SectionIn 1 2
 163   SetOutPath "$INSTDIR\include\asm\default"
 164   File "${DEV_ROOT}\include\asm\default\features.h"
 165   SetOutPath "$INSTDIR\include\asm\gbz80"
 166   File "${DEV_ROOT}\include\asm\gbz80\features.h"
 167   SetOutPath "$INSTDIR\include\asm\z80"
 168   File "${DEV_ROOT}\include\asm\z80\features.h"
 169   SetOutPath "$INSTDIR\include"
 170   File "${DEV_ROOT}\include\*.h"
 171 SectionEnd
 172
 173 Section "SDCC DS390 library"
 174   SectionIn 1 2
 175   SetOutPath "$INSTDIR\lib\ds390"
 176   File "${DEV_ROOT}\lib\ds390\*.asm"
 177   File "${DEV_ROOT}\lib\ds390\*.rel"
 178   File "${DEV_ROOT}\lib\ds390\*.lib"
 179 SectionEnd
 180
 181 Section "SDCC DS400 library"
 182   SectionIn 1 2
 183   SetOutPath "$INSTDIR\lib\ds400"
 184   File "${DEV_ROOT}\lib\ds400\*.asm"
 185   File "${DEV_ROOT}\lib\ds400\*.rel"
 186   File "${DEV_ROOT}\lib\ds400\*.lib"
 187 SectionEnd
 188
 189 Section "SDCC GBZ80 library"
 190   SectionIn 1 2
 191   SetOutPath "$INSTDIR\lib\gbz80"
 192   File "${DEV_ROOT}\lib\gbz80\*.asm"
 193   File "${DEV_ROOT}\lib\gbz80\*.o"
 194   File "${DEV_ROOT}\lib\gbz80\*.lib"
 195 SectionEnd
 196
 197 Section "SDCC Z80 library"
 198   SectionIn 1 2
 199   SetOutPath "$INSTDIR\lib\z80"
 200   File "${DEV_ROOT}\lib\z80\*.asm"
 201   File "${DEV_ROOT}\lib\z80\*.o"
 202   File "${DEV_ROOT}\lib\z80\*.lib"
 203 SectionEnd
 204
 205 Section "SDCC large model library"
 206   SectionIn 1 2
 207   SetOutPath "$INSTDIR\lib\large"
 208   File "${DEV_ROOT}\lib\large\*.asm"
 209   File "${DEV_ROOT}\lib\large\*.rel"
 210   File "${DEV_ROOT}\lib\large\*.lib"
 211 SectionEnd
 212
 213 Section "SDCC small model library"
 214   SectionIn 1 2
 215   SetOutPath "$INSTDIR\lib\small"
 216   File "${DEV_ROOT}\lib\small\*.asm"
 217   File "${DEV_ROOT}\lib\small\*.rel"
 218   File "${DEV_ROOT}\lib\small\*.lib"
 219 SectionEnd
 220
 221 Section "SDCC HC08 library"
 222   SectionIn 1 2
 223   SetOutPath "$INSTDIR\lib\hc08"
 224   File "${DEV_ROOT}\lib\hc08\*.asm"
 225   File "${DEV_ROOT}\lib\hc08\*.rel"
 226   File "${DEV_ROOT}\lib\hc08\*.lib"
 227 SectionEnd
 228
 229 Section "SDCC library sources"
 230   SectionIn 1
 231   SetOutPath "$INSTDIR\lib\src\ds390\examples"
 232   File "${DEV_ROOT}\lib\src\ds390\examples\MOVED"
 233
 234   SetOutPath "$INSTDIR\lib\src\ds390"
 235   File "${DEV_ROOT}\lib\src\ds390\*.c"
 236   File "${DEV_ROOT}\lib\src\ds390\libds390.lib"
 237   File "${DEV_ROOT}\lib\src\ds390\Makefile"
 238   File "${DEV_ROOT}\lib\src\ds390\Makefile.dep"
 239
 240   SetOutPath "$INSTDIR\lib\src\ds400"
 241   File "${DEV_ROOT}\lib\src\ds400\*.c"
 242   File "${DEV_ROOT}\lib\src\ds400\libds400.lib"
 243   File "${DEV_ROOT}\lib\src\ds400\Makefile"
 244   File "${DEV_ROOT}\lib\src\ds400\Makefile.dep"
 245
 246   SetOutPath "$INSTDIR\lib\src\gbz80"
 247   File "${DEV_ROOT}\lib\src\gbz80\*.c"
 248   File "${DEV_ROOT}\lib\src\gbz80\*.s"
 249   File "${DEV_ROOT}\lib\src\gbz80\gbz80.lib"
 250   File "${DEV_ROOT}\lib\src\gbz80\Makefile"
 251   File "${DEV_ROOT}\lib\src\gbz80\README"
 252
 253   SetOutPath "$INSTDIR\lib\src\z80"
 254   File "${DEV_ROOT}\lib\src\z80\*.c"
 255   File "${DEV_ROOT}\lib\src\z80\*.s"
 256   File "${DEV_ROOT}\lib\src\z80\Makefile"
 257   File "${DEV_ROOT}\lib\src\z80\README"
 258   File "${DEV_ROOT}\lib\src\z80\z80.lib"
 259
 260   SetOutPath "$INSTDIR\lib\src\hc08"
 261   File "${DEV_ROOT}\lib\src\hc08\*.c"
 262   File "${DEV_ROOT}\lib\src\hc08\Makefile"
 263   File "${DEV_ROOT}\lib\src\hc08\hc08.lib"
 264
 265   SetOutPath "$INSTDIR\lib\src"
 266   File "${DEV_ROOT}\lib\src\*.c"
 267 SectionEnd
 268
 269 Section -Icons
 270 !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 271   CreateDirectory "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE"
 272   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\SDCC on the Web.lnk" "$INSTDIR\sdcc.url"
 273   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Uninstall SDCC.lnk" "$INSTDIR\uninstall.exe"
 274   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Documentation.lnk" "$INSTDIR\doc\README.TXT" "" "$INSTDIR\sdcc.ico" "" "" "" ""
 275   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Change Log.lnk" "$INSTDIR\doc\ChangeLog_head.txt" "" "$INSTDIR\sdcc.ico" "" "" "" ""
 276   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\GPL 2 License.lnk" "$INSTDIR\COPYING.TXT"
 277 !insertmacro MUI_STARTMENU_WRITE_END
 278 SectionEnd
 279
 280 Section -INI
 281   WriteIniStr "$INSTDIR\sdcc.url" "InternetShortcut" "URL" "http://sdcc.sourceforge.net/"
 282 SectionEnd
 283
 284 Section -PostInstall
 285   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "DisplayName" "SDCC"
 286   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "UninstallString" "$INSTDIR\uninstall.exe"
 287   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "Publisher" "sdcc.sourceforge.net"
 288   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "URLInfoAbout" "http://sdcc.sourceforge.net/"
 289   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "HelpLink" "http://sdcc.sourceforge.net/"
 290   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "URLUpdateInfo" "http://sdcc.sourceforge.net/"
 291   WriteUninstaller "$INSTDIR\uninstall.exe"
 292 SectionEnd
 293
 294 Section -AddToPath
 295   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Do you want to add $INSTDIR\bin to the PATH?" IDNO +3
 296     Push "$INSTDIR\bin"
 297     Call AddToPath
 298 SectionEnd
 299
 300
 301 ;;;; Uninstaller code ;;;;
 302
 303 Function un.onInit
 304   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" IDYES +2
 305   Abort
 306 FunctionEnd
 307
 308 Function un.onUninstSuccess
 309   HideWindow
 310   MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer."
 311 FunctionEnd
 312
 313 Section Uninstall
 314   !insertmacro MUI_STARTMENU_GETFOLDER Application $MUI_STARTMENUPAGE_VARIABLE
 315
 316   Delete "$INSTDIR\sdcc.url"
 317
 318   DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "NSIS:StartMenuDir"
 319   DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC"
 320
 321   Delete "$INSTDIR\uninstall.exe"
 322   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\GPL 2 License.lnk"
 323   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Change Log.lnk"
 324   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Documentation.lnk"
 325   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Uninstall SDCC.lnk"
 326   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\SDCC on the Web.lnk"
 327
 328   Delete "$INSTDIR\lib\src\hc08\*.c"
 329   Delete "$INSTDIR\lib\src\hc08\hc08.lib"
 330   Delete "$INSTDIR\lib\src\hc08\Makefile"
 331
 332   Delete "$INSTDIR\lib\src\z80\*.c"
 333   Delete "$INSTDIR\lib\src\z80\*.s"
 334   Delete "$INSTDIR\lib\src\z80\z80.lib"
 335   Delete "$INSTDIR\lib\src\z80\README"
 336   Delete "$INSTDIR\lib\src\z80\Makefile"
 337
 338   Delete "$INSTDIR\lib\src\gbz80\*.c"
 339   Delete "$INSTDIR\lib\src\gbz80\*.s"
 340   Delete "$INSTDIR\lib\src\gbz80\gbz80.lib"
 341   Delete "$INSTDIR\lib\src\gbz80\README"
 342   Delete "$INSTDIR\lib\src\gbz80\Makefile"
 343
 344   Delete "$INSTDIR\lib\src\ds390\*.c"
 345   Delete "$INSTDIR\lib\src\ds390\libds390.lib"
 346   Delete "$INSTDIR\lib\src\ds390\Makefile.dep"
 347   Delete "$INSTDIR\lib\src\ds390\Makefile"
 348   Delete "$INSTDIR\lib\src\ds390\examples\MOVED"
 349
 350   Delete "$INSTDIR\lib\src\ds400\*.c"
 351   Delete "$INSTDIR\lib\src\ds400\libds400.lib"
 352   Delete "$INSTDIR\lib\src\ds400\Makefile.dep"
 353   Delete "$INSTDIR\lib\src\ds400\Makefile"
 354
 355   Delete "$INSTDIR\lib\src\*.c"
 356
 357   Delete "$INSTDIR\lib\hc08\*.rel"
 358   Delete "$INSTDIR\lib\hc08\*.asm"
 359   Delete "$INSTDIR\lib\hc08\*.lib"
 360
 361   Delete "$INSTDIR\lib\z80\*.o"
 362   Delete "$INSTDIR\lib\z80\*.asm"
 363   Delete "$INSTDIR\lib\z80\*.lib"
 364
 365   Delete "$INSTDIR\lib\small\*.asm"
 366   Delete "$INSTDIR\lib\small\*.rel"
 367   Delete "$INSTDIR\lib\small\*.lib"
 368
 369   Delete "$INSTDIR\lib\large\*.asm"
 370   Delete "$INSTDIR\lib\large\*.rel"
 371   Delete "$INSTDIR\lib\large\*.lib"
 372
 373   Delete "$INSTDIR\lib\gbz80\*.asm"
 374   Delete "$INSTDIR\lib\gbz80\*.o"
 375   Delete "$INSTDIR\lib\gbz80\*.lib"
 376
 377   Delete "$INSTDIR\lib\ds390\*.asm"
 378   Delete "$INSTDIR\lib\ds390\*.rel"
 379   Delete "$INSTDIR\lib\ds390\*.lib"
 380
 381   Delete "$INSTDIR\lib\ds400\*.asm"
 382   Delete "$INSTDIR\lib\ds400\*.rel"
 383   Delete "$INSTDIR\lib\ds400\*.lib"
 384
 385   Delete "$INSTDIR\include\asm\z80\*.h"
 386   Delete "$INSTDIR\include\asm\gbz80\*.h"
 387   Delete "$INSTDIR\include\asm\default\*.h"
 388   Delete "$INSTDIR\include\*.h"
 389
 390   Delete "$INSTDIR\doc\README.TXT"
 391   Delete "$INSTDIR\doc\ChangeLog_head.txt"
 392
 393   Delete "$INSTDIR\bin\*.exe"
 394
 395   Delete "$INSTDIR\COPYING.TXT"
 396   Delete "$INSTDIR\sdcc.ico"
 397
 398   RMDir "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE"
 399
 400   RMDir "$INSTDIR\lib\src\z80"
 401   RMDir "$INSTDIR\lib\src\gbz80"
 402   RMDir "$INSTDIR\lib\src\ds390\examples"
 403   RMDir "$INSTDIR\lib\src\ds390"
 404   RMDir "$INSTDIR\lib\src\ds400"
 405   RMDir "$INSTDIR\lib\src\hc08"
 406   RMDir "$INSTDIR\lib\src"
 407
 408   RMDir "$INSTDIR\lib\z80"
 409   RMDir "$INSTDIR\lib\small"
 410   RMDir "$INSTDIR\lib\large"
 411   RMDir "$INSTDIR\lib\gbz80"
 412   RMDir "$INSTDIR\lib\ds390"
 413   RMDir "$INSTDIR\lib\ds400"
 414   RMDir "$INSTDIR\lib\hc08"
 415   RMDir "$INSTDIR\lib"
 416
 417   RMDir "$INSTDIR\include\asm\z80"
 418   RMDir "$INSTDIR\include\asm\gbz80"
 419   RMDir "$INSTDIR\include\asm\default"
 420   RMDir "$INSTDIR\include\asm"
 421   RMDir "$INSTDIR\include"
 422
 423   RMDir "$INSTDIR\doc"
 424
 425   RMDir "$INSTDIR\bin"
 426
 427   RMDir "$INSTDIR"
 428
 429   Push "$INSTDIR\bin"
 430   Call un.RemoveFromPath
 431
 432   SetAutoClose true
 433 SectionEnd
 434
 435 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 436 ; Path Manipulation functions                                                 ;
 437 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 438
 439 !verbose 3
 440 !include "WinMessages.NSH"
 441 !verbose 4
 442
 443 ; AddToPath - Adds the given dir to the search path.
 444 ;        Input - head of the stack
 445 ;        Note - Win9x systems requires reboot
 446
 447 Function AddToPath
 448   Exch $0
 449   Push $1
 450   Push $2
 451   Push $3
 452   Push $4
 453
 454   ; don't add if the path doesn't exist
 455   IfFileExists $0 "" AddToPath_done
 456
 457   Call IsNT
 458   Pop $4
 459   StrCmp $4 1 +3
 460     ; Not on NT: read PATH from environment variable
 461     ReadEnvStr $1 PATH
 462     Goto +2
 463     ; On NT: read PATH from registry
 464     ReadRegStr $1 HKCU "Environment" "PATH"
 465   Push "$1;"
 466   Push "$0;"
 467   Call StrStr
 468   Pop $2
 469   StrCmp $2 "" "" AddToPath_done
 470   Push "$1;"
 471   Push "$0\;"
 472   Call StrStr
 473   Pop $2
 474   StrCmp $2 "" "" AddToPath_done
 475   GetFullPathName /SHORT $3 $0
 476   Push "$1;"
 477   Push "$3;"
 478   Call StrStr
 479   Pop $2
 480   StrCmp $2 "" "" AddToPath_done
 481   Push "$1;"
 482   Push "$3\;"
 483   Call StrStr
 484   Pop $2
 485   StrCmp $2 "" "" AddToPath_done
 486
 487   StrCmp $4 1 AddToPath_NT
 488     ; Not on NT
 489     StrCpy $1 $WINDIR 2
 490     FileOpen $1 "$1\autoexec.bat" a
 491     FileSeek $1 -1 END
 492     FileReadByte $1 $2
 493     IntCmp $2 26 0 +2 +2 ; DOS EOF
 494       FileSeek $1 -1 END ; write over EOF
 495     FileWrite $1 "$\r$\nSET PATH=%PATH%;$3$\r$\n"
 496     FileClose $1
 497     SetRebootFlag true
 498     Goto AddToPath_done
 499
 500   AddToPath_NT:
 501     ReadRegStr $1 HKCU "Environment" "PATH"
 502     StrCpy $2 $1 1 -1  ; copy last char
 503     StrCmp $2 ";" 0 +2 ; if last char == ;
 504       StrCpy $1 $1 -1  ; remove last char
 505     StrCmp $1 "" AddToPath_NTdoIt
 506       StrCpy $0 "$1;$0"
 507     AddToPath_NTdoIt:
 508       WriteRegExpandStr HKCU "Environment" "PATH" $0
 509       SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
 510
 511   AddToPath_done:
 512     Pop $4
 513     Pop $3
 514     Pop $2
 515     Pop $1
 516     Pop $0
 517 FunctionEnd
 518
 519 ; RemoveFromPath - Remove a given dir from the path
 520 ;     Input: head of the stack
 521
 522 Function un.RemoveFromPath
 523   Exch $0
 524   Push $1
 525   Push $2
 526   Push $3
 527   Push $4
 528   Push $5
 529   Push $6
 530
 531   IntFmt $6 "%c" 26 ; DOS EOF
 532
 533   Call un.IsNT
 534   Pop $1
 535   StrCmp $1 1 unRemoveFromPath_NT
 536     ; Not on NT
 537     StrCpy $1 $WINDIR 2
 538     FileOpen $1 "$1\autoexec.bat" r
 539     GetTempFileName $4
 540     FileOpen $2 $4 w
 541     GetFullPathName /SHORT $0 $0
 542     StrCpy $0 "SET PATH=%PATH%;$0"
 543     Goto unRemoveFromPath_dosLoop
 544
 545     unRemoveFromPath_dosLoop:
 546       FileRead $1 $3
 547       StrCpy $5 $3 1 -1 ; read last char
 548       StrCmp $5 $6 0 +2 ; if DOS EOF
 549         StrCpy $3 $3 -1 ; remove DOS EOF so we can compare
 550       StrCmp $3 "$0$\r$\n" unRemoveFromPath_dosLoopRemoveLine
 551       StrCmp $3 "$0$\n" unRemoveFromPath_dosLoopRemoveLine
 552       StrCmp $3 "$0" unRemoveFromPath_dosLoopRemoveLine
 553       StrCmp $3 "" unRemoveFromPath_dosLoopEnd
 554       FileWrite $2 $3
 555       Goto unRemoveFromPath_dosLoop
 556       unRemoveFromPath_dosLoopRemoveLine:
 557         SetRebootFlag true
 558         Goto unRemoveFromPath_dosLoop
 559
 560     unRemoveFromPath_dosLoopEnd:
 561       FileClose $2
 562       FileClose $1
 563       StrCpy $1 $WINDIR 2
 564       Delete "$1\autoexec.bat"
 565       CopyFiles /SILENT $4 "$1\autoexec.bat"
 566       Delete $4
 567       Goto unRemoveFromPath_done
 568
 569   unRemoveFromPath_NT:
 570     ReadRegStr $1 HKCU "Environment" "PATH"
 571     StrCpy $5 $1 1 -1 ; copy last char
 572     StrCmp $5 ";" +2  ; if last char != ;
 573       StrCpy $1 "$1;" ; append ;
 574     Push $1
 575     Push "$0;"
 576     Call un.StrStr    ; Find `$0;` in $1
 577     Pop $2            ; pos of our dir
 578     StrCmp $2 "" unRemoveFromPath_done
 579       ; else, it is in path
 580       ; $0 - path to add
 581       ; $1 - path var
 582       StrLen $3 "$0;"
 583       StrLen $4 $2
 584       StrCpy $5 $1 -$4   ; $5 is now the part before the path to remove
 585       StrCpy $6 $2 "" $3 ; $6 is now the part after the path to remove
 586       StrCpy $3 $5$6
 587
 588       StrCpy $5 $3 1 -1  ; copy last char
 589       StrCmp $5 ";" 0 +2 ; if last char == ;
 590         StrCpy $3 $3 -1  ; remove last char
 591
 592       StrCmp $3 "" +3
 593         ; New PATH not empty: update the registry
 594         WriteRegExpandStr HKCU "Environment" "PATH" $3
 595         Goto +2
 596         ; New PATH empty: remove from the registry
 597         DeleteRegValue HKCU "Environment" "PATH"
 598       SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
 599
 600   unRemoveFromPath_done:
 601     Pop $6
 602     Pop $5
 603     Pop $4
 604     Pop $3
 605     Pop $2
 606     Pop $1
 607     Pop $0
 608 FunctionEnd
 609
 610 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 611 ;            Utility Functions            ;
 612 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 613
 614 ; IsNT
 615 ; no input
 616 ; output, top of the stack = 1 if NT or 0 if not
 617 ;
 618 ; Usage:
 619 ;   Call IsNT
 620 ;   Pop $R0
 621 ;  ($R0 at this point is 1 or 0)
 622
 623 !macro IsNT un
 624 Function ${un}IsNT
 625   Push $0
 626   ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" CurrentVersion
 627   StrCmp $0 "" 0 IsNT_yes
 628   ; we are not NT.
 629   Pop $0
 630   Push 0
 631   Return
 632
 633   IsNT_yes:
 634     ; NT!!!
 635     Pop $0
 636     Push 1
 637 FunctionEnd
 638 !macroend
 639 !insertmacro IsNT ""
 640 !insertmacro IsNT "un."
 641
 642 ; StrStr
 643 ; input, top of stack = string to search for
 644 ;        top of stack-1 = string to search in
 645 ; output, top of stack (replaces with the portion of the string remaining)
 646 ; modifies no other variables.
 647 ;
 648 ; Usage:
 649 ;   Push "this is a long ass string"
 650 ;   Push "ass"
 651 ;   Call StrStr
 652 ;   Pop $R0
 653 ;  ($R0 at this point is "ass string")
 654
 655 !macro StrStr un
 656 Function ${un}StrStr
 657 Exch $R1   ; st=haystack,old$R1, $R1=needle
 658   Exch     ; st=old$R1,haystack
 659   Exch $R2 ; st=old$R1,old$R2, $R2=haystack
 660   Push $R3
 661   Push $R4
 662   Push $R5
 663   StrLen $R3 $R1
 664   StrCpy $R4 0
 665   ; $R1=needle
 666   ; $R2=haystack
 667   ; $R3=len(needle)
 668   ; $R4=cnt
 669   ; $R5=tmp
 670   loop:
 671     StrCpy $R5 $R2 $R3 $R4
 672     StrCmp $R5 $R1 done
 673     StrCmp $R5 "" done
 674     IntOp $R4 $R4 + 1
 675     Goto loop
 676 done:
 677   StrCpy $R1 $R2 "" $R4
 678   Pop $R5
 679   Pop $R4
 680   Pop $R3
 681   Pop $R2
 682   Exch $R1
 683 FunctionEnd
 684 !macroend
 685 !insertmacro StrStr ""
 686 !insertmacro StrStr "un."