git.gag.com Git - fw/sdcc/blob - sim/ucsim/configure.in

   1 #!/bin/sh
   2
   3 AC_INIT(.version)
   4 AC_CONFIG_HEADER(ddconfig.h:ddconfig_in.h)
   5
   6 AC_PROG_AWK
   7
   8 AC_MSG_CHECKING(version of the package)
   9 if test -f .version; then
  10   VERSION=`cat .version`
  11   AC_MSG_RESULT($VERSION)
  12 else
  13   VERSION="0.0.0"
  14   AC_MSG_RESULT(unknown using 0.0.0)
  15 fi
  16 VERSIONHI=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $1}'`
  17 VERSIONLO=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $2}'`
  18 VERSIONP=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $3}'`
  19 AC_SUBST(VERSION)
  20 AC_SUBST(VERSIONHI)
  21 AC_SUBST(VERSIONLO)
  22 AC_SUBST(VERSIONP)
  23 AC_DEFINE_UNQUOTED(VERSIONSTR, "${VERSION}")
  24 AC_DEFINE_UNQUOTED(VERSIONHI, $VERSIONHI)
  25 AC_DEFINE_UNQUOTED(VERSIONLO, $VERSIONLO)
  26 AC_DEFINE_UNQUOTED(VERSIONP, $VERSIONP)
  27
  28 # Some options
  29 #==============
  30 # *nix default: "${datadir}/sdcc/doc"
  31 AC_ARG_VAR(docdir, documentation installation directory)
  32 if test "${docdir}" = ""; then
  33     docdir="\${datadir}"/sdcc/doc
  34 fi
  35 AC_SUBST(docdir)
  36
  37 AC_ARG_ENABLE(ucsim,
  38 [  --enable-ucsim          compile ucsim frontend],
  39 if test $enable_ucsim != "no"; then
  40     enable_ucsim="yes"
  41 fi,
  42 #default
  43 enable_ucsim="no")
  44 AC_ARG_ENABLE(dlso,
  45 [  --enable-dlso           compile dynamically loadable shared libraries],
  46 if test $enable_dlso != "no"; then
  47     enable_dlso="yes"
  48 fi,
  49 enable_dlso="no")
  50 AC_ARG_ENABLE(51,
  51 [  --disable-51            do not compile simulator for MCS51],
  52 if test $enable_51 != "no"; then
  53     enable_51="yes"
  54 fi,
  55 enable_51="yes")
  56 AC_ARG_ENABLE(avr,
  57 [  --disable-avr           do not compile simulator for AVR],
  58 if test $enable_avr != "no"; then
  59     enable_avr="yes"
  60 fi,
  61 enable_avr="yes")
  62 AC_ARG_ENABLE(z80,
  63 [  --enable-z80            compile simulator for Z80],
  64 if test $enable_z80 != "no"; then
  65     enable_z80="yes"
  66 fi,
  67 enable_z80="no")
  68 AC_ARG_ENABLE(hc08,
  69 [  --enable-hc08           compile simulator for hc08],
  70 if test $enable_hc08 != "no"; then
  71     enable_hc08="yes"
  72 fi,
  73 enable_hc08="yes")
  74 AC_ARG_ENABLE(xa,
  75 [  --enable-xa             compile simulator for XA],
  76 if test $enable_xa != "no"; then
  77     enable_xa="yes"
  78 fi,
  79 enable_xa="no")
  80 AC_ARG_ENABLE(portmon,
  81 [  --enable-serio          compile serio GUI tool (needs curses)],
  82 if test $enable_serio != "no"; then
  83     enable_serio="yes"
  84 fi,
  85 enable_serio="yes")
  86 AC_SUBST(enable_ucsim)
  87 AC_SUBST(enable_dlso)
  88 AC_SUBST(enable_51)
  89 AC_SUBST(enable_avr)
  90 AC_SUBST(enable_z80)
  91 AC_SUBST(enable_hc08)
  92 AC_SUBST(enable_xa)
  93 AC_SUBST(enable_serio)
  94
  95 AC_ARG_ENABLE(statistic,
  96 [  --enable-statistic      compile statistical features (slower simulation)],
  97 if test $enable_statistic != "no"; then
  98    enable_statistic="yes"
  99 fi,
 100 enable_statistic="no")
 101 AC_DEFINE_UNQUOTED(STATISTIC, $enable_statistic)
 102
 103
 104 # Required programs
 105 #-------------------
 106 AC_PROG_CXX
 107 AC_PROG_CXXCPP
 108 AC_PROG_INSTALL
 109 AC_PROG_RANLIB
 110 dnl AC_LANG_CPLUSPLUS
 111
 112 AC_CHECK_PROG(STRIP, strip, strip, :)
 113
 114 AC_LIBTOOL_DLOPEN
 115 dnl AC_LIBTOOL_WIN32_DLL
 116 AC_PROG_LIBTOOL
 117 AC_SUBST(LIBTOOL_DEPS)
 118
 119 AC_PROG_LEX
 120 if test ${LEX} = "flex"; then
 121         AC_DEFINE(HAVE_FLEX)
 122 fi
 123 AC_PROG_YACC
 124 AC_CHECK_PROG(BISON_PLUS_PLUS, bison++, bison++, :)
 125
 126
 127 AC_LANG_CPLUSPLUS
 128
 129 # Checking for header files.
 130 # ===========================================================================
 131
 132 if test -d /stuff/include; then
 133   CPPFLAGS="$CPPFLAGS -I/stuff/include"
 134 fi
 135
 136 AC_HEADER_STDC
 137 AC_CHECK_HEADERS(getopt.h)
 138 AC_CHECK_HEADERS(unistd.h)
 139 AC_CHECK_HEADER(sys/socket.h,
 140     AC_DEFINE(SOCKET_AVAIL)
 141     AC_DEFINE(HAVE_SYS_SOCKET_H)
 142     AC_EGREP_HEADER(socklen_t,
 143                     sys/socket.h,
 144                     AC_DEFINE_UNQUOTED(SOCKLEN_T, socklen_t),
 145                     AC_DEFINE_UNQUOTED(SOCKLEN_T, uint))
 146 )
 147 AC_CHECK_HEADER(dlfcn.h)
 148 AC_HEADER_DIRENT
 149
 150 # This must be after CXXCPP
 151
 152 AC_CACHE_CHECK(which header file defines FD_ macros, ucsim_cv_fd,
 153 [ucsim_cv_fd="unknown"
 154 AC_EGREP_CPP(yes, [
 155 #include <sys/time.h>
 156 #ifdef FD_ZERO
 157 yes
 158 #endif], ucsim_cv_fd="<sys/time.h>")
 159 AC_EGREP_CPP(yes, [
 160 #include <sys/types.h>
 161 #ifdef FD_ZERO
 162 yes
 163 #endif], ucsim_cv_fd="<sys/types.h>")
 164 AC_EGREP_CPP(yes, [
 165 #include <sys/select.h>
 166 #ifdef FD_ZERO
 167 yes
 168 #endif], ucsim_cv_fd="<sys/types.h>")])
 169
 170 AC_DEFINE(FD_HEADER_OK, 0)
 171 if echo $ucsim_cv_fd|grep time >/dev/null 2>&1; then
 172 AC_DEFINE(FD_NEED_TIME_H, 1)
 173 AC_DEFINE(FD_HEADER_OK, 1)
 174 else
 175 AC_DEFINE(FD_NEED_TIME_H, 0)
 176 fi
 177 if echo $ucsim_cv_fd|grep types >/dev/null 2>&1; then
 178 AC_DEFINE(FD_NEED_TYPES_H, 1)
 179 AC_DEFINE(FD_HEADER_OK, 1)
 180 else
 181 AC_DEFINE(FD_NEED_TYPES_H, 0)
 182 fi
 183 if echo $ucsim_cv_fd|grep select >/dev/null 2>&1; then
 184 AC_DEFINE(FD_NEED_SELECT_H, 1)
 185 AC_DEFINE(FD_HEADER_OK, 1)
 186 else
 187 AC_DEFINE(FD_NEED_SELECT_H, 0)
 188 fi
 189
 190 AC_DEFINE_UNQUOTED(HEADER_FD, ${ucsim_cv_fd})
 191
 192
 193 # Checking for functions/libs
 194 # ===========================================================================
 195 AC_CHECK_LIB(socket,socket)
 196 AC_CHECK_LIB(nsl,xdr_short)
 197 AC_CHECK_LIB(dl,dlopen,
 198 dl_ok="yes"
 199 DL="-ldl",
 200 dl_ok="no"
 201 DL="")
 202 AC_SUBST(dl_ok)
 203 AC_SUBST(DL)
 204 AC_CHECK_LIB(panel,panel_above,
 205 panel_ok="yes"
 206 curses_ok="yes"
 207 CURSES_LIBS="-lpanel -lcurses"
 208 ,
 209 panel_ok="no"
 210 AC_CHECK_LIB(curses,nl,
 211 curses_ok="yes"
 212 CURSES_LIBS="-lcurses"
 213 ,
 214 ncurses_ok="no")
 215 ,
 216 -lcurses)
 217 AC_SUBST(panel_ok)
 218 AC_SUBST(curses_ok)
 219 AC_SUBST(CURSES_LIBS)
 220
 221 AC_FUNC_VPRINTF
 222 AC_CHECK_FUNCS(vsnprintf)
 223 AC_CHECK_FUNCS(vasprintf)
 224 AC_CHECK_FUNCS(strlen strcpy strcat strstr strcmp strerror strtok strdup)
 225 AC_CHECK_FUNCS(strchr memcpy)
 226 dnl AC_CHECK_FUNCS(getline)
 227 dnl AC_CHECK_FUNCS(getdelim)
 228 AC_CHECK_FUNCS(fgets)
 229 AC_CHECK_FUNCS(yylex)
 230
 231 AC_CACHE_CHECK(whether scanf knows %a, ucsim_cv_scanf_a,
 232 [echo "a b" >conftest.data
 233 AC_TRY_RUN([
 234 #include <stdio.h>
 235 void main(void)
 236 {
 237   FILE *f;
 238   char *a;
 239   int  i;
 240   if ((f= fopen("conftest.data", "r")) == NULL)
 241     exit(1);
 242   i= fscanf(f, " %a[a-z] ", &a);
 243   fclose(f);
 244   if (i == 0)
 245     exit(2);
 246   if (i == 1)
 247     exit(0);
 248   exit(3);
 249 }],
 250 ucsim_cv_scanf_a="yes",
 251 ucsim_cv_scanf_a="no",
 252 ucsim_cv_scanf_a="unknown")
 253 ])
 254 if test "$ucsim_cv_scanf_a" = "yes"; then
 255   AC_DEFINE(SCANF_A)
 256 fi
 257
 258 AC_CACHE_CHECK(whether getcwd is GNUish, ucsim_cv_getcwd,
 259 [AC_TRY_RUN([
 260 #include <unistd.h>
 261 void main(void)
 262 {
 263   if ((getcwd(NULL, 0)) == NULL)
 264     exit(1);
 265   exit(0);
 266 }],
 267 ucsim_cv_getcwd="yes",
 268 ucsim_cv_getcwd="no",
 269 ucsim_cv_getcwd="unknown")
 270 ])
 271 if test "$ucsim_cv_getcwd" = "yes"; then
 272   AC_DEFINE(GNU_GETCWD)
 273 fi
 274
 275 AC_DEFUN(ucsim_ACCEPT_LENGTH_T,
 276  [AC_CACHE_CHECK([for type of length pointer parameter of accept],
 277    ucsim_cv_accept_length_type,
 278    [ac_save_CPPFLAGS="$CPPFLAGS"
 279     ucsim_cv_accept_length_type=no
 280     for ac_val in int size_t socklen_t; do
 281       CPPFLAGS="$ac_save_CPPFLAGS -DACCEPT_SOCKLEN_T=$ac_val"
 282       AC_TRY_COMPILE([#include <sys/types.h>
 283 #include <sys/socket.h>],
 284         [struct sockaddr a; $ac_val len; accept (0, &a, &len);],
 285         [ucsim_cv_accept_length_type=$ac_val; break])
 286     done
 287     CPPFLAGS="$ac_save_CPPFLAGS"])
 288   if test "$ucsim_cv_accept_length_type" != no; then
 289     AC_DEFINE_UNQUOTED(ACCEPT_SOCKLEN_T, $ucsim_cv_accept_length_type,
 290       [Define to be the type of length parameter of accept (without the \*').])
 291   fi
 292  ]
 293 )
 294 #'
 295
 296 ucsim_ACCEPT_LENGTH_T
 297
 298 # Macro definitions
 299 ###################
 300
 301 # DD_COPT macro checks if the compiler specified as the 1st parameter
 302 # supports option specified as the 2nd parameter
 303 # For example: DD_COPT(CXX, fPIC)
 304
 305 AC_DEFUN(DD_COPT, [
 306 AC_CACHE_CHECK(whether $$1 accepts -$2,ucsim_cv_$1$2,
 307 cat >_test_.c <<EOF
 308 #include <stdio.h>
 309 void main(void) {}
 310 EOF
 311 $$1 -v -$2 -c _test_.c 1>&5 2>&5
 312 if test "$?" = "0"; then
 313   ucsim_cv_$1$2="yes"
 314 else
 315   ucsim_cv_$1$2="no"
 316 fi
 317 rm -f _test_.* a.out)
 318 ])
 319
 320
 321 # Checking characteristics of compilers and other programs
 322 # --------------------------------------------------------
 323
 324 # Cross compiling overrides
 325 # FIXME
 326 if test "$CC" = "i586-mingw32msvc-gcc"; then
 327   ac_cv_c_bigendian=no
 328   ac_cv_sizeof_char=1
 329   ac_cv_sizeof_short=2
 330   ac_cv_sizeof_int=4
 331   ac_cv_sizeof_long=4
 332   ac_cv_sizeof_long_long=4
 333 fi
 334
 335 if test "$cross_compiling" = "no"
 336 then
 337     AC_C_BIGENDIAN
 338 else
 339 #echo "CROSS ENDIAN"
 340     if $CXX -v 2>&1|grep "mingw" >/dev/null 2>&1; then
 341         ac_cv_c_bigendian=no
 342     else
 343         : # FIXME
 344     fi
 345 #echo "CROSS ENDIAN DONE"
 346 fi
 347
 348 AC_CACHE_CHECK(whether preprocessor accepts -MM or -M,ucsim_cv_MM,
 349 echo "#include <stdio.h>" >_test_.c
 350 echo "" >>_test_.c
 351 $CXXCPP -v -MM _test_.c 1>&5 2>&5
 352 if test "$?" = "0"; then
 353   ucsim_cv_MM="-MM"
 354 else
 355   ucsim_cv_MM="-M"
 356 fi
 357 rm -f _test_.*)
 358 M_OR_MM=$ucsim_cv_MM
 359 AC_SUBST(M_OR_MM)
 360
 361 # This is the first time when CFLAGS are set/modified!!
 362
 363 DD_COPT(CXX, ggdb)
 364 if test "$ucsim_cv_CXXggdb" = "yes"; then
 365         gopt="-ggdb"
 366 else
 367         gopt="-g"
 368 fi
 369 if test "$CXXFLAGS"x = x ;then
 370         CXXFLAGS="$gopt"
 371 else
 372         CXXFLAGS="$CXXFLAGS $gopt"
 373 fi
 374
 375 DD_COPT(CXX, pipe)
 376 if test "$ucsim_cv_CXXpipe" = "yes"; then
 377   CXXFLAGS="$CXXFLAGS -pipe"
 378 fi
 379
 380 PICOPT=""
 381 SHAREDLIB="no"
 382 DD_COPT(CXX, fPIC)
 383 if test "$ucsim_cv_CXXfPIC" = "yes"; then
 384     PICOPT="-fPIC"
 385 else
 386     DD_COPT(CXX, fpic)
 387     if test "$ucsim_cv_CXXfpic" = "yes"; then
 388         PICOPT="-fpic"
 389     fi
 390 fi
 391 if test "$PICOPT"x != "x"; then
 392     SHAREDLIB="yes"
 393 fi
 394 # If this is Cygwin neither use Position Independant Code
 395 # nor build .so
 396 # Quick + dirty by Bernhard
 397 # FIXME
 398 if $CXX -v 2>&1 | grep -i cygwin 1>&5 2>&5; then
 399     PICOPT=""
 400     SHAREDLIB="no"
 401 fi
 402 AC_SUBST(SHAREDLIB)
 403 AC_SUBST(PICOPT)
 404
 405 dlso_ok="no"
 406 if test $SHAREDLIB = "yes" -a $dl_ok = "yes" -a $enable_dlso = "yes"; then
 407     dlso_ok="yes"
 408 fi
 409 AC_SUBST(dlso_ok)
 410
 411 # Checks for typedefs, structures, and compiler characteristics.
 412 # ===========================================================================
 413
 414 AC_TYPE_SIGNAL
 415 if test "$cross_compiling" = "no"; then
 416 AC_CHECK_SIZEOF(char)
 417 AC_CHECK_SIZEOF(short)
 418 AC_CHECK_SIZEOF(int)
 419 AC_CHECK_SIZEOF(long)
 420 AC_CHECK_SIZEOF(long long)
 421 else
 422     if $CXX -v 2>&1|grep "mingw" >/dev/null 2>&1; then
 423         ac_cv_sizeof_char=1
 424         ac_cv_sizeof_short=2
 425         ac_cv_sizeof_int=4
 426         ac_cv_sizeof_long=4
 427         ac_cv_sizeof_long_long=4
 428     else
 429         : # FIXME
 430     fi
 431 #echo
 432 fi
 433
 434 type_name()
 435 {
 436     if expr "$ac_cv_sizeof_char" '>=' "$1" >/dev/null; then
 437         echo "char"
 438         exit
 439     fi
 440     if expr "$ac_cv_sizeof_short" '>=' "$1" >/dev/null; then
 441         echo "short"
 442         exit
 443     fi
 444     if expr "$ac_cv_sizeof_int" '>=' "$1" >/dev/null; then
 445         echo "int"
 446         exit
 447     fi
 448     if expr "$ac_cv_sizeof_long" '>=' "$1" >/dev/null; then
 449         echo "long"
 450         exit
 451     fi
 452     if expr "$ac_cv_sizeof_long_long" '>=' "$1" >/dev/null; then
 453         echo "long long"
 454         exit
 455     fi
 456     echo "long long"
 457 }
 458
 459 AC_MSG_CHECKING(type name for byte)
 460 TYPE_BYTE=`type_name 1`
 461 AC_MSG_RESULT($TYPE_BYTE)
 462 AC_MSG_CHECKING(type name for word)
 463 TYPE_WORD=`type_name 2`
 464 AC_MSG_RESULT($TYPE_WORD)
 465 AC_MSG_CHECKING(type name for dword)
 466 TYPE_DWORD=`type_name 4`
 467 AC_MSG_RESULT($TYPE_DWORD)
 468 AC_DEFINE_UNQUOTED(TYPE_BYTE, $TYPE_BYTE)
 469 AC_DEFINE_UNQUOTED(TYPE_WORD, $TYPE_WORD)
 470 AC_DEFINE_UNQUOTED(TYPE_DWORD, $TYPE_DWORD)
 471
 472 if echo $TYPE_DWORD|grep short >/dev/null; then
 473     A="h"
 474 elif echo $TYPE_DWORD|grep long >/dev/null; then
 475     A="l"
 476 else
 477     A=""
 478 fi
 479
 480 if echo $TYPE_WORD|grep short >/dev/null; then M="h"
 481 elif echo $TYPE_WORD|grep long >/dev/null; then M="l"
 482 else M=""
 483 fi
 484
 485 AC_DEFINE_UNQUOTED(_A_, "${A}")
 486 AC_DEFINE_UNQUOTED(_M_, "${M}")
 487
 488 # Generating output files
 489 # ===========================================================================
 490
 491 AC_OUTPUT(main.mk:main_in.mk
 492 packages.mk:packages_in.mk
 493 sim.src/Makefile
 494 cmd.src/Makefile
 495 s51.src/Makefile
 496 avr.src/Makefile
 497 z80.src/Makefile
 498 hc08.src/Makefile
 499 xa.src/Makefile
 500 gui.src/Makefile
 501 gui.src/serio.src/Makefile
 502 doc/Makefile
 503 )
 504
 505 #gui.src/portmon.src/Makefile
 506
 507
 508 # End of configure/configure.in