git.gag.com Git - debian/gzip/blob - configure.ac

   1 # Configure template for gzip.
   2
   3 # Copyright (C) 1999-2002, 2006-2007, 2009-2016 Free Software Foundation, Inc.
   4
   5 # Copyright (C) 1992-1993 Jean-loup Gailly
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3, or (at your option)
  10 # any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 # 02111-1307, USA.
  21
  22 AC_PREREQ([2.60])
  23 AC_INIT([gzip],
  24         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  25         [bug-gzip@gnu.org])
  26
  27 AC_CONFIG_SRCDIR([gzip.c])
  28 AC_CONFIG_AUX_DIR([build-aux])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  31 AM_INIT_AUTOMAKE([1.11 subdir-objects dist-xz color-tests parallel-tests])
  32 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  33
  34 dnl POSIXCHECK is worthwhile for maintainers, but adds several seconds
  35 dnl (more than 10% execution time) to ./configure, with no benefit for
  36 dnl most users.  Using it to look for bugs requires:
  37 dnl   GNULIB_POSIXCHECK=1 autoreconf -f
  38 dnl   ./configure
  39 dnl   make
  40 dnl   make -C src clean
  41 dnl   make CFLAGS=-DGNULIB_POSIXCHECK=1
  42 dnl FIXME: Once we figure out how to avoid false positives, we should
  43 dnl have 'make my-distcheck' in dist-check.mk exercise this.
  44 m4_syscmd([test "${GNULIB_POSIXCHECK+set}" = set])
  45 m4_if(m4_sysval, [0], [], [dnl
  46 gl_ASSERT_NO_GNULIB_POSIXCHECK])
  47
  48 AC_PROG_CC_STDC
  49 AM_PROG_CC_C_O
  50 AC_PROG_CPP
  51 AC_PROG_GREP
  52 AC_CHECK_TOOL([NM], [nm], [nm])
  53 AC_PROG_LN_S
  54 AC_PROG_RANLIB
  55 AC_PROG_SHELL
  56
  57 gl_EARLY
  58
  59 gl_INIT
  60
  61 AC_ARG_ENABLE([gcc-warnings],
  62   [AS_HELP_STRING([--enable-gcc-warnings],
  63      [turn on many GCC warnings (for developers; best with GNU make)])],
  64   [case $enableval in
  65      yes|no) ;;
  66      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  67    esac
  68    gl_gcc_warnings=$enableval],
  69   [if test -d "$srcdir"/.git; then
  70      gl_gcc_warnings=yes
  71    else
  72      gl_gcc_warnings=no
  73    fi]
  74 )
  75
  76 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
  77 # ------------------------------------------------
  78 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
  79 # Otherwise, run RUN-IF-NOT-FOUND.
  80 AC_DEFUN([gl_GCC_VERSION_IFELSE],
  81   [AC_PREPROC_IFELSE(
  82     [AC_LANG_PROGRAM(
  83       [[
  84 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
  85 /* ok */
  86 #else
  87 # error "your version of gcc is older than $1.$2"
  88 #endif
  89       ]]),
  90     ], [$3], [$4])
  91   ]
  92 )
  93
  94 if test "$gl_gcc_warnings" = yes; then
  95   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  96   AC_SUBST([WERROR_CFLAGS])
  97
  98   nw=
  99   # This, $nw, is the list of warnings we disable.
 100   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
 101   nw="$nw -Waggregate-return"       # anachronistic
 102   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
 103   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 104   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 105   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 106   nw="$nw -Wcast-qual"              # Too many warnings for now
 107   nw="$nw -Wconversion"             # Too many warnings for now
 108   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 109   nw="$nw -Wsign-conversion"        # Too many warnings for now
 110   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 111   nw="$nw -Wunreachable-code"       # Too many warnings for now
 112   nw="$nw -Wpadded"                 # Our structs are not padded
 113   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 114   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 115   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
 116   nw="$nw -Wvla"                    # warnings in gettext.h
 117   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 118   nw="$nw -Wswitch-enum"            # Too many warnings for now
 119   nw="$nw -Wswitch-default"         # Too many warnings for now
 120   nw="$nw -Wstack-protector"        # not worth working around
 121   # things I might fix soon:
 122   nw="$nw -Wfloat-equal"            # sort.c, seq.c
 123   nw="$nw -Wmissing-format-attribute" # copy.c
 124   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
 125   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
 126
 127   # Warnings that gzip runs afoul of but coreutils does not.
 128   nw="$nw -Wold-style-definition"
 129   nw="$nw -Wshadow"
 130   nw="$nw -Wstrict-overflow"
 131
 132   # Using -Wstrict-overflow is a pain, but the alternative is worse.
 133   # For an example, see the code that provoked this report:
 134   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=33498
 135   # Code like that still infloops with gcc-4.6.0 and -O2.  Scary indeed.
 136
 137   gl_MANYWARN_ALL_GCC([ws])
 138   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 139   for w in $ws; do
 140     gl_WARN_ADD([$w])
 141   done
 142   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 143   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 144   gl_WARN_ADD([-Wsuggest-attribute=const])
 145   gl_WARN_ADD([-Wsuggest-attribute=noreturn])
 146   gl_WARN_ADD([-Wno-format-nonliteral])
 147
 148   # Enable this warning only with gcc-4.7 and newer.  With 4.6.2 20111027,
 149   # it suggests test.c's advance function may be pure, even though it
 150   # increments a global variable.  Oops.
 151   # Normally we'd write code to test for the precise failure, but that
 152   # requires a relatively large input to make gcc exhibit the failure.
 153   gl_GCC_VERSION_IFELSE([4], [7], [gl_WARN_ADD([-Wsuggest-attribute=pure])])
 154
 155   # In spite of excluding -Wlogical-op above, it is enabled, as of
 156   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 157   gl_WARN_ADD([-Wno-logical-op])
 158
 159   gl_WARN_ADD([-fdiagnostics-show-option])
 160   gl_WARN_ADD([-funit-at-a-time])
 161
 162   AC_SUBST([WARN_CFLAGS])
 163
 164   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 165   AH_VERBATIM([FORTIFY_SOURCE],
 166   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 167       without upsetting glibc 2.15+. */
 168    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 169    # define _FORTIFY_SOURCE 2
 170    #endif
 171   ])
 172   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 173
 174   # We use a slightly smaller set of warning options for lib/.
 175   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 176   nw=
 177   nw="$nw -Wstrict-overflow"
 178   nw="$nw -Wuninitialized"
 179   nw="$nw -Wunused-macros"
 180   nw="$nw -Wmissing-prototypes"
 181   nw="$nw -Wold-style-definition"
 182   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 183   AC_SUBST([GNULIB_WARN_CFLAGS])
 184 fi
 185
 186 # cc -E produces incorrect asm files on SVR4, so postprocess it.
 187 ASCPPPOST="sed '/^ *\\#/d; s,//.*,,; s/% /%/g; s/\\. /./g'"
 188 AC_SUBST([ASCPPPOST])
 189
 190 AC_CACHE_CHECK([for underline in external names], [gzip_cv_underline],
 191   [gzip_cv_underline=yes
 192    AC_TRY_COMPILE([int foo() {return 0;}], [],
 193      [$NM conftest.$OBJEXT | grep _foo >/dev/null 2>&1 ||
 194         gzip_cv_underline=no])])
 195 ASCPPFLAGS=
 196 if test $gzip_cv_underline = no; then
 197   ASCPPFLAGS='-DNO_UNDERLINE'
 198 fi
 199 AC_SUBST([ASCPPFLAGS])
 200 AC_OBJEXT
 201
 202 # Try to assemble match.S.
 203 # "gcc -E match.s" ignores -E, so we must use _match.S.
 204 AC_CACHE_CHECK([for an assembler syntax supported by this package],
 205   [gzip_cv_assembler],
 206   [gzip_cv_assembler=no
 207    case $DEFS in
 208    *NO_ASM*) ;;
 209    *)
 210      if cp $srcdir/lib/match.c _match.S &&
 211         eval "$CPP $CPPFLAGS $ASCPPFLAGS _match.S > _match.i" &&
 212         eval "$ASCPPPOST < _match.i > match_.s"; then
 213        if test ! -s match_.s || grep error < match_.s > /dev/null; then
 214          :
 215        elif eval "$CC $CPPFLAGS $CFLAGS -c match_.s >/dev/null" &&
 216             test -f match_.$OBJEXT; then
 217          rm -f match_.$OBJEXT
 218          gzip_cv_assembler=yes
 219          if echo 'void foo (void) {}' > conftest.c &&
 220             eval "$CC $CPPFLAGS $CFLAGS -S conftest.c >/dev/null" &&
 221             grep '\.note\.GNU-stack' conftest.s >/dev/null &&
 222             eval "$CC $CPPFLAGS $CFLAGS -c -Wa,--noexecstack match_.s >/dev/null" &&
 223             test -f match_.$OBJEXT; then
 224            gzip_cv_assembler='yes, with -Wa,--noexecstack'
 225          fi
 226        fi
 227      fi
 228      rm -f conftest* _match.i _match.S match_.s match_.$OBJEXT;;
 229    esac])
 230 if test "$gzip_cv_assembler" != no; then
 231   AC_DEFINE([ASMV], ,
 232     [Define if an assembler version of longest_match is available.])
 233   AC_LIBOBJ(match)
 234 fi
 235 if test "$gzip_cv_assembler" = 'yes, with -Wa,--noexecstack'; then
 236   ASFLAGS_config='-Wa,--noexecstack'
 237 else
 238   ASFLAGS_config=
 239 fi
 240 AC_SUBST([ASFLAGS_config])
 241
 242 AC_ISC_POSIX
 243 AC_C_CONST
 244 AC_HEADER_STDC
 245 AC_CHECK_HEADERS_ONCE(fcntl.h limits.h memory.h time.h)
 246 AC_CHECK_FUNCS_ONCE([chown fchmod fchown lstat siginterrupt])
 247 AC_HEADER_DIRENT
 248 AC_TYPE_SIGNAL
 249 AC_TYPE_SIZE_T
 250 AC_TYPE_OFF_T
 251
 252 AC_CONFIG_FILES([Makefile doc/Makefile lib/Makefile tests/Makefile])
 253 AC_OUTPUT