git.gag.com Git - fw/openocd/blob - contrib/loaders/checksum/armv7m_crc.s

   1 /***************************************************************************
   2  *   Copyright (C) 2010 by Spencer Oliver                                  *
   3  *   spen@spen-soft.co.uk                                                  *
   4  *                                                                         *
   5  *   This program is free software; you can redistribute it and/or modify  *
   6  *   it under the terms of the GNU General Public License as published by  *
   7  *   the Free Software Foundation; either version 2 of the License, or     *
   8  *   (at your option) any later version.                                   *
   9  *                                                                         *
  10  *   This program is distributed in the hope that it will be useful,       *
  11  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  12  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  13  *   GNU General Public License for more details.                          *
  14  *                                                                         *
  15  *   You should have received a copy of the GNU General Public License     *
  16  *   along with this program; if not, write to the                         *
  17  *   Free Software Foundation, Inc.,                                       *
  18  *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.           *
  19  ***************************************************************************/
  20
  21 /*
  22         parameters:
  23         r0 - address in - crc out
  24         r1 - char count
  25 */
  26
  27         .text
  28         .syntax unified
  29         .cpu cortex-m0
  30         .thumb
  31         .thumb_func
  32
  33         .align  2
  34
  35 _start:
  36 main:
  37         mov             r2, r0
  38         movs    r0, #0
  39         mvns    r0, r0
  40         ldr             r6, CRC32XOR
  41         mov             r3, r1
  42         movs    r4, #0
  43         b               ncomp
  44 nbyte:
  45         ldrb    r1, [r2, r4]
  46         lsls    r1, r1, #24
  47         eors    r0, r0, r1
  48         movs    r5, #0
  49 loop:
  50         cmp             r0, #0
  51         bge             notset
  52         lsls    r0, r0, #1
  53         eors    r0, r0, r6
  54         b               cont
  55 notset:
  56         lsls    r0, r0, #1
  57 cont:
  58         adds    r5, r5, #1
  59         cmp             r5, #8
  60         bne             loop
  61         adds    r4, r4, #1
  62 ncomp:
  63         cmp             r4, r3
  64         bne             nbyte
  65         bkpt    #0
  66
  67         .align  2
  68
  69 CRC32XOR:       .word   0x04c11db7
  70
  71         .end