git.gag.com Git - fw/openocd/blob - tcl/target/marvell/88f37x0.cfg

   1 # Main file for Marvell Armada 3700 series targets
   2 #
   3 # !!!!!!
   4 #
   5 # This file should not be included directly. Instead, please include
   6 # either marvell/88f3710.cfg or marvell/88f3720.cfg, which set the needed
   7 # variables to the appropriate values.
   8 #
   9 # !!!!!!
  10
  11 # Armada 3700 supports both JTAG and SWD transports.
  12 source [find target/swj-dp.tcl]
  13
  14 if { [info exists CORES] } {
  15     set _cores $CORES
  16 } else {
  17     error "CORES not set. Please do not include marvell/88f37x0.cfg directly, but the specific chip configuration file (marvell/88f3710.cfg, marvell/88f3720.cfg, etc.)."
  18 }
  19
  20 if { [info exists CHIPNAME] } {
  21     set _CHIPNAME $CHIPNAME
  22 } else {
  23     set _CHIPNAME [format a37%s0 $_cores]
  24 }
  25
  26 set _ctis {0x80820000 0x80920000}
  27
  28 #
  29 # Main DAP
  30 #
  31 if { [info exists DAP_TAPID] } {
  32     set _DAP_TAPID $DAP_TAPID
  33 } else {
  34     set _DAP_TAPID 0x4ba00477
  35 }
  36
  37 # declare the one JTAG tap to access the DAP
  38 swj_newdap $_CHIPNAME cpu -irlen 4 -ircapture 0x1 -irmask 0xf -expected-id $_DAP_TAPID -ignore-version -enable
  39 dap create $_CHIPNAME.dap -chain-position $_CHIPNAME.cpu
  40
  41 # declare the main application cores
  42 set _TARGETNAME $_CHIPNAME.cpu
  43 set _smp_command ""
  44
  45 for { set _core 0 } { $_core < $_cores } { incr _core 1 } {
  46
  47     cti create cti$_core -dap $_CHIPNAME.dap -baseaddr [lindex $_ctis $_core] -ap-num 0
  48
  49     set _command "target create ${_TARGETNAME}$_core aarch64 \
  50                          -dap $_CHIPNAME.dap -coreid $_core \
  51                          -cti cti$_core"
  52
  53     if { $_core != 0 } {
  54         # non-boot core examination may fail
  55         set _command "$_command -defer-examine"
  56         set _smp_command "$_smp_command ${_TARGETNAME}$_core"
  57     } else {
  58         # uncomment when "hawt" rtos is merged
  59         # set _command "$_command -rtos hawt"
  60         set _smp_command "target smp ${_TARGETNAME}$_core"
  61     }
  62
  63     eval $_command
  64 }
  65
  66 eval $_smp_command
  67
  68 # declare the auxiliary Cortex-M3 core on AP #3
  69 target create ${_TARGETNAME}.m3 cortex_m -dap $_CHIPNAME.dap -ap-num 3 -defer-examine
  70
  71 targets ${_TARGETNAME}0