git.gag.com Git - fw/sdcc/blob - sim/ucsim/configure.in

   1 #!/bin/sh
   2
   3 AC_INIT(.version)
   4 AC_CONFIG_HEADER(ddconfig.h:ddconfig_in.h)
   5
   6 AC_PROG_AWK
   7
   8 AC_MSG_CHECKING(version of the package)
   9 if test -f .version; then
  10   VERSION=`cat .version`
  11   AC_MSG_RESULT($VERSION)
  12 else
  13   VERSION="0.0.0"
  14   AC_MSG_RESULT(unknown using 0.0.0)
  15 fi
  16 VERSIONHI=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $1}'`
  17 VERSIONLO=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $2}'`
  18 VERSIONP=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $3}'`
  19 AC_SUBST(VERSION)
  20 AC_SUBST(VERSIONHI)
  21 AC_SUBST(VERSIONLO)
  22 AC_SUBST(VERSIONP)
  23 AC_DEFINE_UNQUOTED(VERSIONSTR, "${VERSION}")
  24 AC_DEFINE_UNQUOTED(VERSIONHI, $VERSIONHI)
  25 AC_DEFINE_UNQUOTED(VERSIONLO, $VERSIONLO)
  26 AC_DEFINE_UNQUOTED(VERSIONP, $VERSIONP)
  27
  28 # Some options
  29 #==============
  30 AC_ARG_ENABLE(ucsim,
  31 [  --enable-ucsim          compile ucsim frontend],
  32 if test $enable_ucsim != "no"; then
  33     enable_ucsim="yes"
  34 fi,
  35 #default
  36 enable_ucsim="no")
  37 AC_ARG_ENABLE(dlso,
  38 [  --enable-dlso           compile dynamically loadable shared libraries],
  39 if test $enable_dlso != "no"; then
  40     enable_dlso="yes"
  41 fi,
  42 enable_dlso="no")
  43 AC_ARG_ENABLE(51,
  44 [  --disable-51            do not compile simulator for MCS51],
  45 if test $enable_51 != "no"; then
  46     enable_51="yes"
  47 fi,
  48 enable_51="yes")
  49 AC_ARG_ENABLE(avr,
  50 [  --disable-avr           do not compile simulator for AVR],
  51 if test $enable_avr != "no"; then
  52     enable_avr="yes"
  53 fi,
  54 enable_avr="yes")
  55 AC_ARG_ENABLE(z80,
  56 [  --enable-z80            compile simulator for Z80],
  57 if test $enable_z80 != "no"; then
  58     enable_z80="yes"
  59 fi,
  60 enable_z80="no")
  61 AC_ARG_ENABLE(hc08,
  62 [  --enable-hc08            compile simulator for hc08],
  63 if test $enable_hc08 != "no"; then
  64     enable_hc08="yes"
  65 fi,
  66 enable_hc08="yes")
  67 AC_ARG_ENABLE(xa,
  68 [  --enable-xa             compile simulator for XA],
  69 if test $enable_xa != "no"; then
  70     enable_xa="yes"
  71 fi,
  72 enable_xa="no")
  73 AC_ARG_ENABLE(portmon,
  74 [  --enable-serio          compile serio GUI tool (needs curses)],
  75 if test $enable_serio != "no"; then
  76     enable_serio="yes"
  77 fi,
  78 enable_serio="yes")
  79 AC_SUBST(enable_ucsim)
  80 AC_SUBST(enable_dlso)
  81 AC_SUBST(enable_51)
  82 AC_SUBST(enable_avr)
  83 AC_SUBST(enable_z80)
  84 AC_SUBST(enable_hc08)
  85 AC_SUBST(enable_xa)
  86 AC_SUBST(enable_serio)
  87
  88 AC_ARG_ENABLE(statistic,
  89 [  --enable-statistic      compile statistical features (slower simulation)],
  90 if test $enable_statistic != "no"; then
  91    enable_statistic="yes"
  92 fi,
  93 enable_statistic="no")
  94 AC_DEFINE_UNQUOTED(STATISTIC, $enable_statistic)
  95
  96
  97 # Required programs
  98 #-------------------
  99 AC_PROG_CXX
 100 AC_PROG_CXXCPP
 101 AC_PROG_INSTALL
 102 AC_PROG_RANLIB
 103 dnl AC_LANG_CPLUSPLUS
 104
 105 AC_CHECK_PROG(STRIP, strip, strip, :)
 106
 107 AC_LIBTOOL_DLOPEN
 108 dnl AC_LIBTOOL_WIN32_DLL
 109 AC_PROG_LIBTOOL
 110 AC_SUBST(LIBTOOL_DEPS)
 111
 112 AC_LANG_CPLUSPLUS
 113
 114 # Checking for header files.
 115 # ===========================================================================
 116
 117 if test -d /stuff/include; then
 118   CPPFLAGS="$CPPFLAGS -I/stuff/include"
 119 fi
 120
 121 AC_HEADER_STDC
 122 AC_CHECK_HEADERS(getopt.h)
 123 AC_CHECK_HEADERS(unistd.h)
 124 AC_CHECK_HEADER(sys/socket.h,
 125     AC_DEFINE(SOCKET_AVAIL)
 126     AC_DEFINE(HAVE_SYS_SOCKET_H)
 127     AC_EGREP_HEADER(socklen_t,
 128                     sys/socket.h,
 129                     AC_DEFINE_UNQUOTED(SOCKLEN_T, socklen_t),
 130                     AC_DEFINE_UNQUOTED(SOCKLEN_T, uint))
 131 )
 132 AC_CHECK_HEADER(dlfcn.h)
 133 AC_HEADER_DIRENT
 134
 135 # This must be after CXXCPP
 136
 137 AC_CACHE_CHECK(which header file defines FD_ macros, ucsim_cv_fd,
 138 [ucsim_cv_fd="unknown"
 139 AC_EGREP_CPP(yes, [
 140 #include <sys/time.h>
 141 #ifdef FD_ZERO
 142 yes
 143 #endif], ucsim_cv_fd="<sys/time.h>")
 144 AC_EGREP_CPP(yes, [
 145 #include <sys/types.h>
 146 #ifdef FD_ZERO
 147 yes
 148 #endif], ucsim_cv_fd="<sys/types.h>")
 149 AC_EGREP_CPP(yes, [
 150 #include <sys/select.h>
 151 #ifdef FD_ZERO
 152 yes
 153 #endif], ucsim_cv_fd="<sys/types.h>")])
 154
 155 AC_DEFINE(FD_HEADER_OK, 0)
 156 if echo $ucsim_cv_fd|grep time >/dev/null 2>&1; then
 157 AC_DEFINE(FD_NEED_TIME_H, 1)
 158 AC_DEFINE(FD_HEADER_OK, 1)
 159 else
 160 AC_DEFINE(FD_NEED_TIME_H, 0)
 161 fi
 162 if echo $ucsim_cv_fd|grep types >/dev/null 2>&1; then
 163 AC_DEFINE(FD_NEED_TYPES_H, 1)
 164 AC_DEFINE(FD_HEADER_OK, 1)
 165 else
 166 AC_DEFINE(FD_NEED_TYPES_H, 0)
 167 fi
 168 if echo $ucsim_cv_fd|grep select >/dev/null 2>&1; then
 169 AC_DEFINE(FD_NEED_SELECT_H, 1)
 170 AC_DEFINE(FD_HEADER_OK, 1)
 171 else
 172 AC_DEFINE(FD_NEED_SELECT_H, 0)
 173 fi
 174
 175 AC_DEFINE_UNQUOTED(HEADER_FD, ${ucsim_cv_fd})
 176
 177
 178 # Checking for functions/libs
 179 # ===========================================================================
 180 AC_CHECK_LIB(socket,socket)
 181 AC_CHECK_LIB(nsl,xdr_short)
 182 AC_CHECK_LIB(dl,dlopen,
 183 dl_ok="yes"
 184 DL="-ldl",
 185 dl_ok="no"
 186 DL="")
 187 AC_SUBST(dl_ok)
 188 AC_SUBST(DL)
 189 AC_CHECK_LIB(panel,panel_above,
 190 panel_ok="yes"
 191 curses_ok="yes"
 192 CURSES_LIBS="-lpanel -lcurses"
 193 ,
 194 panel_ok="no"
 195 AC_CHECK_LIB(curses,nl,
 196 curses_ok="yes"
 197 CURSES_LIBS="-lcurses"
 198 ,
 199 ncurses_ok="no")
 200 ,
 201 -lcurses)
 202 AC_SUBST(panel_ok)
 203 AC_SUBST(curses_ok)
 204 AC_SUBST(CURSES_LIBS)
 205
 206 AC_FUNC_VPRINTF
 207 AC_CHECK_FUNCS(vsnprintf vasprintf)
 208 AC_CHECK_FUNCS(strlen strcpy strcat strstr strcmp strerror strtok strdup)
 209 AC_CHECK_FUNCS(strchr memcpy)
 210 dnl AC_CHECK_FUNCS(getline)
 211 dnl AC_CHECK_FUNCS(getdelim)
 212 AC_CHECK_FUNCS(fgets)
 213 AC_CHECK_FUNCS(yylex)
 214
 215 AC_CACHE_CHECK(whether scanf knows %a, ucsim_cv_scanf_a,
 216 [echo "a b" >conftest.data
 217 AC_TRY_RUN([
 218 #include <stdio.h>
 219 void main(void)
 220 {
 221   FILE *f;
 222   char *a;
 223   int  i;
 224   if ((f= fopen("conftest.data", "r")) == NULL)
 225     exit(1);
 226   i= fscanf(f, " %a[a-z] ", &a);
 227   fclose(f);
 228   if (i == 0)
 229     exit(2);
 230   if (i == 1)
 231     exit(0);
 232   exit(3);
 233 }],
 234 ucsim_cv_scanf_a="yes",
 235 ucsim_cv_scanf_a="no",
 236 ucsim_cv_scanf_a="unknown")
 237 ])
 238 if test "$ucsim_cv_scanf_a" = "yes"; then
 239   AC_DEFINE(SCANF_A)
 240 fi
 241
 242 AC_CACHE_CHECK(whether getcwd is GNUish, ucsim_cv_getcwd,
 243 [AC_TRY_RUN([
 244 #include <unistd.h>
 245 void main(void)
 246 {
 247   if ((getcwd(NULL, 0)) == NULL)
 248     exit(1);
 249   exit(0);
 250 }],
 251 ucsim_cv_getcwd="yes",
 252 ucsim_cv_getcwd="no",
 253 ucsim_cv_getcwd="unknown")
 254 ])
 255 if test "$ucsim_cv_getcwd" = "yes"; then
 256   AC_DEFINE(GNU_GETCWD)
 257 fi
 258
 259 AC_DEFUN(ucsim_ACCEPT_LENGTH_T,
 260  [AC_CACHE_CHECK([for type of length pointer parameter of accept],
 261    ucsim_cv_accept_length_type,
 262    [ac_save_CPPFLAGS="$CPPFLAGS"
 263     ucsim_cv_accept_length_type=no
 264     for ac_val in int size_t socklen_t; do
 265       CPPFLAGS="$ac_save_CPPFLAGS -DACCEPT_SOCKLEN_T=$ac_val"
 266       AC_TRY_COMPILE([#include <sys/types.h>
 267 #include <sys/socket.h>],
 268         [struct sockaddr a; $ac_val len; accept (0, &a, &len);],
 269         [ucsim_cv_accept_length_type=$ac_val; break])
 270     done
 271     CPPFLAGS="$ac_save_CPPFLAGS"])
 272   if test "$ucsim_cv_accept_length_type" != no; then
 273     AC_DEFINE_UNQUOTED(ACCEPT_SOCKLEN_T, $ucsim_cv_accept_length_type,
 274       [Define to be the type of length parameter of accept (without the \*').])
 275   fi
 276  ]
 277 )
 278 #'
 279
 280 ucsim_ACCEPT_LENGTH_T
 281
 282 # Macro definitions
 283 ###################
 284
 285 # DD_COPT macro checks if the compiler specified as the 1st parameter
 286 # supports option specified as the 2nd parameter
 287 # For example: DD_COPT(CXX, fPIC)
 288
 289 AC_DEFUN(DD_COPT, [
 290 AC_CACHE_CHECK(whether $$1 accepts -$2,ucsim_cv_$1$2,
 291 cat >_test_.c <<EOF
 292 #include <stdio.h>
 293 void main(void) {}
 294 EOF
 295 $$1 -v -$2 -c _test_.c 1>&5 2>&5
 296 if test "$?" = "0"; then
 297   ucsim_cv_$1$2="yes"
 298 else
 299   ucsim_cv_$1$2="no"
 300 fi
 301 rm -f _test_.* a.out)
 302 ])
 303
 304
 305 # Checking characteristics of compilers and other programs
 306 # --------------------------------------------------------
 307
 308 # Cross compiling overrides
 309 # FIXME
 310 if test "$CC" = "i586-mingw32msvc-gcc"; then
 311   ac_cv_c_bigendian=no
 312   ac_cv_sizeof_char=1
 313   ac_cv_sizeof_short=2
 314   ac_cv_sizeof_int=4
 315   ac_cv_sizeof_long=4
 316   ac_cv_sizeof_long_long=4
 317 fi
 318
 319 if test "$cross_compiling" = "no"
 320 then
 321     AC_C_BIGENDIAN
 322 else
 323 #echo "CROSS ENDIAN"
 324     if $CXX -v 2>&1|grep "mingw" >/dev/null 2>&1; then
 325         ac_cv_c_bigendian=no
 326     else
 327         : # FIXME
 328     fi
 329 #echo "CROSS ENDIAN DONE"
 330 fi
 331
 332 AC_CACHE_CHECK(whether preprocessor accepts -MM or -M,ucsim_cv_MM,
 333 echo "#include <stdio.h>" >_test_.c
 334 echo "" >>_test_.c
 335 $CXXCPP -v -MM _test_.c 1>&5 2>&5
 336 if test "$?" = "0"; then
 337   ucsim_cv_MM="-MM"
 338 else
 339   ucsim_cv_MM="-M"
 340 fi
 341 rm -f _test_.*)
 342 M_OR_MM=$ucsim_cv_MM
 343 AC_SUBST(M_OR_MM)
 344
 345 # This is the first time when CFLAGS are set/modified!!
 346
 347 DD_COPT(CXX, ggdb)
 348 if test "$ucsim_cv_CXXggdb" = "yes"; then
 349     if test "$CXXFLAGS"x = x ;then
 350         CXXFLAGS="-ggdb"
 351     else
 352         CXXFLAGS="$CXXFLAGS -ggdb"
 353     fi
 354 fi
 355
 356 DD_COPT(CXX, pipe)
 357 if test "$ucsim_cv_CXXpipe" = "yes"; then
 358   CXXFLAGS="$CXXFLAGS -pipe"
 359 fi
 360
 361 PICOPT=""
 362 SHAREDLIB="no"
 363 DD_COPT(CXX, fPIC)
 364 if test "$ucsim_cv_CXXfPIC" = "yes"; then
 365     PICOPT="-fPIC"
 366 else
 367     DD_COPT(CXX, fpic)
 368     if test "$ucsim_cv_CXXfpic" = "yes"; then
 369         PICOPT="-fpic"
 370     fi
 371 fi
 372 if test "$PICOPT"x != "x"; then
 373     SHAREDLIB="yes"
 374 fi
 375 # If this is Cygwin neither use Position Independant Code
 376 # nor build .so
 377 # Quick + dirty by Bernhard
 378 # FIXME
 379 if $CXX -v 2>&1 | grep -i cygwin 1>&5 2>&5; then
 380     PICOPT=""
 381     SHAREDLIB="no"
 382 fi
 383 AC_SUBST(SHAREDLIB)
 384 AC_SUBST(PICOPT)
 385
 386 dlso_ok="no"
 387 if test $SHAREDLIB = "yes" -a $dl_ok = "yes" -a $enable_dlso = "yes"; then
 388     dlso_ok="yes"
 389 fi
 390 AC_SUBST(dlso_ok)
 391
 392 # Checks for typedefs, structures, and compiler characteristics.
 393 # ===========================================================================
 394
 395 AC_TYPE_SIGNAL
 396 if test "$cross_compiling" = "no"; then
 397 AC_CHECK_SIZEOF(char)
 398 AC_CHECK_SIZEOF(short)
 399 AC_CHECK_SIZEOF(int)
 400 AC_CHECK_SIZEOF(long)
 401 AC_CHECK_SIZEOF(long long)
 402 else
 403     if $CXX -v 2>&1|grep "mingw" >/dev/null 2>&1; then
 404         ac_cv_sizeof_char=1
 405         ac_cv_sizeof_short=2
 406         ac_cv_sizeof_int=4
 407         ac_cv_sizeof_long=4
 408         ac_cv_sizeof_long_long=4
 409     else
 410         : # FIXME
 411     fi
 412 #echo
 413 fi
 414
 415 type_name()
 416 {
 417     if expr "$ac_cv_sizeof_char" '>=' "$1" >/dev/null; then
 418         echo "char"
 419         exit
 420     fi
 421     if expr "$ac_cv_sizeof_short" '>=' "$1" >/dev/null; then
 422         echo "short"
 423         exit
 424     fi
 425     if expr "$ac_cv_sizeof_int" '>=' "$1" >/dev/null; then
 426         echo "int"
 427         exit
 428     fi
 429     if expr "$ac_cv_sizeof_long" '>=' "$1" >/dev/null; then
 430         echo "long"
 431         exit
 432     fi
 433     if expr "$ac_cv_sizeof_long_long" '>=' "$1" >/dev/null; then
 434         echo "long long"
 435         exit
 436     fi
 437     echo "long long"
 438 }
 439
 440 AC_MSG_CHECKING(type name for byte)
 441 TYPE_BYTE=`type_name 1`
 442 AC_MSG_RESULT($TYPE_BYTE)
 443 AC_MSG_CHECKING(type name for word)
 444 TYPE_WORD=`type_name 2`
 445 AC_MSG_RESULT($TYPE_WORD)
 446 AC_MSG_CHECKING(type name for dword)
 447 TYPE_DWORD=`type_name 4`
 448 AC_MSG_RESULT($TYPE_DWORD)
 449 AC_DEFINE_UNQUOTED(TYPE_BYTE, $TYPE_BYTE)
 450 AC_DEFINE_UNQUOTED(TYPE_WORD, $TYPE_WORD)
 451 AC_DEFINE_UNQUOTED(TYPE_DWORD, $TYPE_DWORD)
 452
 453 if echo $TYPE_DWORD|grep short >/dev/null; then
 454     A="h"
 455 elif echo $TYPE_DWORD|grep long >/dev/null; then
 456     A="l"
 457 else
 458     A=""
 459 fi
 460
 461 if echo $TYPE_WORD|grep short >/dev/null; then M="h"
 462 elif echo $TYPE_WORD|grep long >/dev/null; then M="l"
 463 else M=""
 464 fi
 465
 466 AC_DEFINE_UNQUOTED(_A_, "${A}")
 467 AC_DEFINE_UNQUOTED(_M_, "${M}")
 468
 469 # *nix default: "${datadir}/sdcc/doc"
 470 AC_ARG_VAR(docdir, documentation installation directory)
 471 if test "${docdir}" = ""; then
 472     docdir="\${datadir}"/sdcc/doc
 473 fi
 474 AC_SUBST(docdir)
 475
 476 # Generating output files
 477 # ===========================================================================
 478
 479 AC_OUTPUT(main.mk:main_in.mk
 480 packages.mk:packages_in.mk
 481 sim.src/Makefile
 482 cmd.src/Makefile
 483 s51.src/Makefile
 484 avr.src/Makefile
 485 z80.src/Makefile
 486 hc08.src/Makefile
 487 xa.src/Makefile
 488 gui.src/Makefile
 489 gui.src/serio.src/Makefile
 490 doc/Makefile
 491 )
 492
 493 #gui.src/portmon.src/Makefile
 494
 495
 496 # End of configure/configure.in