git.gag.com Git - debian/tar/blob - m4/mbsinit.m4

   1 # mbsinit.m4 serial 5
   2 dnl Copyright (C) 2008, 2010-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_MBSINIT],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST])
  11
  12   AC_REQUIRE([AC_TYPE_MBSTATE_T])
  13   gl_MBSTATE_T_BROKEN
  14
  15   AC_CHECK_FUNCS_ONCE([mbsinit])
  16   if test $ac_cv_func_mbsinit = no; then
  17     HAVE_MBSINIT=0
  18   else
  19     if test $REPLACE_MBSTATE_T = 1; then
  20       REPLACE_MBSINIT=1
  21     else
  22       dnl On mingw, mbsinit() always returns 1, which is inappropriate for
  23       dnl states produced by mbrtowc() for an incomplete multibyte character
  24       dnl in multibyte locales.
  25       case "$host_os" in
  26         mingw*) REPLACE_MBSINIT=1 ;;
  27       esac
  28     fi
  29   fi
  30   if test $HAVE_MBSINIT = 0 || test $REPLACE_MBSINIT = 1; then
  31     gl_REPLACE_WCHAR_H
  32     AC_LIBOBJ([mbsinit])
  33     gl_PREREQ_MBSINIT
  34   fi
  35 ])
  36
  37 # Prerequisites of lib/mbsinit.c.
  38 AC_DEFUN([gl_PREREQ_MBSINIT], [
  39   :
  40 ])