git.gag.com Git - debian/gzip/blob - m4/manywarnings.m4

   1 # manywarnings.m4 serial 7
   2 dnl Copyright (C) 2008-2016 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Simon Josefsson
   8
   9 # gl_MANYWARN_COMPLEMENT(OUTVAR, LISTVAR, REMOVEVAR)
  10 # --------------------------------------------------
  11 # Copy LISTVAR to OUTVAR except for the entries in REMOVEVAR.
  12 # Elements separated by whitespace.  In set logic terms, the function
  13 # does OUTVAR = LISTVAR \ REMOVEVAR.
  14 AC_DEFUN([gl_MANYWARN_COMPLEMENT],
  15 [
  16   gl_warn_set=
  17   set x $2; shift
  18   for gl_warn_item
  19   do
  20     case " $3 " in
  21       *" $gl_warn_item "*)
  22         ;;
  23       *)
  24         gl_warn_set="$gl_warn_set $gl_warn_item"
  25         ;;
  26     esac
  27   done
  28   $1=$gl_warn_set
  29 ])
  30
  31 # gl_MANYWARN_ALL_GCC(VARIABLE)
  32 # -----------------------------
  33 # Add all documented GCC warning parameters to variable VARIABLE.
  34 # Note that you need to test them using gl_WARN_ADD if you want to
  35 # make sure your gcc understands it.
  36 AC_DEFUN([gl_MANYWARN_ALL_GCC],
  37 [
  38   dnl First, check for some issues that only occur when combining multiple
  39   dnl gcc warning categories.
  40   AC_REQUIRE([AC_PROG_CC])
  41   if test -n "$GCC"; then
  42
  43     dnl Check if -W -Werror -Wno-missing-field-initializers is supported
  44     dnl with the current $CC $CFLAGS $CPPFLAGS.
  45     AC_MSG_CHECKING([whether -Wno-missing-field-initializers is supported])
  46     AC_CACHE_VAL([gl_cv_cc_nomfi_supported], [
  47       gl_save_CFLAGS="$CFLAGS"
  48       CFLAGS="$CFLAGS -W -Werror -Wno-missing-field-initializers"
  49       AC_COMPILE_IFELSE(
  50         [AC_LANG_PROGRAM([[]], [[]])],
  51         [gl_cv_cc_nomfi_supported=yes],
  52         [gl_cv_cc_nomfi_supported=no])
  53       CFLAGS="$gl_save_CFLAGS"])
  54     AC_MSG_RESULT([$gl_cv_cc_nomfi_supported])
  55
  56     if test "$gl_cv_cc_nomfi_supported" = yes; then
  57       dnl Now check whether -Wno-missing-field-initializers is needed
  58       dnl for the { 0, } construct.
  59       AC_MSG_CHECKING([whether -Wno-missing-field-initializers is needed])
  60       AC_CACHE_VAL([gl_cv_cc_nomfi_needed], [
  61         gl_save_CFLAGS="$CFLAGS"
  62         CFLAGS="$CFLAGS -W -Werror"
  63         AC_COMPILE_IFELSE(
  64           [AC_LANG_PROGRAM(
  65              [[void f (void)
  66                {
  67                  typedef struct { int a; int b; } s_t;
  68                  s_t s1 = { 0, };
  69                }
  70              ]],
  71              [[]])],
  72           [gl_cv_cc_nomfi_needed=no],
  73           [gl_cv_cc_nomfi_needed=yes])
  74         CFLAGS="$gl_save_CFLAGS"
  75       ])
  76       AC_MSG_RESULT([$gl_cv_cc_nomfi_needed])
  77     fi
  78
  79     dnl Next, check if -Werror -Wuninitialized is useful with the
  80     dnl user's choice of $CFLAGS; some versions of gcc warn that it
  81     dnl has no effect if -O is not also used
  82     AC_MSG_CHECKING([whether -Wuninitialized is supported])
  83     AC_CACHE_VAL([gl_cv_cc_uninitialized_supported], [
  84       gl_save_CFLAGS="$CFLAGS"
  85       CFLAGS="$CFLAGS -Werror -Wuninitialized"
  86       AC_COMPILE_IFELSE(
  87         [AC_LANG_PROGRAM([[]], [[]])],
  88         [gl_cv_cc_uninitialized_supported=yes],
  89         [gl_cv_cc_uninitialized_supported=no])
  90       CFLAGS="$gl_save_CFLAGS"])
  91     AC_MSG_RESULT([$gl_cv_cc_uninitialized_supported])
  92
  93   fi
  94
  95   # List all gcc warning categories.
  96   # To compare this list to your installed GCC's, run this Bash command:
  97   #
  98   # comm -3 \
  99   #  <(sed -n 's/^  *\(-[^ ]*\) .*/\1/p' manywarnings.m4 | sort) \
 100   #  <(gcc --help=warnings | sed -n 's/^  \(-[^ ]*\) .*/\1/p' | sort |
 101   #      grep -v -x -f <(
 102   #         awk '/^[^#]/ {print $1}' ../build-aux/gcc-warning.spec))
 103
 104   gl_manywarn_set=
 105   for gl_manywarn_item in \
 106     -W \
 107     -Wabi \
 108     -Waddress \
 109     -Waggressive-loop-optimizations \
 110     -Wall \
 111     -Wattributes \
 112     -Wbad-function-cast \
 113     -Wbool-compare \
 114     -Wbuiltin-macro-redefined \
 115     -Wcast-align \
 116     -Wchar-subscripts \
 117     -Wchkp \
 118     -Wclobbered \
 119     -Wcomment \
 120     -Wcomments \
 121     -Wcoverage-mismatch \
 122     -Wcpp \
 123     -Wdate-time \
 124     -Wdeprecated \
 125     -Wdeprecated-declarations \
 126     -Wdesignated-init \
 127     -Wdisabled-optimization \
 128     -Wdiscarded-array-qualifiers \
 129     -Wdiscarded-qualifiers \
 130     -Wdiv-by-zero \
 131     -Wdouble-promotion \
 132     -Wempty-body \
 133     -Wendif-labels \
 134     -Wenum-compare \
 135     -Wextra \
 136     -Wformat-contains-nul \
 137     -Wformat-extra-args \
 138     -Wformat-nonliteral \
 139     -Wformat-security \
 140     -Wformat-signedness \
 141     -Wformat-y2k \
 142     -Wformat-zero-length \
 143     -Wfree-nonheap-object \
 144     -Wignored-qualifiers \
 145     -Wimplicit \
 146     -Wimplicit-function-declaration \
 147     -Wimplicit-int \
 148     -Wincompatible-pointer-types \
 149     -Winit-self \
 150     -Winline \
 151     -Wint-conversion \
 152     -Wint-to-pointer-cast \
 153     -Winvalid-memory-model \
 154     -Winvalid-pch \
 155     -Wjump-misses-init \
 156     -Wlogical-not-parentheses \
 157     -Wlogical-op \
 158     -Wmain \
 159     -Wmaybe-uninitialized \
 160     -Wmemset-transposed-args \
 161     -Wmissing-braces \
 162     -Wmissing-declarations \
 163     -Wmissing-field-initializers \
 164     -Wmissing-include-dirs \
 165     -Wmissing-parameter-type \
 166     -Wmissing-prototypes \
 167     -Wmultichar \
 168     -Wnarrowing \
 169     -Wnested-externs \
 170     -Wnonnull \
 171     -Wodr \
 172     -Wold-style-declaration \
 173     -Wold-style-definition \
 174     -Wopenmp-simd \
 175     -Woverflow \
 176     -Woverlength-strings \
 177     -Woverride-init \
 178     -Wpacked \
 179     -Wpacked-bitfield-compat \
 180     -Wparentheses \
 181     -Wpointer-arith \
 182     -Wpointer-sign \
 183     -Wpointer-to-int-cast \
 184     -Wpragmas \
 185     -Wreturn-local-addr \
 186     -Wreturn-type \
 187     -Wsequence-point \
 188     -Wshadow \
 189     -Wshift-count-negative \
 190     -Wshift-count-overflow \
 191     -Wsizeof-array-argument \
 192     -Wsizeof-pointer-memaccess \
 193     -Wstack-protector \
 194     -Wstrict-aliasing \
 195     -Wstrict-overflow \
 196     -Wstrict-prototypes \
 197     -Wsuggest-attribute=const \
 198     -Wsuggest-attribute=format \
 199     -Wsuggest-attribute=noreturn \
 200     -Wsuggest-attribute=pure \
 201     -Wsuggest-final-methods \
 202     -Wsuggest-final-types \
 203     -Wswitch \
 204     -Wswitch-bool \
 205     -Wswitch-default \
 206     -Wsync-nand \
 207     -Wsystem-headers \
 208     -Wtrampolines \
 209     -Wtrigraphs \
 210     -Wtype-limits \
 211     -Wuninitialized \
 212     -Wunknown-pragmas \
 213     -Wunsafe-loop-optimizations \
 214     -Wunused \
 215     -Wunused-but-set-parameter \
 216     -Wunused-but-set-variable \
 217     -Wunused-function \
 218     -Wunused-label \
 219     -Wunused-local-typedefs \
 220     -Wunused-macros \
 221     -Wunused-parameter \
 222     -Wunused-result \
 223     -Wunused-value \
 224     -Wunused-variable \
 225     -Wvarargs \
 226     -Wvariadic-macros \
 227     -Wvector-operation-performance \
 228     -Wvla \
 229     -Wvolatile-register-var \
 230     -Wwrite-strings \
 231     \
 232     ; do
 233     gl_manywarn_set="$gl_manywarn_set $gl_manywarn_item"
 234   done
 235
 236   # gcc --help=warnings outputs an unusual form for these options; list
 237   # them here so that the above 'comm' command doesn't report a false match.
 238   gl_manywarn_set="$gl_manywarn_set -Warray-bounds=2"
 239   gl_manywarn_set="$gl_manywarn_set -Wnormalized=nfc"
 240
 241   # These are needed for older GCC versions.
 242   if test -n "$GCC"; then
 243     case `($CC --version) 2>/dev/null` in
 244       'gcc (GCC) '[[0-3]].* | \
 245       'gcc (GCC) '4.[[0-7]].*)
 246         gl_manywarn_set="$gl_manywarn_set -fdiagnostics-show-option"
 247         gl_manywarn_set="$gl_manywarn_set -funit-at-a-time"
 248           ;;
 249     esac
 250   fi
 251
 252   # Disable specific options as needed.
 253   if test "$gl_cv_cc_nomfi_needed" = yes; then
 254     gl_manywarn_set="$gl_manywarn_set -Wno-missing-field-initializers"
 255   fi
 256
 257   if test "$gl_cv_cc_uninitialized_supported" = no; then
 258     gl_manywarn_set="$gl_manywarn_set -Wno-uninitialized"
 259   fi
 260
 261   $1=$gl_manywarn_set
 262 ])