git.gag.com Git - debian/gzip/blob - m4/fprintf-posix.m4

   1 # fprintf-posix.m4 serial 14
   2 dnl Copyright (C) 2007-2016 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  10   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  11   AC_REQUIRE([gl_PRINTF_INFINITE])
  12   AC_REQUIRE([gl_PRINTF_INFINITE_LONG_DOUBLE])
  13   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  15   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  16   AC_REQUIRE([gl_PRINTF_DIRECTIVE_LS])
  17   AC_REQUIRE([gl_PRINTF_POSITIONS])
  18   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  19   AC_REQUIRE([gl_PRINTF_FLAG_LEFTADJUST])
  20   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  21   AC_REQUIRE([gl_PRINTF_PRECISION])
  22   AC_REQUIRE([gl_PRINTF_ENOMEM])
  23   gl_cv_func_fprintf_posix=no
  24   case "$gl_cv_func_printf_sizes_c99" in
  25     *yes)
  26       case "$gl_cv_func_printf_long_double" in
  27         *yes)
  28           case "$gl_cv_func_printf_infinite" in
  29             *yes)
  30               case "$gl_cv_func_printf_infinite_long_double" in
  31                 *yes)
  32                   case "$gl_cv_func_printf_directive_a" in
  33                     *yes)
  34                       case "$gl_cv_func_printf_directive_f" in
  35                         *yes)
  36                           case "$gl_cv_func_printf_directive_n" in
  37                             *yes)
  38                               case "$gl_cv_func_printf_directive_ls" in
  39                                 *yes)
  40                                   case "$gl_cv_func_printf_positions" in
  41                                     *yes)
  42                                       case "$gl_cv_func_printf_flag_grouping" in
  43                                         *yes)
  44                                           case "$gl_cv_func_printf_flag_leftadjust" in
  45                                             *yes)
  46                                               case "$gl_cv_func_printf_flag_zero" in
  47                                                 *yes)
  48                                                   case "$gl_cv_func_printf_precision" in
  49                                                     *yes)
  50                                                       case "$gl_cv_func_printf_enomem" in
  51                                                         *yes)
  52                                                           # fprintf exists and is
  53                                                           # already POSIX compliant.
  54                                                           gl_cv_func_fprintf_posix=yes
  55                                                           ;;
  56                                                       esac
  57                                                       ;;
  58                                                   esac
  59                                                   ;;
  60                                               esac
  61                                               ;;
  62                                           esac
  63                                           ;;
  64                                       esac
  65                                       ;;
  66                                   esac
  67                                   ;;
  68                               esac
  69                               ;;
  70                           esac
  71                           ;;
  72                       esac
  73                       ;;
  74                   esac
  75                   ;;
  76               esac
  77               ;;
  78           esac
  79           ;;
  80       esac
  81       ;;
  82   esac
  83   if test $gl_cv_func_fprintf_posix = no; then
  84     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  85     gl_PREREQ_VASNPRINTF_INFINITE_DOUBLE
  86     gl_PREREQ_VASNPRINTF_INFINITE_LONG_DOUBLE
  87     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  88     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  89     gl_PREREQ_VASNPRINTF_DIRECTIVE_LS
  90     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  91     gl_PREREQ_VASNPRINTF_FLAG_LEFTADJUST
  92     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  93     gl_PREREQ_VASNPRINTF_PRECISION
  94     gl_PREREQ_VASNPRINTF_ENOMEM
  95     gl_REPLACE_VASNPRINTF
  96     gl_REPLACE_FPRINTF
  97   fi
  98 ])
  99
 100 AC_DEFUN([gl_REPLACE_FPRINTF],
 101 [
 102   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
 103   AC_LIBOBJ([fprintf])
 104   REPLACE_FPRINTF=1
 105   AC_DEFINE([REPLACE_FPRINTF_POSIX], [1],
 106     [Define if fprintf is overridden by a POSIX compliant gnulib implementation.])
 107   gl_PREREQ_FPRINTF
 108 ])
 109
 110 AC_DEFUN([gl_PREREQ_FPRINTF], [:])