git.gag.com Git - debian/gzip/blob - m4/stdint.m4

   1 # stdint.m4 serial 44
   2 dnl Copyright (C) 2001-2016 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN_ONCE([gl_STDINT_H],
  11 [
  12   AC_PREREQ([2.59])dnl
  13
  14   dnl Check for long long int and unsigned long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  23   if test $ac_cv_type_unsigned_long_long_int = yes; then
  24     HAVE_UNSIGNED_LONG_LONG_INT=1
  25   else
  26     HAVE_UNSIGNED_LONG_LONG_INT=0
  27   fi
  28   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
  29
  30   dnl Check for <wchar.h>, in the same way as gl_WCHAR_H does.
  31   AC_CHECK_HEADERS_ONCE([wchar.h])
  32   if test $ac_cv_header_wchar_h = yes; then
  33     HAVE_WCHAR_H=1
  34   else
  35     HAVE_WCHAR_H=0
  36   fi
  37   AC_SUBST([HAVE_WCHAR_H])
  38
  39   dnl Check for <inttypes.h>.
  40   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  41   if test $ac_cv_header_inttypes_h = yes; then
  42     HAVE_INTTYPES_H=1
  43   else
  44     HAVE_INTTYPES_H=0
  45   fi
  46   AC_SUBST([HAVE_INTTYPES_H])
  47
  48   dnl Check for <sys/types.h>.
  49   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  50   if test $ac_cv_header_sys_types_h = yes; then
  51     HAVE_SYS_TYPES_H=1
  52   else
  53     HAVE_SYS_TYPES_H=0
  54   fi
  55   AC_SUBST([HAVE_SYS_TYPES_H])
  56
  57   gl_CHECK_NEXT_HEADERS([stdint.h])
  58   if test $ac_cv_header_stdint_h = yes; then
  59     HAVE_STDINT_H=1
  60   else
  61     HAVE_STDINT_H=0
  62   fi
  63   AC_SUBST([HAVE_STDINT_H])
  64
  65   dnl Now see whether we need a substitute <stdint.h>.
  66   if test $ac_cv_header_stdint_h = yes; then
  67     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  68       [gl_cv_header_working_stdint_h],
  69       [gl_cv_header_working_stdint_h=no
  70        AC_COMPILE_IFELSE([
  71          AC_LANG_PROGRAM([[
  72 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
  73 #define __STDC_CONSTANT_MACROS 1
  74 #define __STDC_LIMIT_MACROS 1
  75 #include <stdint.h>
  76 /* Dragonfly defines WCHAR_MIN, WCHAR_MAX only in <wchar.h>.  */
  77 #if !(defined WCHAR_MIN && defined WCHAR_MAX)
  78 #error "WCHAR_MIN, WCHAR_MAX not defined in <stdint.h>"
  79 #endif
  80 ]
  81 gl_STDINT_INCLUDES
  82 [
  83 #ifdef INT8_MAX
  84 int8_t a1 = INT8_MAX;
  85 int8_t a1min = INT8_MIN;
  86 #endif
  87 #ifdef INT16_MAX
  88 int16_t a2 = INT16_MAX;
  89 int16_t a2min = INT16_MIN;
  90 #endif
  91 #ifdef INT32_MAX
  92 int32_t a3 = INT32_MAX;
  93 int32_t a3min = INT32_MIN;
  94 #endif
  95 #ifdef INT64_MAX
  96 int64_t a4 = INT64_MAX;
  97 int64_t a4min = INT64_MIN;
  98 #endif
  99 #ifdef UINT8_MAX
 100 uint8_t b1 = UINT8_MAX;
 101 #else
 102 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
 103 #endif
 104 #ifdef UINT16_MAX
 105 uint16_t b2 = UINT16_MAX;
 106 #endif
 107 #ifdef UINT32_MAX
 108 uint32_t b3 = UINT32_MAX;
 109 #endif
 110 #ifdef UINT64_MAX
 111 uint64_t b4 = UINT64_MAX;
 112 #endif
 113 int_least8_t c1 = INT8_C (0x7f);
 114 int_least8_t c1max = INT_LEAST8_MAX;
 115 int_least8_t c1min = INT_LEAST8_MIN;
 116 int_least16_t c2 = INT16_C (0x7fff);
 117 int_least16_t c2max = INT_LEAST16_MAX;
 118 int_least16_t c2min = INT_LEAST16_MIN;
 119 int_least32_t c3 = INT32_C (0x7fffffff);
 120 int_least32_t c3max = INT_LEAST32_MAX;
 121 int_least32_t c3min = INT_LEAST32_MIN;
 122 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 123 int_least64_t c4max = INT_LEAST64_MAX;
 124 int_least64_t c4min = INT_LEAST64_MIN;
 125 uint_least8_t d1 = UINT8_C (0xff);
 126 uint_least8_t d1max = UINT_LEAST8_MAX;
 127 uint_least16_t d2 = UINT16_C (0xffff);
 128 uint_least16_t d2max = UINT_LEAST16_MAX;
 129 uint_least32_t d3 = UINT32_C (0xffffffff);
 130 uint_least32_t d3max = UINT_LEAST32_MAX;
 131 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 132 uint_least64_t d4max = UINT_LEAST64_MAX;
 133 int_fast8_t e1 = INT_FAST8_MAX;
 134 int_fast8_t e1min = INT_FAST8_MIN;
 135 int_fast16_t e2 = INT_FAST16_MAX;
 136 int_fast16_t e2min = INT_FAST16_MIN;
 137 int_fast32_t e3 = INT_FAST32_MAX;
 138 int_fast32_t e3min = INT_FAST32_MIN;
 139 int_fast64_t e4 = INT_FAST64_MAX;
 140 int_fast64_t e4min = INT_FAST64_MIN;
 141 uint_fast8_t f1 = UINT_FAST8_MAX;
 142 uint_fast16_t f2 = UINT_FAST16_MAX;
 143 uint_fast32_t f3 = UINT_FAST32_MAX;
 144 uint_fast64_t f4 = UINT_FAST64_MAX;
 145 #ifdef INTPTR_MAX
 146 intptr_t g = INTPTR_MAX;
 147 intptr_t gmin = INTPTR_MIN;
 148 #endif
 149 #ifdef UINTPTR_MAX
 150 uintptr_t h = UINTPTR_MAX;
 151 #endif
 152 intmax_t i = INTMAX_MAX;
 153 uintmax_t j = UINTMAX_MAX;
 154
 155 #include <limits.h> /* for CHAR_BIT */
 156 #define TYPE_MINIMUM(t) \
 157   ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ TYPE_MAXIMUM (t)))
 158 #define TYPE_MAXIMUM(t) \
 159   ((t) ((t) 0 < (t) -1 \
 160         ? (t) -1 \
 161         : ((((t) 1 << (sizeof (t) * CHAR_BIT - 2)) - 1) * 2 + 1)))
 162 struct s {
 163   int check_PTRDIFF:
 164       PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t)
 165       && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t)
 166       ? 1 : -1;
 167   /* Detect bug in FreeBSD 6.0 / ia64.  */
 168   int check_SIG_ATOMIC:
 169       SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t)
 170       && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t)
 171       ? 1 : -1;
 172   int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1;
 173   int check_WCHAR:
 174       WCHAR_MIN == TYPE_MINIMUM (wchar_t)
 175       && WCHAR_MAX == TYPE_MAXIMUM (wchar_t)
 176       ? 1 : -1;
 177   /* Detect bug in mingw.  */
 178   int check_WINT:
 179       WINT_MIN == TYPE_MINIMUM (wint_t)
 180       && WINT_MAX == TYPE_MAXIMUM (wint_t)
 181       ? 1 : -1;
 182
 183   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 184   int check_UINT8_C:
 185         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 186   int check_UINT16_C:
 187         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 188
 189   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 190 #ifdef UINT8_MAX
 191   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 192 #endif
 193 #ifdef UINT16_MAX
 194   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 195 #endif
 196 #ifdef UINT32_MAX
 197   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 198 #endif
 199 #ifdef UINT64_MAX
 200   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 201 #endif
 202   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 203   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 204   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 205   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 206   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 207   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 208   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 209   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 210   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 211   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 212   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 213 };
 214          ]])],
 215          [dnl Determine whether the various *_MIN, *_MAX macros are usable
 216           dnl in preprocessor expression. We could do it by compiling a test
 217           dnl program for each of these macros. It is faster to run a program
 218           dnl that inspects the macro expansion.
 219           dnl This detects a bug on HP-UX 11.23/ia64.
 220           AC_RUN_IFELSE([
 221             AC_LANG_PROGRAM([[
 222 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 223 #define __STDC_CONSTANT_MACROS 1
 224 #define __STDC_LIMIT_MACROS 1
 225 #include <stdint.h>
 226 ]
 227 gl_STDINT_INCLUDES
 228 [
 229 #include <stdio.h>
 230 #include <string.h>
 231 #define MVAL(macro) MVAL1(macro)
 232 #define MVAL1(expression) #expression
 233 static const char *macro_values[] =
 234   {
 235 #ifdef INT8_MAX
 236     MVAL (INT8_MAX),
 237 #endif
 238 #ifdef INT16_MAX
 239     MVAL (INT16_MAX),
 240 #endif
 241 #ifdef INT32_MAX
 242     MVAL (INT32_MAX),
 243 #endif
 244 #ifdef INT64_MAX
 245     MVAL (INT64_MAX),
 246 #endif
 247 #ifdef UINT8_MAX
 248     MVAL (UINT8_MAX),
 249 #endif
 250 #ifdef UINT16_MAX
 251     MVAL (UINT16_MAX),
 252 #endif
 253 #ifdef UINT32_MAX
 254     MVAL (UINT32_MAX),
 255 #endif
 256 #ifdef UINT64_MAX
 257     MVAL (UINT64_MAX),
 258 #endif
 259     NULL
 260   };
 261 ]], [[
 262   const char **mv;
 263   for (mv = macro_values; *mv != NULL; mv++)
 264     {
 265       const char *value = *mv;
 266       /* Test whether it looks like a cast expression.  */
 267       if (strncmp (value, "((unsigned int)"/*)*/, 15) == 0
 268           || strncmp (value, "((unsigned short)"/*)*/, 17) == 0
 269           || strncmp (value, "((unsigned char)"/*)*/, 16) == 0
 270           || strncmp (value, "((int)"/*)*/, 6) == 0
 271           || strncmp (value, "((signed short)"/*)*/, 15) == 0
 272           || strncmp (value, "((signed char)"/*)*/, 14) == 0)
 273         return mv - macro_values + 1;
 274     }
 275   return 0;
 276 ]])],
 277               [gl_cv_header_working_stdint_h=yes],
 278               [],
 279               [dnl When cross-compiling, assume it works.
 280                gl_cv_header_working_stdint_h=yes
 281               ])
 282          ])
 283       ])
 284   fi
 285   if test "$gl_cv_header_working_stdint_h" = yes; then
 286     dnl Now see whether the system <stdint.h> works without
 287     dnl __STDC_CONSTANT_MACROS/__STDC_LIMIT_MACROS defined.
 288     AC_CACHE_CHECK([whether stdint.h predates C++11],
 289       [gl_cv_header_stdint_predates_cxx11_h],
 290       [gl_cv_header_stdint_predates_cxx11_h=yes
 291        AC_COMPILE_IFELSE([
 292          AC_LANG_PROGRAM([[
 293 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 294 #include <stdint.h>
 295 ]
 296 gl_STDINT_INCLUDES
 297 [
 298 intmax_t im = INTMAX_MAX;
 299 int32_t i32 = INT32_C (0x7fffffff);
 300          ]])],
 301          [gl_cv_header_stdint_predates_cxx11_h=no])])
 302
 303     if test "$gl_cv_header_stdint_predates_cxx11_h" = yes; then
 304       AC_DEFINE([__STDC_CONSTANT_MACROS], [1],
 305                 [Define to 1 if the system <stdint.h> predates C++11.])
 306       AC_DEFINE([__STDC_LIMIT_MACROS], [1],
 307                 [Define to 1 if the system <stdint.h> predates C++11.])
 308     fi
 309     STDINT_H=
 310   else
 311     dnl Check for <sys/inttypes.h>, and for
 312     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 313     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 314     if test $ac_cv_header_sys_inttypes_h = yes; then
 315       HAVE_SYS_INTTYPES_H=1
 316     else
 317       HAVE_SYS_INTTYPES_H=0
 318     fi
 319     AC_SUBST([HAVE_SYS_INTTYPES_H])
 320     if test $ac_cv_header_sys_bitypes_h = yes; then
 321       HAVE_SYS_BITYPES_H=1
 322     else
 323       HAVE_SYS_BITYPES_H=0
 324     fi
 325     AC_SUBST([HAVE_SYS_BITYPES_H])
 326
 327     gl_STDINT_TYPE_PROPERTIES
 328     STDINT_H=stdint.h
 329   fi
 330   AC_SUBST([STDINT_H])
 331   AM_CONDITIONAL([GL_GENERATE_STDINT_H], [test -n "$STDINT_H"])
 332 ])
 333
 334 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 335 dnl Determine the size of each of the given types in bits.
 336 AC_DEFUN([gl_STDINT_BITSIZEOF],
 337 [
 338   dnl Use a shell loop, to avoid bloating configure, and
 339   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 340   dnl   config.h.in,
 341   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 342   m4_foreach_w([gltype], [$1],
 343     [AH_TEMPLATE([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 344        [Define to the number of bits in type ']gltype['.])])
 345   for gltype in $1 ; do
 346     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 347       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
 348          [$2
 349 #include <limits.h>], [result=unknown])
 350        eval gl_cv_bitsizeof_${gltype}=\$result
 351       ])
 352     eval result=\$gl_cv_bitsizeof_${gltype}
 353     if test $result = unknown; then
 354       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 355       dnl do a syntax check even on unused #if conditions and give an error
 356       dnl on valid C code like this:
 357       dnl   #if 0
 358       dnl   # if  > 32
 359       dnl   # endif
 360       dnl   #endif
 361       result=0
 362     fi
 363     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 364     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 365     eval BITSIZEOF_${GLTYPE}=\$result
 366   done
 367   m4_foreach_w([gltype], [$1],
 368     [AC_SUBST([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 369 ])
 370
 371 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 372 dnl Determine the signedness of each of the given types.
 373 dnl Define HAVE_SIGNED_TYPE if type is signed.
 374 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 375 [
 376   dnl Use a shell loop, to avoid bloating configure, and
 377   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 378   dnl   config.h.in,
 379   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 380   m4_foreach_w([gltype], [$1],
 381     [AH_TEMPLATE([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 382        [Define to 1 if ']gltype[' is a signed integer type.])])
 383   for gltype in $1 ; do
 384     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 385       [AC_COMPILE_IFELSE(
 386          [AC_LANG_PROGRAM([$2[
 387             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 388          result=yes, result=no)
 389        eval gl_cv_type_${gltype}_signed=\$result
 390       ])
 391     eval result=\$gl_cv_type_${gltype}_signed
 392     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 393     if test "$result" = yes; then
 394       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], [1])
 395       eval HAVE_SIGNED_${GLTYPE}=1
 396     else
 397       eval HAVE_SIGNED_${GLTYPE}=0
 398     fi
 399   done
 400   m4_foreach_w([gltype], [$1],
 401     [AC_SUBST([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 402 ])
 403
 404 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 405 dnl Determine the suffix to use for integer constants of the given types.
 406 dnl Define t_SUFFIX for each such type.
 407 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 408 [
 409   dnl Use a shell loop, to avoid bloating configure, and
 410   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 411   dnl   config.h.in,
 412   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 413   m4_foreach_w([gltype], [$1],
 414     [AH_TEMPLATE(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 415        [Define to l, ll, u, ul, ull, etc., as suitable for
 416         constants of type ']gltype['.])])
 417   for gltype in $1 ; do
 418     AC_CACHE_CHECK([for $gltype integer literal suffix],
 419       [gl_cv_type_${gltype}_suffix],
 420       [eval gl_cv_type_${gltype}_suffix=no
 421        eval result=\$gl_cv_type_${gltype}_signed
 422        if test "$result" = yes; then
 423          glsufu=
 424        else
 425          glsufu=u
 426        fi
 427        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 428          case $glsuf in
 429            '')  gltype1='int';;
 430            l)   gltype1='long int';;
 431            ll)  gltype1='long long int';;
 432            i64) gltype1='__int64';;
 433            u)   gltype1='unsigned int';;
 434            ul)  gltype1='unsigned long int';;
 435            ull) gltype1='unsigned long long int';;
 436            ui64)gltype1='unsigned __int64';;
 437          esac
 438          AC_COMPILE_IFELSE(
 439            [AC_LANG_PROGRAM([$2[
 440               extern $gltype foo;
 441               extern $gltype1 foo;]])],
 442            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 443          eval result=\$gl_cv_type_${gltype}_suffix
 444          test "$result" != no && break
 445        done])
 446     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 447     eval result=\$gl_cv_type_${gltype}_suffix
 448     test "$result" = no && result=
 449     eval ${GLTYPE}_SUFFIX=\$result
 450     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], [$result])
 451   done
 452   m4_foreach_w([gltype], [$1],
 453     [AC_SUBST(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 454 ])
 455
 456 dnl gl_STDINT_INCLUDES
 457 AC_DEFUN([gl_STDINT_INCLUDES],
 458 [[
 459   /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 460      included before <wchar.h>.  */
 461   #include <stddef.h>
 462   #include <signal.h>
 463   #if HAVE_WCHAR_H
 464   # include <stdio.h>
 465   # include <time.h>
 466   # include <wchar.h>
 467   #endif
 468 ]])
 469
 470 dnl gl_STDINT_TYPE_PROPERTIES
 471 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 472 dnl of interest to stdint.in.h.
 473 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 474 [
 475   AC_REQUIRE([gl_MULTIARCH])
 476   if test $APPLE_UNIVERSAL_BUILD = 0; then
 477     gl_STDINT_BITSIZEOF([ptrdiff_t size_t],
 478       [gl_STDINT_INCLUDES])
 479   fi
 480   gl_STDINT_BITSIZEOF([sig_atomic_t wchar_t wint_t],
 481     [gl_STDINT_INCLUDES])
 482   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 483     [gl_STDINT_INCLUDES])
 484   gl_cv_type_ptrdiff_t_signed=yes
 485   gl_cv_type_size_t_signed=no
 486   if test $APPLE_UNIVERSAL_BUILD = 0; then
 487     gl_INTEGER_TYPE_SUFFIX([ptrdiff_t size_t],
 488       [gl_STDINT_INCLUDES])
 489   fi
 490   gl_INTEGER_TYPE_SUFFIX([sig_atomic_t wchar_t wint_t],
 491     [gl_STDINT_INCLUDES])
 492
 493   dnl If wint_t is smaller than 'int', it cannot satisfy the ISO C 99
 494   dnl requirement that wint_t is "unchanged by default argument promotions".
 495   dnl In this case gnulib's <wchar.h> and <wctype.h> override wint_t.
 496   dnl Set the variable BITSIZEOF_WINT_T accordingly.
 497   if test $BITSIZEOF_WINT_T -lt 32; then
 498     BITSIZEOF_WINT_T=32
 499   fi
 500 ])
 501
 502 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
 503 dnl Remove this when we can assume autoconf >= 2.61.
 504 m4_ifdef([AC_COMPUTE_INT], [], [
 505   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
 506 ])
 507
 508 # Hey Emacs!
 509 # Local Variables:
 510 # indent-tabs-mode: nil
 511 # End: