git.gag.com Git - debian/gzip/blob - m4/exponentl.m4

   1 # exponentl.m4 serial 2
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6 AC_DEFUN([gl_LONG_DOUBLE_EXPONENT_LOCATION],
   7 [
   8   AC_REQUIRE([gl_BIGENDIAN])
   9   AC_CACHE_CHECK([where to find the exponent in a 'long double'],
  10     [gl_cv_cc_long_double_expbit0],
  11     [
  12       AC_TRY_RUN([
  13 #include <float.h>
  14 #include <stddef.h>
  15 #include <stdio.h>
  16 #include <string.h>
  17 #define NWORDS \
  18   ((sizeof (long double) + sizeof (unsigned int) - 1) / sizeof (unsigned int))
  19 typedef union { long double value; unsigned int word[NWORDS]; }
  20         memory_long_double;
  21 static unsigned int ored_words[NWORDS];
  22 static unsigned int anded_words[NWORDS];
  23 static void add_to_ored_words (long double x)
  24 {
  25   memory_long_double m;
  26   size_t i;
  27   /* Clear it first, in case
  28      sizeof (long double) < sizeof (memory_long_double).  */
  29   memset (&m, 0, sizeof (memory_long_double));
  30   m.value = x;
  31   for (i = 0; i < NWORDS; i++)
  32     {
  33       ored_words[i] |= m.word[i];
  34       anded_words[i] &= m.word[i];
  35     }
  36 }
  37 int main ()
  38 {
  39   size_t j;
  40   FILE *fp = fopen ("conftest.out", "w");
  41   if (fp == NULL)
  42     return 1;
  43   for (j = 0; j < NWORDS; j++)
  44     anded_words[j] = ~ (unsigned int) 0;
  45   add_to_ored_words (0.25L);
  46   add_to_ored_words (0.5L);
  47   add_to_ored_words (1.0L);
  48   add_to_ored_words (2.0L);
  49   add_to_ored_words (4.0L);
  50   /* Remove bits that are common (e.g. if representation of the first mantissa
  51      bit is explicit).  */
  52   for (j = 0; j < NWORDS; j++)
  53     ored_words[j] &= ~anded_words[j];
  54   /* Now find the nonzero word.  */
  55   for (j = 0; j < NWORDS; j++)
  56     if (ored_words[j] != 0)
  57       break;
  58   if (j < NWORDS)
  59     {
  60       size_t i;
  61       for (i = j + 1; i < NWORDS; i++)
  62         if (ored_words[i] != 0)
  63           {
  64             fprintf (fp, "unknown");
  65             return (fclose (fp) != 0);
  66           }
  67       for (i = 0; ; i++)
  68         if ((ored_words[j] >> i) & 1)
  69           {
  70             fprintf (fp, "word %d bit %d", (int) j, (int) i);
  71             return (fclose (fp) != 0);
  72           }
  73     }
  74   fprintf (fp, "unknown");
  75   return (fclose (fp) != 0);
  76 }
  77         ],
  78         [gl_cv_cc_long_double_expbit0=`cat conftest.out`],
  79         [gl_cv_cc_long_double_expbit0="unknown"],
  80         [
  81           dnl When cross-compiling, we don't know. It depends on the
  82           dnl ABI and compiler version. There are too many cases.
  83           gl_cv_cc_long_double_expbit0="unknown"
  84         ])
  85       rm -f conftest.out
  86     ])
  87   case "$gl_cv_cc_long_double_expbit0" in
  88     word*bit*)
  89       word=`echo "$gl_cv_cc_long_double_expbit0" | sed -e 's/word //' -e 's/ bit.*//'`
  90       bit=`echo "$gl_cv_cc_long_double_expbit0" | sed -e 's/word.*bit //'`
  91       AC_DEFINE_UNQUOTED([LDBL_EXPBIT0_WORD], [$word],
  92         [Define as the word index where to find the exponent of 'long double'.])
  93       AC_DEFINE_UNQUOTED([LDBL_EXPBIT0_BIT], [$bit],
  94         [Define as the bit index in the word where to find bit 0 of the exponent of 'long double'.])
  95       ;;
  96   esac
  97 ])