git.gag.com Git - debian/gzip/blob - configure.ac

   1 # Configure template for gzip.
   2
   3 # Copyright (C) 1999-2002, 2006-2007, 2009-2010 Free Software Foundation, Inc.
   4
   5 # Copyright (C) 1992-1993 Jean-loup Gailly
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3, or (at your option)
  10 # any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 # 02111-1307, USA.
  21
  22 AC_PREREQ([2.60])
  23 AC_INIT([gzip],
  24         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  25         [bug-gzip@gnu.org])
  26
  27 AC_CONFIG_SRCDIR(gzip.c)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  30 AM_INIT_AUTOMAKE([1.11 dist-xz color-tests parallel-tests])
  31 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  32
  33 AC_PROG_CC_STDC
  34 AM_PROG_CC_C_O
  35 AC_PROG_CPP
  36 AC_CHECK_TOOL([NM], [nm], [nm])
  37 AC_PROG_LN_S
  38 AC_PROG_RANLIB
  39 AC_PROG_SHELL
  40
  41 gl_EARLY
  42 AC_SYS_LARGEFILE
  43
  44 gl_INIT
  45
  46 AC_ARG_ENABLE([gcc-warnings],
  47   [AS_HELP_STRING([--enable-gcc-warnings],
  48                   [turn on lots of GCC warnings (for developers)])],
  49   [case $enableval in
  50      yes|no) ;;
  51      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  52    esac
  53    gl_gcc_warnings=$enableval],
  54   [gl_gcc_warnings=no]
  55 )
  56
  57 if test "$gl_gcc_warnings" = yes; then
  58   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  59   AC_SUBST([WERROR_CFLAGS])
  60
  61   nw=
  62   # This, $nw, is the list of warnings we disable.
  63   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  64   nw="$nw -Waggregate-return"       # anachronistic
  65   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
  66   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  67   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  68   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  69   nw="$nw -Wcast-qual"              # Too many warnings for now
  70   nw="$nw -Wconversion"             # Too many warnings for now
  71   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  72   nw="$nw -Wsign-conversion"        # Too many warnings for now
  73   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  74   nw="$nw -Wunreachable-code"       # Too many warnings for now
  75   nw="$nw -Wpadded"                 # Our structs are not padded
  76   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  77   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  78   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
  79   nw="$nw -Wvla"                    # warnings in gettext.h
  80   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
  81   nw="$nw -Wswitch-enum"            # Too many warnings for now
  82   nw="$nw -Wswitch-default"         # Too many warnings for now
  83   nw="$nw -Wstack-protector"        # not worth working around
  84   # things I might fix soon:
  85   nw="$nw -Wfloat-equal"            # sort.c, seq.c
  86   nw="$nw -Wmissing-format-attribute" # copy.c
  87   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
  88   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
  89   nw="$nw -Wstrict-overflow"        # expr.c, pr.c, tr.c, factor.c
  90   # initial problems in gzip
  91   nw="$nw -Wold-style-definition"
  92   nw="$nw -Wshadow"
  93   nw="$nw -Wunused-macros"
  94   # ?? -Wstrict-overflow
  95
  96   gl_MANYWARN_ALL_GCC([ws])
  97   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  98   for w in $ws; do
  99     gl_WARN_ADD([$w])
 100   done
 101   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 102   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 103   gl_WARN_ADD([-Wno-pointer-sign])     # Too many warnings for now
 104   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 105   gl_WARN_ADD([-Wno-overflow])         # util.c
 106   gl_WARN_ADD([-Wno-type-limits])      # util.c
 107
 108   # In spite of excluding -Wlogical-op above, it is enabled, as of
 109   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 110   gl_WARN_ADD([-Wno-logical-op])
 111
 112   gl_WARN_ADD([-fdiagnostics-show-option])
 113   gl_WARN_ADD([-funit-at-a-time])
 114
 115   AC_SUBST([WARN_CFLAGS])
 116
 117   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 118   AC_DEFINE([_FORTIFY_SOURCE], [2],
 119     [enable compile-time and run-time bounds-checking, and some warnings])
 120   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 121
 122   # We use a slightly smaller set of warning options for lib/.
 123   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 124   nw=
 125   nw="$nw -Wuninitialized"
 126   nw="$nw -Wmissing-prototypes"
 127   nw="$nw -Wold-style-definition"
 128   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 129   AC_SUBST([GNULIB_WARN_CFLAGS])
 130 fi
 131
 132 # cc -E produces incorrect asm files on SVR4, so postprocess it.
 133 ASCPPPOST="sed '/^ *#/d; s,//.*,,; s/% /%/g; s/\\. /./g'"
 134 AC_SUBST([ASCPPPOST])
 135
 136 AC_CACHE_CHECK([for underline in external names], [gzip_cv_underline],
 137   [gzip_cv_underline=yes
 138    AC_TRY_COMPILE([int foo() {return 0;}], [],
 139      [$NM conftest.$OBJEXT | grep _foo >/dev/null 2>&1 ||
 140         gzip_cv_underline=no])])
 141 ASCPPFLAGS=
 142 if test $gzip_cv_underline = no; then
 143   ASCPPFLAGS='-DNO_UNDERLINE'
 144 fi
 145 AC_SUBST([ASCPPFLAGS])
 146 AC_OBJEXT
 147
 148 # Try to assemble match.S.
 149 # "gcc -E match.s" ignores -E, so we must use _match.S.
 150 AC_CACHE_CHECK([for an assembler syntax supported by this package],
 151   [gzip_cv_assembler],
 152   [gzip_cv_assembler=no
 153    case " $DEFS " in
 154    *' NO_ASM '*) ;;
 155    *)
 156      if cp $srcdir/lib/match.c _match.S &&
 157         eval "$CPP $CPPFLAGS $ASCPPFLAGS _match.S > _match.i" 2>/dev/null &&
 158         eval "$ASCPPPOST < _match.i > match_.s" 2>/dev/null; then
 159        if test ! -s match_.s || grep error < match_.s > /dev/null; then
 160          :
 161        elif eval "$CC $CPPFLAGS $CFLAGS -c match_.s >/dev/null 2>&1" &&
 162             test -f match_.$OBJEXT; then
 163          rm -f match_.$OBJEXT
 164          gzip_cv_assembler=yes
 165          if echo 'void foo (void) {}' > conftest.c &&
 166             eval "$CC $CPPFLAGS $CFLAGS -S conftest.c >/dev/null 2>&1" &&
 167             grep '\.note\.GNU-stack' conftest.s >/dev/null 2>&1 &&
 168             eval "$CC $CPPFLAGS $CFLAGS -c -Wa,--noexecstack match_.s >/dev/null 2>&1" &&
 169             test -f match_.$OBJEXT; then
 170            gzip_cv_assembler='yes, with -Wa,--noexecstack'
 171          fi
 172        fi
 173      fi
 174      rm -f conftest* _match.i _match.S match_.s match_.$OBJEXT;;
 175    esac])
 176 if test "$gzip_cv_assembler" != no; then
 177   AC_DEFINE(ASMV, ,
 178     [Define if an assembler version of longest_match is available.])
 179   AC_LIBOBJ(match)
 180 fi
 181 if test "$gzip_cv_assembler" = 'yes, with -Wa,--noexecstack'; then
 182   ASFLAGS_config='-Wa,--noexecstack'
 183 else
 184   ASFLAGS_config=
 185 fi
 186 AC_SUBST([ASFLAGS_config])
 187
 188 AC_ISC_POSIX
 189 AC_C_CONST
 190 AC_HEADER_STDC
 191 AC_CHECK_HEADERS_ONCE(fcntl.h limits.h memory.h time.h)
 192 AC_CHECK_FUNCS_ONCE([chown fchmod fchown lstat siginterrupt])
 193 AC_HEADER_DIRENT
 194 AC_TYPE_SIGNAL
 195 AC_TYPE_SIZE_T
 196 AC_TYPE_OFF_T
 197
 198 AC_CONFIG_FILES([Makefile doc/Makefile lib/Makefile])
 199 AC_OUTPUT