git.gag.com Git - fw/openocd/blob - testing/examples/LPC2294Test/prj/lpc2294_ram.ld

   1 /****************************************************************************
   2 *  Copyright (c) 2006 by Michael Fischer. All rights reserved.
   3 *
   4 *  Redistribution and use in source and binary forms, with or without
   5 *  modification, are permitted provided that the following conditions
   6 *  are met:
   7 *
   8 *  1. Redistributions of source code must retain the above copyright
   9 *     notice, this list of conditions and the following disclaimer.
  10 *  2. Redistributions in binary form must reproduce the above copyright
  11 *     notice, this list of conditions and the following disclaimer in the
  12 *     documentation and/or other materials provided with the distribution.
  13 *  3. Neither the name of the author nor the names of its contributors may
  14 *     be used to endorse or promote products derived from this software
  15 *     without specific prior written permission.
  16 *
  17 *  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  18 *  "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  19 *  LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  20 *  FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL
  21 *  THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  22 *  INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
  23 *  BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
  24 *  OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  25 *  AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  26 *  OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF
  27 *  THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28 *  SUCH DAMAGE.
  29 *
  30 ****************************************************************************
  31 *
  32 *  History:
  33 *
  34 *  31.03.06  mifi   First Version
  35 ****************************************************************************/
  36
  37
  38 ENTRY(ResetHandler)
  39 SEARCH_DIR(.)
  40
  41 /*
  42  * Define stack size here
  43  */
  44 FIQ_STACK_SIZE = 0x0100;
  45 IRQ_STACK_SIZE = 0x0100;
  46 ABT_STACK_SIZE = 0x0100;
  47 UND_STACK_SIZE = 0x0100;
  48 SVC_STACK_SIZE = 0x0400;
  49
  50 /*
  51  * This file, olimex_lpce2294_ram.ld, locate the program in the internal
  52  * ram of the LPC2294. For more information about the memory of the LPC2294
  53  * take a look in the LPC2119/2129/2194/2292/2294 USER MANUAL.
  54  * Reference is made to the user manual from 2004 May 03
  55  *
  56  * Take a look at page 48, section 2.Memory Addressing
  57  */
  58
  59 MEMORY
  60 {
  61   ram : org = 0x40000000, len = 16k
  62 }
  63
  64 /*
  65  * Do not change the next code
  66  */
  67 SECTIONS
  68 {
  69   .text :
  70   {
  71     *(.vectors);
  72     . = ALIGN(4);
  73     *(.init);
  74     . = ALIGN(4);
  75     *(.text);
  76     . = ALIGN(4);
  77     *(.rodata);
  78     . = ALIGN(4);
  79     *(.rodata*);
  80     . = ALIGN(4);
  81     *(.glue_7t);
  82     . = ALIGN(4);
  83     *(.glue_7);
  84     . = ALIGN(4);
  85     etext = .;
  86   } > ram
  87
  88   .data :
  89   {
  90     PROVIDE (__data_start = .);
  91     *(.data)
  92     . = ALIGN(4);
  93     edata = .;
  94     _edata = .;
  95     PROVIDE (__data_end = .);
  96   } > ram
  97
  98   .bss :
  99   {
 100     PROVIDE (__bss_start = .);
 101     *(.bss)
 102     *(COMMON)
 103     . = ALIGN(4);
 104     PROVIDE (__bss_end = .);
 105
 106     . = ALIGN(256);
 107
 108     PROVIDE (__stack_start = .);
 109
 110     PROVIDE (__stack_fiq_start = .);
 111     . += FIQ_STACK_SIZE;
 112     . = ALIGN(4);
 113     PROVIDE (__stack_fiq_end = .);
 114
 115     PROVIDE (__stack_irq_start = .);
 116     . += IRQ_STACK_SIZE;
 117     . = ALIGN(4);
 118     PROVIDE (__stack_irq_end = .);
 119
 120     PROVIDE (__stack_abt_start = .);
 121     . += ABT_STACK_SIZE;
 122     . = ALIGN(4);
 123     PROVIDE (__stack_abt_end = .);
 124
 125     PROVIDE (__stack_und_start = .);
 126     . += UND_STACK_SIZE;
 127     . = ALIGN(4);
 128     PROVIDE (__stack_und_end = .);
 129
 130     PROVIDE (__stack_svc_start = .);
 131     . += SVC_STACK_SIZE;
 132     . = ALIGN(4);
 133     PROVIDE (__stack_svc_end = .);
 134     PROVIDE (__stack_end = .);
 135     PROVIDE (__heap_start = .);
 136   } > ram
 137
 138 }
 139 /*** EOF ***/
 140