git.gag.com Git - fw/sdcc/blob - configure.in

   1 #!/bin/sh
   2
   3 AC_PREREQ(2.60)
   4 AC_INIT([sdcc], [2.7.2], [sdcc-devel@lists.sourceforge.net])
   5 AC_CONFIG_SRCDIR([Makefile.in])
   6 AC_CONFIG_HEADER(sdccconf.h:sdccconf_in.h)
   7
   8 AC_PROG_AWK
   9
  10 VERSION=$PACKAGE_VERSION
  11 VERSIONHI=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $1}'`
  12 VERSIONLO=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $2}'`
  13 VERSIONP=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $3}'`
  14
  15 AC_MSG_RESULT(${VERSION})
  16 AC_SUBST(VERSION)
  17 AC_SUBST(VERSIONHI)
  18 AC_SUBST(VERSIONLO)
  19 AC_SUBST(VERSIONP)
  20 AC_DEFINE_UNQUOTED(SDCC_VERSION_LO, ${VERSIONLO})
  21 AC_DEFINE_UNQUOTED(SDCC_VERSION_HI, ${VERSIONHI})
  22 AC_DEFINE_UNQUOTED(SDCC_VERSION_P, ${VERSIONP})
  23 AC_DEFINE_UNQUOTED(SDCC_VERSION_STR, "${VERSION}")
  24 AC_ARG_PROGRAM
  25 sdcc_cv_version=$VERSION
  26 sdcc_cv_versionhi=$VERSIONHI
  27 sdcc_cv_versionlo=$VERSIONLO
  28 sdcc_cv_versionp=$VERSIONP
  29
  30
  31 # Required programs
  32 # ===========================================================================
  33 AC_PROG_CC
  34 AC_PROG_CPP
  35 AC_PROG_INSTALL
  36 AC_PROG_RANLIB
  37 AC_CHECK_PROG(AUTOCONF, autoconf, autoconf, :)
  38 AC_CHECK_PROG(STRIP, strip, strip, :)
  39 AC_CHECK_PROG(AS, as, as, :)
  40 AC_CHECK_PROG(CP, cp, cp, :)
  41
  42 dnl Don't use AC_PROG_LEX
  43 dnl LEXLIB is not useful in gcc.
  44 AC_CHECK_PROGS(LEX, flex lex, :)
  45
  46 dnl Don't use AC_PROG_YACC
  47 AC_CHECK_PROGS(YACC, 'bison -y' byacc yacc, :)
  48
  49 AC_DEFUN(SDCC_REQUIRE_PROG,
  50 [if test "$1" = ":"; then
  51   AC_MSG_ERROR([Cannot find required program $2.])
  52  fi
  53 ])
  54
  55 SDCC_REQUIRE_PROG($YACC, bison)
  56 SDCC_REQUIRE_PROG($LEX, flex)
  57
  58 AC_LANG_C
  59
  60
  61 # Checking for functions
  62 # ===========================================================================
  63 AC_CHECK_FUNCS(strerror)
  64 AC_CHECK_FUNCS(vsnprintf snprintf vsprintf mkstemp)
  65
  66
  67 # Macro definitions
  68 # ===========================================================================
  69
  70 # adl_DD_COPT macro checks if the compiler specified as the 1st parameter
  71 # supports option specified as the 2nd parameter
  72 # For example: DD_CPORT(CXX, fPIC)
  73
  74 AC_DEFUN(adl_DD_COPT, [
  75 AC_CACHE_CHECK(whether $$1 accepts -$2,sdcc_cv_$1$2,
  76 cat >_test_.c <<EOF
  77 #include <stdio.h>
  78 void main(void) {}
  79 EOF
  80 $$1 -v -$2 -c _test_.c 1>&5 2>&5
  81 if test "$?" = "0"; then
  82   sdcc_cv_$1$2="yes"
  83 else
  84   sdcc_cv_$1$2="no"
  85 fi
  86 rm -f _test_.* a.out)
  87 ])
  88
  89 # This macro expands DIR and assigns it to RET.
  90 # If DIR is NONE, then it's replaced by DEFAULT.
  91 #
  92 # Based on AC_DEFINE_DIR
  93 #
  94 # Examples:
  95 #
  96 #  adl_EXPAND(prefix, "/usr/local", expanded_prefix)
  97
  98 AC_DEFUN([adl_EXPAND], [
  99   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
 100   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 101   ac_expand=[$]$1
 102   test "x$ac_expand" = xNONE && ac_expand="[$]$2"
 103   ac_expand=`eval echo [$]ac_expand`
 104   $3=`eval echo [$]ac_expand`
 105 ])
 106
 107 # adl_NORMALIZE_PATH
 108 #
 109 #  - empty paths are changed to '.'
 110 #  - trailing slashes are removed
 111 #  - repeated slashes are squeezed except a leading doubled slash '//'
 112 #    (which might indicate a networked disk on some OS).
 113 #
 114 #
 115 # REFERENCE_STRING is used to turn '/' into '\' and vice-versa: if
 116 # REFERENCE_STRING contains some backslashes, all slashes and backslashes
 117 # are turned into backslashes, otherwise they are all turned into slashes.
 118 #
 119 # This makes processing of DOS filenames quite easier, because you can turn a
 120 # filename to the Unix notation, make your processing, and turn it back to
 121 # original notation.
 122
 123 dnl Available from the GNU Autoconf Macro Archive at:
 124 dnl http://www.gnu.org/software/ac-archive/htmldoc/normpath.html
 125 dnl
 126 AC_DEFUN([adl_NORMALIZE_PATH],
 127 [case ":[$]$1:" in
 128 dnl change empty paths to '.'
 129   ::) $1='.' ;;
 130 dnl strip trailing slashes
 131   :*[[\\/]]:) $1=`echo "[$]$1" | sed 's,[[\\/]]*[$],,'` ;;
 132   :*:) ;;
 133 esac
 134 dnl squeze repeated slashes
 135 case ifelse($2,,"[$]$1",$2) in
 136 dnl if the path contains any backslashes, turn slashes into backslashes
 137
 138 dnl Bernhard Held 2003-04-06
 139 dnl This was the original line. It does not:
 140 dnl - convert the first slash
 141 dnl - replace a slash with a double-backslash
 142 dnl *\\*) $1=`echo "[$]$1" | sed 's,\(.\)[[\\/]][[\\/]]*,\1\\\\,g'` ;;
 143     *\\*) $1=`echo "[$]$1" | sed 's,\(.\)[[\\/]][[\\/]]*,\1\\\\\\\\,g
 144                                   s,^[[\\/]],\\\\\\\\,'` ;;
 145
 146 dnl if the path contains slashes, also turn backslashes into slashes
 147  *) $1=`echo "[$]$1" | sed 's,\(.\)[[\\/]][[\\/]]*,\1/,g'` ;;
 148 esac])
 149
 150
 151 # adl_COMPUTE_RELATIVE_PATH
 152 #
 153 # PATH_LIST is a space-separated list of colon-separated triplets of the form
 154 # 'FROM:TO:RESULT'. This function iterates over these triplets and set $RESULT
 155 # to the relative path from $FROM to $TO. Note that $FROM and $TO needs to be
 156 # absolute filenames for this macro to success.
 157
 158 AC_DEFUN([adl_COMPUTE_RELATIVE_PATHS],
 159 [for _lcl_i in $1; do
 160   _lcl_from=\[$]`echo "[$]_lcl_i" | sed 's,:.*$,,'`
 161   _lcl_to=\[$]`echo "[$]_lcl_i" | sed 's,^[[^:]]*:,,' | sed 's,:[[^:]]*$,,'`
 162   _lcl_result_var=`echo "[$]_lcl_i" | sed 's,^.*:,,'`
 163   adl_RECURSIVE_EVAL([[$]_lcl_from], [_lcl_from])
 164   adl_RECURSIVE_EVAL([[$]_lcl_to], [_lcl_to])
 165   _lcl_notation="$_lcl_from$_lcl_to"
 166   adl_NORMALIZE_PATH([_lcl_from],['/'])
 167   adl_NORMALIZE_PATH([_lcl_to],['/'])
 168   adl_COMPUTE_RELATIVE_PATH([_lcl_from], [_lcl_to], [_lcl_result_tmp])
 169   adl_NORMALIZE_PATH([_lcl_result_tmp],["[$]_lcl_notation"])
 170   eval $_lcl_result_var='[$]_lcl_result_tmp'
 171 done])
 172
 173 ## Note:
 174 ## *****
 175 ## The following helper macros are too fragile to be used out
 176 ## of adl_COMPUTE_RELATIVE_PATHS (mainly because they assume that
 177 ## paths are normalized), that's why I'm keeping them in the same file.
 178 ## Still, some of them maybe worth to reuse.
 179
 180 dnl adl_COMPUTE_RELATIVE_PATH(FROM, TO, RESULT)
 181 dnl ===========================================
 182 dnl Compute the relative path to go from $FROM to $TO and set the value
 183 dnl of $RESULT to that value.  This function work on raw filenames
 184 dnl (for instead it will considerate /usr//local and /usr/local as
 185 dnl two distinct paths), you should really use adl_COMPUTE_REALTIVE_PATHS
 186 dnl instead to have the paths sanitized automatically.
 187 dnl
 188 dnl For instance:
 189 dnl    first_dir=/somewhere/on/my/disk/bin
 190 dnl    second_dir=/somewhere/on/another/disk/share
 191 dnl    adl_COMPUTE_RELATIVE_PATH(first_dir, second_dir, first_to_second)
 192 dnl will set $first_to_second to '../../../another/disk/share'.
 193 AC_DEFUN([adl_COMPUTE_RELATIVE_PATH],
 194 [adl_COMPUTE_COMMON_PATH([$1], [$2], [_lcl_common_prefix])
 195 adl_COMPUTE_BACK_PATH([$1], [_lcl_common_prefix], [_lcl_first_rel])
 196 adl_COMPUTE_SUFFIX_PATH([$2], [_lcl_common_prefix], [_lcl_second_suffix])
 197 $3="[$]_lcl_first_rel[$]_lcl_second_suffix"])
 198
 199 dnl adl_COMPUTE_COMMON_PATH(LEFT, RIGHT, RESULT)
 200 dnl ============================================
 201 dnl Compute the common path to $LEFT and $RIGHT and set the result to $RESULT.
 202 dnl
 203 dnl For instance:
 204 dnl    first_path=/somewhere/on/my/disk/bin
 205 dnl    second_path=/somewhere/on/another/disk/share
 206 dnl    adl_COMPUTE_COMMON_PATH(first_path, second_path, common_path)
 207 dnl will set $common_path to '/somewhere/on'.
 208 AC_DEFUN([adl_COMPUTE_COMMON_PATH],
 209 [$3=''
 210 _lcl_second_prefix_match=''
 211 while test "[$]_lcl_second_prefix_match" != 0; do
 212   _lcl_first_prefix=`expr "x[$]$1" : "x\([$]$3/*[[^/]]*\)"`
 213   _lcl_second_prefix_match=`expr "x[$]$2" : "x[$]_lcl_first_prefix"`
 214   if test "[$]_lcl_second_prefix_match" != 0; then
 215     if test "[$]_lcl_first_prefix" != "[$]$3"; then
 216       $3="[$]_lcl_first_prefix"
 217     else
 218       _lcl_second_prefix_match=0
 219     fi
 220   fi
 221 done])
 222
 223 dnl adl_COMPUTE_SUFFIX_PATH(PATH, SUBPATH, RESULT)
 224 dnl ==============================================
 225 dnl Substrack $SUBPATH from $PATH, and set the resulting suffix
 226 dnl (or the empty string if $SUBPATH is not a subpath of $PATH)
 227 dnl to $RESULT.
 228 dnl
 229 dnl For instace:
 230 dnl    first_path=/somewhere/on/my/disk/bin
 231 dnl    second_path=/somewhere/on
 232 dnl    adl_COMPUTE_SUFFIX_PATH(first_path, second_path, common_path)
 233 dnl will set $common_path to '/my/disk/bin'.
 234 AC_DEFUN([adl_COMPUTE_SUFFIX_PATH],
 235 [$3=`expr "x[$]$1" : "x[$]$2/*\(.*\)"`])
 236
 237 dnl adl_COMPUTE_BACK_PATH(PATH, SUBPATH, RESULT)
 238 dnl ============================================
 239 dnl Compute the relative path to go from $PATH to $SUBPATH, knowing that
 240 dnl $SUBPATH is a subpath of $PATH (any other words, only repeated '../'
 241 dnl should be needed to move from $PATH to $SUBPATH) and set the value
 242 dnl of $RESULT to that value.  If $SUBPATH is not a subpath of PATH,
 243 dnl set $RESULT to the empty string.
 244 dnl
 245 dnl For instance:
 246 dnl    first_path=/somewhere/on/my/disk/bin
 247 dnl    second_path=/somewhere/on
 248 dnl    adl_COMPUTE_BACK_PATH(first_path, second_path, back_path)
 249 dnl will set $back_path to '../../../'.
 250 AC_DEFUN([adl_COMPUTE_BACK_PATH],
 251 [adl_COMPUTE_SUFFIX_PATH([$1], [$2], [_lcl_first_suffix])
 252 $3=''
 253 _lcl_tmp='xxx'
 254 while test "[$]_lcl_tmp" != ''; do
 255   _lcl_tmp=`expr "x[$]_lcl_first_suffix" : "x[[^/]]*/*\(.*\)"`
 256   if test "[$]_lcl_first_suffix" != ''; then
 257      _lcl_first_suffix="[$]_lcl_tmp"
 258      $3="../[$]$3"
 259   fi
 260 done])
 261
 262
 263 dnl adl_RECURSIVE_EVAL(VALUE, RESULT)
 264 dnl =================================
 265 dnl Interpolate the VALUE in loop until it does not change,
 266 dnl and set the result to $RESULT.
 267 dnl WARNING: It is easy to get an infinite loop with some unsane input.
 268 AC_DEFUN([adl_RECURSIVE_EVAL],
 269 [_lcl_receval="$1"
 270 $2=`(test "x$prefix" = xNONE && prefix="$ac_default_prefix"
 271      test "x$exec_prefix" = xNONE && exec_prefix="${prefix}"
 272      _lcl_receval_old=''
 273      while test "[$]_lcl_receval_old" != "[$]_lcl_receval"; do
 274        _lcl_receval_old="[$]_lcl_receval"
 275        eval _lcl_receval="\"[$]_lcl_receval\""
 276      done
 277      echo "[$]_lcl_receval")`])
 278
 279 dnl adl_NORMALIZE_DEFINE_UNQUOTED(var, DEFINE, REFERENCE_STRING)
 280 AC_DEFUN([adl_NORMALIZE_DEFINE_UNQUOTED], [
 281   ac_ndu=[$]$1
 282   adl_NORMALIZE_PATH([ac_ndu], [$]$3)
 283   AC_DEFINE_UNQUOTED($2, "${ac_ndu}")
 284 ])
 285
 286 dnl adl_NORMALIZE_PATH_MSG(input_string, var, dir_separator)
 287 dnl ========================================================
 288 dnl call adl_NORMALIZE_PATH and format it for the result message
 289 AC_DEFUN([adl_NORMALIZE_PATH_MSG], [
 290 dnl replace /./ by /
 291 $2=`echo "$1" | sed 's,/\./,/,g'`
 292 adl_NORMALIZE_PATH([$2], [$3])
 293 dnl replace \\ by \
 294 $2=`echo "[$]$2" | sed 's,\\\\\\\\,\\\\,g'`
 295 ])
 296
 297
 298 # Checking characteristics of compilers and other programs
 299 # ===========================================================================
 300 AC_CACHE_CHECK(whether preprocessor accepts -MM or -M,sdcc_cv_MM,
 301 echo "#include <stdio.h>" >_test_.c
 302 echo "" >>_test_.c
 303 $CPP -v -MM _test_.c 1>&5 2>&5
 304 if test "$?" = "0"; then
 305   sdcc_cv_MM="-MM"
 306 else
 307   sdcc_cv_MM="-M"
 308 fi
 309 rm -f _test_.*)
 310 M_OR_MM=$sdcc_cv_MM
 311 AC_SUBST(M_OR_MM)
 312
 313 # This is the first time when CFLAGS are set/modified!!
 314 adl_DD_COPT(CC, ggdb)
 315 if test "$sdcc_cv_CCggdb" = "yes"; then
 316   CFLAGS="-ggdb ${CFLAGS}"
 317 fi
 318
 319 adl_DD_COPT(CC, pipe)
 320 if test "$sdcc_cv_CCpipe" = "yes"; then
 321   CFLAGS="-pipe $CFLAGS"
 322 fi
 323
 324
 325 # Checks for typedefs, structures, and compiler characteristics.
 326 # ===========================================================================
 327 AC_TYPE_SIGNAL
 328
 329 AC_CHECK_SIZEOF(char)
 330 AC_CHECK_SIZEOF(short)
 331 AC_CHECK_SIZEOF(int)
 332 AC_CHECK_SIZEOF(long)
 333 AC_C_CHAR_UNSIGNED
 334
 335 type_name()
 336 {
 337   if expr "$ac_cv_sizeof_char" '>=' "$1" >/dev/null; then
 338       echo "char"
 339     exit
 340   fi
 341   if expr "$ac_cv_sizeof_short" '>=' "$1" >/dev/null; then
 342     echo "short"
 343     exit
 344   fi
 345   if expr "$ac_cv_sizeof_int" '>=' "$1" >/dev/null; then
 346     echo "int"
 347     exit
 348   fi
 349   if expr "$ac_cv_sizeof_long" '>=' "$1" >/dev/null; then
 350     echo "long"
 351     exit
 352   fi
 353   echo "long"
 354 }
 355
 356 AC_MSG_CHECKING(type name for byte)
 357 TYPE_CHAR=`type_name 1`
 358 if test "$ac_cv_c_char_unsigned" = "yes"; then
 359   TYPE_BYTE="signed $TYPE_CHAR"
 360 else
 361   TYPE_BYTE=$TYPE_CHAR
 362 fi
 363 AC_MSG_RESULT($TYPE_BYTE)
 364 AC_MSG_CHECKING(type name for word)
 365 TYPE_WORD=`type_name 2`
 366 AC_MSG_RESULT($TYPE_WORD)
 367 AC_MSG_CHECKING(type name for dword)
 368 TYPE_DWORD=`type_name 4`
 369 AC_MSG_RESULT($TYPE_DWORD)
 370
 371 AC_DEFINE_UNQUOTED(TYPE_BYTE,  $TYPE_BYTE)
 372 AC_DEFINE_UNQUOTED(TYPE_WORD,  $TYPE_WORD)
 373 AC_DEFINE_UNQUOTED(TYPE_DWORD, $TYPE_DWORD)
 374
 375 AC_DEFINE_UNQUOTED(TYPE_UBYTE,  unsigned $TYPE_CHAR)
 376 AC_DEFINE_UNQUOTED(TYPE_UWORD,  unsigned $TYPE_WORD)
 377 AC_DEFINE_UNQUOTED(TYPE_UDWORD, unsigned $TYPE_DWORD)
 378
 379 AC_C_BIGENDIAN
 380
 381 # Set standard installation paths
 382 # ===========================================================================
 383
 384 # In the Makefiles we need paths with '/' as directory separator, even if
 385 # crosscompiling for Win32.
 386 # And we want to preserve the macros (e.g. ${prefix}) in the Makefiles.
 387 # The variables in the Makefiles are replaced by AC_SUBST()
 388 #
 389 # In sdccconf.h the '/' in paths can be replaced by "\\" (normalized), if
 390 #
 391 # The macros are expanded for the header.
 392 # The variables in the header are replaced by AC_*DEFINE*()
 393 # sdccconf_h_dir_separator contains a backslash.
 394 AC_ARG_VAR(sdccconf_h_dir_separator, needed in sdccconf.h: either "/" (default) or "\\")
 395 if test "x${sdccconf_h_dir_separator}" = "x"; then
 396     sdccconf_h_dir_separator="/"
 397 fi
 398
 399 # Makefiles
 400 ###########
 401
 402 # include_dir_suffix:
 403 # *nix default: "sdcc/include"
 404
 405 AC_ARG_VAR(include_dir_suffix, appended to datadir to define SDCC's include directory)
 406 if test "${include_dir_suffix}" = ""; then
 407     include_dir_suffix="sdcc/include"
 408 fi
 409 AC_SUBST(include_dir_suffix)
 410
 411 # lib_dir_suffix:
 412 # *nix default: "sdcc/lib"
 413 AC_ARG_VAR(lib_dir_suffix, appended to datadir to define SDCC's library root directory)
 414 if test "${lib_dir_suffix}" = ""; then
 415     lib_dir_suffix="sdcc/lib"
 416 fi
 417 AC_SUBST(lib_dir_suffix)
 418
 419 # docdir:
 420 # *nix default: "${datadir}/sdcc/doc"
 421 AC_ARG_VAR(docdir, documentation installation directory)
 422 if test "${docdir}" = ""; then
 423     docdir="\${datadir}"/sdcc/doc
 424 fi
 425 AC_SUBST(docdir)
 426
 427 AC_SUBST(EXEEXT)
 428
 429 # sdccconf.h
 430 ############
 431
 432 AC_DEFINE_UNQUOTED(DIR_SEPARATOR_STRING, "${sdccconf_h_dir_separator}")
 433 AC_DEFINE_UNQUOTED(DIR_SEPARATOR_CHAR  , '${sdccconf_h_dir_separator}')
 434
 435 # prefix:
 436 # default: "NONE", ${ac_default_prefix}: "/usr/local"
 437 adl_EXPAND(prefix, ac_default_prefix, expanded_prefix)
 438 adl_NORMALIZE_DEFINE_UNQUOTED(expanded_prefix, PREFIX, sdccconf_h_dir_separator)
 439
 440 # exec_prefix:
 441 # default: "${prefix}"
 442 adl_EXPAND(exec_prefix, expanded_prefix, expanded_exec_prefix)
 443 adl_NORMALIZE_DEFINE_UNQUOTED(expanded_exec_prefix, EXEC_PREFIX, sdccconf_h_dir_separator)
 444
 445 # bindir:
 446 # default: "${exec_prefix}/bin"
 447 adl_EXPAND(bindir, "NONE", expanded_bindir)
 448 adl_NORMALIZE_DEFINE_UNQUOTED(expanded_bindir, BINDIR, sdccconf_h_dir_separator)
 449
 450 # datadir:
 451 # default: "${prefix}/share"
 452 adl_EXPAND(datadir, "NONE", expanded_datadir)
 453 adl_NORMALIZE_DEFINE_UNQUOTED(expanded_datadir, DATADIR, sdccconf_h_dir_separator)
 454
 455 # include/lib suffix
 456 norm_inc_dir_suffix=${include_dir_suffix}
 457 adl_NORMALIZE_PATH([norm_inc_dir_suffix], [$sdccconf_h_dir_separator])
 458 AC_DEFINE_UNQUOTED(INCLUDE_DIR_SUFFIX,
 459                    DIR_SEPARATOR_STRING "${norm_inc_dir_suffix}")
 460 norm_lib_dir_suffix=${lib_dir_suffix}
 461 adl_NORMALIZE_PATH([norm_lib_dir_suffix], [$sdccconf_h_dir_separator])
 462 AC_DEFINE_UNQUOTED(LIB_DIR_SUFFIX,
 463                    DIR_SEPARATOR_STRING "${norm_lib_dir_suffix}")
 464
 465 # relative paths
 466 adl_COMPUTE_RELATIVE_PATHS([expanded_bindir:expanded_datadir:bin2data_dir])
 467 adl_NORMALIZE_PATH(bin2data_dir, [$sdccconf_h_dir_separator])
 468 AC_DEFINE_UNQUOTED(BIN2DATA_DIR,
 469                    DIR_SEPARATOR_STRING "${bin2data_dir}")
 470
 471 adl_COMPUTE_RELATIVE_PATHS([expanded_prefix:expanded_bindir:prefix2bin_dir])
 472 adl_NORMALIZE_PATH(prefix2bin_dir, [$sdccconf_h_dir_separator])
 473 AC_DEFINE_UNQUOTED(PREFIX2BIN_DIR,
 474                    DIR_SEPARATOR_STRING "${prefix2bin_dir}")
 475
 476 adl_COMPUTE_RELATIVE_PATHS([expanded_prefix:expanded_datadir:prefix2data_dir])
 477 adl_NORMALIZE_PATH(prefix2data_dir, [$sdccconf_h_dir_separator])
 478 if test "${prefix2data_dir}" = "."; then
 479     # small optimization for Mingw32; otherwise Borut will complain ;-)
 480     AC_DEFINE_UNQUOTED(PREFIX2DATA_DIR, "")
 481 else
 482     AC_DEFINE_UNQUOTED(PREFIX2DATA_DIR,
 483                        DIR_SEPARATOR_STRING "${prefix2data_dir}")
 484 fi
 485
 486 # standard libs
 487 AC_DEFINE_UNQUOTED(STD_LIB,       "libsdcc")
 488 AC_DEFINE_UNQUOTED(STD_INT_LIB,   "libint")
 489 AC_DEFINE_UNQUOTED(STD_LONG_LIB,  "liblong")
 490 AC_DEFINE_UNQUOTED(STD_FP_LIB,    "libfloat")
 491 AC_DEFINE_UNQUOTED(STD_DS390_LIB, "libds390")
 492 AC_DEFINE_UNQUOTED(STD_DS400_LIB, "libds400")
 493 AC_DEFINE_UNQUOTED(STD_XA51_LIB,  "libxa51")
 494
 495 # SDCC runtime environment variables
 496 sdcc_dir_name="SDCC_HOME"
 497 AC_DEFINE_UNQUOTED(SDCC_DIR_NAME, "${sdcc_dir_name}")
 498
 499 sdcc_include_name="SDCC_INCLUDE"
 500 AC_DEFINE_UNQUOTED(SDCC_INCLUDE_NAME, "${sdcc_include_name}")
 501
 502 sdcc_lib_name="SDCC_LIB"
 503 AC_DEFINE_UNQUOTED(SDCC_LIB_NAME, "${sdcc_lib_name}")
 504
 505 # Port selection helper
 506 # ===========================================================================
 507 # macro AC_DO_ENABLER()
 508 #   $1 used to access enable_$1, e.g. enable-doc
 509 #   $2 OPT_DISABLE_$2, normally uppercase of $1, e.g. DOC
 510 #   $3 help string
 511 AC_DEFUN([AC_DO_ENABLER], [
 512   AC_ARG_ENABLE($1, AC_HELP_STRING([--enable-$1], $3))
 513
 514   if test "[$]enable_$1" = "yes"; then
 515     OPT_ENABLE_$2=1
 516   else
 517     OPT_ENABLE_$2=0
 518   fi
 519
 520   AC_DEFINE_UNQUOTED(OPT_ENABLE_$2, [$]OPT_ENABLE_$2)
 521   AC_SUBST(OPT_ENABLE_$2)
 522 ])
 523
 524 # macro AC_DO_DISABLER()
 525 #   $1 used to access disable_$1, e.g. ucsim
 526 #   $2 OPT_DISABLE_$2, normally uppercase of $1, e.g. UCSIM
 527 #   $3 help string
 528 AC_DEFUN([AC_DO_DISABLER], [
 529   AC_ARG_ENABLE($1, AC_HELP_STRING([--disable-$1], $3))
 530
 531   dnl the '-' in 'device-lib' needs special handling,
 532   dnl because the variable is 'enable_device_lib'
 533   arg1=`echo $1 | sed s/-/_/`
 534
 535   if test "`eval echo \\$enable_$arg1`" = "no"; then
 536     OPT_DISABLE_$2=1
 537   else
 538     OPT_DISABLE_$2=0
 539   fi
 540
 541   AC_DEFINE_UNQUOTED(OPT_DISABLE_$2, [$]OPT_DISABLE_$2)
 542   AC_SUBST(OPT_DISABLE_$2)
 543 ])
 544
 545 # macro AC_DO_PORT($1, $2, $3, $4)
 546 #   $1 used to access enable_$2_port, e.g. gbz80
 547 #   $2 port name in ports.all and ports.build, e.g. z80
 548 #   $3 OPT_DISABLE_$3, normally uppercase of $2, e.g. GBZ80
 549 #   $4 help string
 550 AC_DEFUN([AC_DO_PORT], [
 551   AC_ARG_ENABLE($1-port,
 552                 AC_HELP_STRING([--disable-$1-port], $4))
 553
 554   if test "[$]enable_$1_port" = "no"; then
 555     OPT_DISABLE_$3=1
 556   else
 557     enable_$1_port="yes"
 558     OPT_DISABLE_$3=0
 559   fi
 560
 561   AC_DEFINE_UNQUOTED(OPT_DISABLE_$3, [$]OPT_DISABLE_$3)
 562   AC_SUBST(OPT_DISABLE_$3)
 563
 564   echo $2 >>ports.all
 565   if test [$]OPT_DISABLE_$3 = 0; then
 566     echo $2 >>ports.build
 567   fi
 568 ])
 569
 570 # Now handle the port selection
 571 # ===========================================================================
 572 rm -f ports.all ports.build
 573 AC_DO_PORT(mcs51, mcs51, MCS51, [Excludes the Intel mcs51 port])
 574 AC_DO_PORT(gbz80, z80,   GBZ80, [Excludes the Gameboy gbz80 port])
 575 AC_DO_PORT(z80,   z80,   Z80,   [Excludes the z80 port])
 576 AC_DO_PORT(avr,   avr,   AVR,   [Excludes the AVR port])
 577 AC_DO_PORT(ds390, ds390, DS390, [Excludes the DS390 port])
 578 AC_DEFINE_UNQUOTED(OPT_DISABLE_TININative, $OPT_DISABLE_DS390)
 579 AC_DO_PORT(ds400, ds400, DS400, [Excludes the DS400 port])
 580 AC_DO_PORT(pic,   pic,   PIC,   [Excludes the PIC port])
 581 AC_DO_PORT(pic16, pic16, PIC16, [Excludes the PIC16 port])
 582 AC_DO_PORT(xa51,  xa51,  XA51,  [Excludes the XA51 port])
 583 AC_DO_PORT(hc08,  hc08,  HC08,  [Excludes the HC08 port])
 584
 585 AC_DO_DISABLER(ucsim,      UCSIM,      [Disables configuring and building of ucsim])
 586 AC_DO_DISABLER(device-lib, DEVICE_LIB, [Disables building device libraries])
 587 AC_DO_DISABLER(packihx,    PACKIHX,    [Disables building packihx])
 588 AC_DO_DISABLER(sdcpp,      SDCPP,      [Disables building sdcpp])
 589 AC_DO_DISABLER(sdcdb,      SDCDB,      [Disables building sdcdb])
 590
 591 AC_DO_ENABLER(doc,   DOC,   [Enables building the documentation])
 592 if test $OPT_ENABLE_DOC = 1; then
 593   AC_CHECK_PROG(LYX,        lyx,        lyx, :)
 594   AC_CHECK_PROG(LATEX2HTML, latex2html, latex2html, :)
 595   AC_CHECK_PROG(PDFLATEX,   pdflatex,   pdflatex, :)
 596   AC_CHECK_PROG(PDFOPT,     pdfopt,     pdfopt, :)
 597   AC_CHECK_PROG(MAKEINDEX,  makeindex,  makeindex, :)
 598
 599   SDCC_REQUIRE_PROG($LYX,        lyx)
 600   SDCC_REQUIRE_PROG($LATEX2HTML, latex2html)
 601   SDCC_REQUIRE_PROG($PDFLATEX,   pdflatex)
 602   SDCC_REQUIRE_PROG($PDFOPT,     pdfopt)
 603   SDCC_REQUIRE_PROG($MAKEINDEX,  makeindex)
 604 fi
 605
 606 AC_DO_ENABLER(libgc, LIBGC, [Use the Bohem memory allocator. Lower runtime footprint.])
 607 if test $OPT_ENABLE_LIBGC = 1; then
 608   AC_CHECK_LIB(gc, GC_malloc)
 609   if test $ac_cv_lib_gc_GC_malloc = no; then
 610     AC_MSG_ERROR([Cannot find library libgc with Bohem memory allocator.])
 611   fi
 612 fi
 613
 614 #remove duplicates
 615 uniq ports.all ports
 616 mv ports ports.all
 617 uniq ports.build ports
 618 mv ports ports.build
 619
 620 # Generating output files
 621 # ===========================================================================
 622 test $OPT_DISABLE_SDCPP   = 0 && AC_CONFIG_SUBDIRS(support/cpp2)
 623 test $OPT_DISABLE_PACKIHX = 0 && AC_CONFIG_SUBDIRS(support/packihx)
 624 test $OPT_DISABLE_UCSIM   = 0 && AC_CONFIG_SUBDIRS(sim/ucsim)
 625 test $OPT_DISABLE_SDCDB   = 0 && AC_CONFIG_SUBDIRS(debugger/mcs51)
 626 AC_CONFIG_FILES([doc/Makefile])
 627
 628 test $OPT_DISABLE_AVR = 0 && AC_CONFIG_FILES([src/avr/Makefile])
 629
 630 if test $OPT_DISABLE_DS390 = 0; then
 631   AC_CONFIG_FILES([src/ds390/Makefile])
 632   test $OPT_DISABLE_DEVICE_LIB = 0 && AC_CONFIG_FILES([device/lib/ds390/Makefile])
 633 fi
 634
 635 if test $OPT_DISABLE_DS400 = 0; then
 636   AC_CONFIG_FILES([src/ds400/Makefile])
 637   test $OPT_DISABLE_DEVICE_LIB = 0 && AC_CONFIG_FILES([device/lib/ds400/Makefile])
 638 fi
 639
 640 if test $OPT_DISABLE_HC08 = 0; then
 641   AC_CONFIG_FILES([src/hc08/Makefile
 642                    as/hc08/Makefile
 643                    as/link/hc08/Makefile])
 644   test $OPT_DISABLE_DEVICE_LIB = 0 && AC_CONFIG_FILES([device/lib/hc08/Makefile])
 645 fi
 646
 647 if test $OPT_DISABLE_MCS51 = 0; then
 648   AC_CONFIG_FILES([src/mcs51/Makefile
 649                    as/mcs51/Makefile
 650                    as/link/mcs51/Makefile])
 651   test $OPT_DISABLE_DEVICE_LIB = 0 && AC_CONFIG_FILES([device/lib/mcs51/Makefile
 652                                                        device/lib/small/Makefile
 653                                                        device/lib/medium/Makefile
 654                                                        device/lib/large/Makefile])
 655 fi
 656
 657 if test $OPT_DISABLE_PIC = 0; then
 658   AC_CONFIG_FILES(src/pic/Makefile)
 659   test $OPT_DISABLE_DEVICE_LIB = 0 && AC_CONFIG_SUBDIRS(device/lib/pic)
 660 fi
 661 if test $OPT_DISABLE_PIC16 = 0; then
 662   AC_CONFIG_FILES(src/pic16/Makefile)
 663   test $OPT_DISABLE_DEVICE_LIB = 0 && AC_CONFIG_SUBDIRS(device/lib/pic16)
 664 fi
 665
 666 test $OPT_DISABLE_XA51 = 0 && AC_CONFIG_FILES([src/xa51/Makefile])
 667
 668 if test $OPT_DISABLE_Z80 = 0; then
 669   AC_CONFIG_FILES([src/z80/Makefile
 670                    as/Makefile
 671                    as/z80/Makefile
 672                    as/link/Makefile
 673                    as/link/z80/Makefile])
 674   test $OPT_DISABLE_DEVICE_LIB = 0 && AC_CONFIG_FILES([device/lib/z80/Makefile
 675                                                        device/lib/gbz80/Makefile])
 676 fi
 677
 678 test $OPT_DISABLE_DEVICE_LIB = 0 && AC_CONFIG_FILES([device/lib/Makefile])
 679
 680 AC_CONFIG_FILES([main.mk:main_in.mk
 681 src/Makefile
 682 device/include/Makefile
 683 support/librarian/Makefile
 684 support/makebin/Makefile
 685 support/regression/Makefile
 686 support/valdiag/Makefile
 687 Makefile
 688 Makefile.common:Makefile.common.in
 689 ])
 690 AC_OUTPUT
 691
 692 # I found no better place
 693 mkdir -p bin
 694
 695 # Prepare result message
 696 # ======================
 697
 698 # In the C-header we need \\ as dir-separator, but in the message only \
 699 dirch=${sdccconf_h_dir_separator}
 700 test ${dirch} = '\\' && dirch='\'
 701
 702 # calc friendly strings
 703 adl_NORMALIZE_PATH_MSG(/${prefix2bin_dir},                         [binPath],  [$dirch])
 704 adl_NORMALIZE_PATH_MSG(/${prefix2data_dir}/${norm_inc_dir_suffix}, [incPath1], [$dirch])
 705 adl_NORMALIZE_PATH_MSG(/${bin2data_dir}/${norm_inc_dir_suffix},    [incPath2], [$dirch])
 706 adl_NORMALIZE_PATH_MSG(${expanded_datadir}/${norm_inc_dir_suffix}, [incPath3], [$dirch])
 707 adl_NORMALIZE_PATH_MSG(/${prefix2data_dir}/${norm_lib_dir_suffix}, [libPath1], [$dirch])
 708 adl_NORMALIZE_PATH_MSG(/${bin2data_dir}/${norm_lib_dir_suffix},    [libPath2], [$dirch])
 709 adl_NORMALIZE_PATH_MSG(${expanded_datadir}/${norm_lib_dir_suffix}, [libPath3], [$dirch])
 710
 711 AC_MSG_RESULT([
 712 sdcc ${VERSION} is now configured for
 713
 714   Build:                ${build_alias}
 715   Host:                 ${host_alias}
 716   Source directory:     ${srcdir}
 717   C compiler:           ${CC}
 718   CFLAGS:               ${CFLAGS}
 719
 720   ENABLED Ports:
 721     avr                 ${enable_avr_port}
 722     ds390               ${enable_ds390_port}
 723     ds400               ${enable_ds400_port}
 724     gbz80               ${enable_gbz80_port}
 725     hc08                ${enable_hc08_port}
 726     mcs51               ${enable_mcs51_port}
 727     pic                 ${enable_pic_port}
 728     pic16               ${enable_pic16_port}
 729     xa51                ${enable_xa51_port}
 730     z80                 ${enable_z80_port}
 731
 732   Disable packihx:      ${OPT_DISABLE_PACKIHX}
 733   Disable ucsim:        ${OPT_DISABLE_UCSIM}
 734   Disable device lib:   ${OPT_DISABLE_DEVICE_LIB}
 735   Disable sdcpp:        ${OPT_DISABLE_SDCPP}
 736   Disable sdcdb:        ${OPT_DISABLE_SDCDB}
 737   Enable documentation: ${OPT_ENABLE_DOC}
 738   Enable libgc:         ${OPT_ENABLE_LIBGC}
 739
 740   Install paths:
 741     binary files:       ${exec_prefix}
 742     include files:      ${datadir}/${include_dir_suffix}
 743     library files:      ${datadir}/${lib_dir_suffix}
 744     documentation:      ${docdir}
 745
 746     prefix:             ${prefix}
 747     datadir:            ${datadir}
 748     datarootdir:        ${datarootdir}
 749
 750   Search paths (incomplete, see manual for all search paths):
 751     binary files:       \$SDCC_HOME${binPath}
 752     include files:      ${incPath1}
 753                         path(argv[[0]])${incPath2}
 754                         ${incPath3}
 755     library files:      \$SDCC_HOME${libPath1}${dirch}<model>
 756                         path(argv[[0]])${libPath2}${dirch}<model>
 757                         ${libPath3}${dirch}<model>
 758 ])
 759 # End of configure/configure.in