git.gag.com Git - debian/gzip/blob - m4/opendir.m4

   1 # opendir.m4 serial 4
   2 dnl Copyright (C) 2011-2016 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_OPENDIR],
   8 [
   9   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  10
  11   AC_CHECK_FUNCS([opendir])
  12   if test $ac_cv_func_opendir = no; then
  13     HAVE_OPENDIR=0
  14   fi
  15   dnl Replace opendir() for supporting the gnulib-defined fchdir() function,
  16   dnl to keep fchdir's bookkeeping up-to-date.
  17   m4_ifdef([gl_FUNC_FCHDIR], [
  18     gl_TEST_FCHDIR
  19     if test $HAVE_FCHDIR = 0; then
  20       if test $HAVE_OPENDIR = 1; then
  21         REPLACE_OPENDIR=1
  22       fi
  23     fi
  24   ])
  25   dnl Replace opendir() on OS/2 kLIBC to support dirfd() function replaced
  26   dnl by gnulib.
  27   case $host_os,$HAVE_OPENDIR in
  28     os2*,1)
  29       REPLACE_OPENDIR=1;;
  30   esac
  31 ])