git.gag.com Git - fw/openocd/blob - contrib/loaders/flash/stmqspi/stmoctospi_read.S

   1 /***************************************************************************
   2  *   Copyright (C) 2019 by Andreas Bolsch                                  *
   3  *   andreas.bolsch@mni.thm.de                                             *
   4  *                                                                         *
   5  *   This program is free software; you can redistribute it and/or modify  *
   6  *   it under the terms of the GNU General Public License as published by  *
   7  *   the Free Software Foundation; either version 2 of the License, or     *
   8  *   (at your option) any later version.                                   *
   9  *                                                                         *
  10  *   This program is distributed in the hope that it will be useful,       *
  11  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  12  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  13  *   GNU General Public License for more details.                          *
  14  *                                                                         *
  15  *   You should have received a copy of the GNU General Public License     *
  16  *   along with this program.  If not, see <http://www.gnu.org/licenses/>. *
  17  ***************************************************************************/
  18
  19         .text
  20         .syntax unified
  21         .cpu cortex-m0
  22         .thumb
  23         .thumb_func
  24
  25 /* Params:
  26  * r0 - total count (bytes), remaining bytes (out, 0 means successful)
  27  * r1 - flash page size
  28  * r2 - address offset into flash
  29  * r3 - OCTOSPI io_base
  30  * r8 - fifo start
  31  * r9 - fifo end + 1
  32
  33  * Clobbered:
  34  * r4 - wp
  35  * r5 - address of OCTOSPI_DR
  36  * r6 - address of OCTOSPI_CCR
  37  * r7 - tmp
  38  */
  39
  40 #include "../../../../src/flash/nor/stmqspi.h"
  41
  42 #define OCTOSPI_CCR_CCR                                 (OCTOSPI_CCR - OCTOSPI_CCR)
  43 #define OCTOSPI_TCR_CCR                                 (OCTOSPI_TCR - OCTOSPI_CCR)
  44 #define OCTOSPI_IR_CCR                                  (OCTOSPI_IR - OCTOSPI_CCR)
  45
  46         .macro  octospi_abort
  47         movs    r5, #(1<<SPI_ABORT)                     /* abort bit mask */
  48         ldr             r7, [r3, #OCTOSPI_CR]           /* get OCTOSPI CR register */
  49         orrs    r7, r7, r5                                      /* set abort bit */
  50         str             r7, [r3, #OCTOSPI_CR]           /* store new CR register */
  51         .endm
  52
  53         .macro  wait_busy
  54 0:
  55         ldr             r7, [r3, #OCTOSPI_SR]           /* load status */
  56         lsrs    r7, r7, #(SPI_BUSY+1)           /* shift BUSY into C */
  57         bcs             0b                                                      /* loop until BUSY cleared */
  58         movs    r7, #(1<<SPI_TCF)                       /* TCF bitmask */
  59         str             r7, [r3, #OCTOSPI_FCR]          /* clear TCF flag */
  60         .endm
  61
  62 start:
  63         subs    r0, r0, #1                                      /* decrement count for DLR */
  64         subs    r1, r1, #1                                      /* page size mask and for DLR */
  65         ldr             r4, wp                                          /* load wp */
  66 start_read:
  67         octospi_abort                                           /* start in clean state */
  68         movs    r5, #OCTOSPI_DR                         /* load OCTOSPI_DR address offset */
  69         adds    r5, r5, r3                                      /* address of OCTOSPI_DR */
  70         movs    r6, #OCTOSPI_CCR-OCTOSPI_DR     /* load OCTOSPI_CCR address offset */
  71         adds    r6, r6, r5                                      /* address of OCTOSPI_CCR */
  72         wait_busy
  73         ldr             r7, cr_page_read                        /* indirect read mode */
  74         str             r7, [r3, #OCTOSPI_CR]           /* set mode */
  75         mov             r7, r2                                          /* get current start address */
  76         orrs    r7, r7, r1                                      /* end of current page */
  77         subs    r7, r7, r2                                      /* count-1 to end of page */
  78         cmp             r7, r0                                          /* if this count <= remaining */
  79         bls             write_dlr                                       /* then write to end of page */
  80         mov             r7, r0                                          /* else write all remaining */
  81 write_dlr:
  82         str             r7, [r3, #OCTOSPI_DLR]          /* size-1 in DLR register */
  83         ldr             r7, ccr_page_read                       /* CCR for read */
  84         str             r7, [r6, #OCTOSPI_CCR_CCR]      /* initiate transfer */
  85         ldr             r7, tcr_page_read                       /* TCR for read */
  86         str             r7, [r6, #OCTOSPI_TCR_CCR]      /* instruction */
  87         ldr             r7, ir_page_read                        /* IR for read */
  88         str             r7, [r6, #OCTOSPI_IR_CCR]       /* instruction */
  89         str             r2, [r3, #OCTOSPI_AR]           /* store SPI start address */
  90 read_loop:
  91         ldrb    r7, [r5]                                        /* read next byte from DR */
  92         strb    r7, [r4, #0]                            /* write next byte */
  93         adds    r4, r4, #1                                      /* increment internal wp */
  94         cmp             r4, r9                                          /* internal wp beyond end? */
  95         blo             wait_fifo                                       /* if no, then ok */
  96         mov             r4, r8                                          /* else wrap around */
  97 wait_fifo:
  98         ldr             r7, rp                                          /* get rp */
  99         cmp             r7, #0                                          /* if rp equals 0 */
 100         beq             exit                                            /* then abort */
 101         cmp             r4, r7                                          /* check if fifo full */
 102         beq             wait_fifo                                       /* wait until not full */
 103         adr             r7, wp                                          /* get address of wp */
 104         str             r4, [r7]                                        /* store updated wp */
 105         adds    r2, r2, #1                                      /* increment address */
 106         subs    r0, r0, #1                                      /* decrement (count-1) */
 107         bmi             exit                                            /* stop if no data left */
 108         tst             r2, r1                                          /* page end ? */
 109         bne             read_loop                                       /* if not, then next byte */
 110 page_end:
 111         bal             start_read                                      /* then next page */
 112
 113 exit:
 114         adds    r0, r0, #1                                      /* increment count due to the -1 */
 115         octospi_abort                                           /* to idle state */
 116
 117         .align  2                                                       /* align to word, bkpt is 4 words */
 118         bkpt    #0                                                      /* before code end for exit_point */
 119         .align  2                                                       /* align to word */
 120
 121         .space  4                                                       /* not used */
 122         .space  4                                                       /* not used */
 123         .space  4                                                       /* not used */
 124         .space  4                                                       /* not used */
 125
 126         .space  4                                                       /* not used */
 127         .space  4                                                       /* not used */
 128         .space  4                                                       /* not used */
 129         .space  4                                                       /* not used */
 130
 131 cr_page_read:
 132         .space  4                                                       /* OCTOSPI_CR value for read command */
 133 ccr_page_read:
 134         .space  4                                                       /* OCTOSPI_CCR value for read command */
 135 tcr_page_read:
 136         .space  4                                                       /* OCTOSPI_TCR value for read command */
 137 ir_page_read:
 138         .space  4                                                       /* OCTOSPI_IR value for read command */
 139
 140         .equ wp, .                                                      /* wp, uint32_t */
 141         .equ rp, wp + 4                                         /* rp, uint32_t */
 142         .equ buffer, rp + 4                                     /* buffer follows right away */