git.gag.com Git - debian/elilo/blob - ia64/longjmp.S

   1 /* Copyright (C) 1999, 2000, 2001, 2002  Free Software Foundation, Inc.
   2    Contributed by David Mosberger-Tang <davidm@hpl.hp.com>.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.
  18
  19    Note that __sigsetjmp() did NOT flush the register stack.  Instead,
  20    we do it here since __longjmp() is usually much less frequently
  21    invoked than __sigsetjmp(). The only difficulty is that __sigsetjmp()
  22    didn't (and wouldn't be able to) save ar.rnat either.  This is a problem
  23    because if we're not careful, we could end up loading random NaT bits.
  24    There are two cases:
  25
  26         (i)  ar.bsp < ia64_rse_rnat_addr(jmpbuf.ar_bsp)
  27                 ar.rnat contains the desired bits---preserve ar.rnat
  28                 across loadrs and write to ar.bspstore
  29
  30         (ii) ar.bsp >= ia64_rse_rnat_addr(jmpbuf.ar_bsp)
  31                 The desired ar.rnat is stored in
  32                 ia64_rse_rnat_addr(jmpbuf.ar_bsp).  Load those
  33                 bits into ar.rnat after setting ar.bspstore. */
  34
  35
  36
  37 #       define  pPos    p6      /* is rotate count positive? */
  38 #       define  pNeg    p7      /* is rotate count negative? */
  39
  40
  41         /* __longjmp(__jmp_buf buf, int val) */
  42
  43         .text
  44         .global longjmp
  45         .proc longjmp
  46 longjmp:
  47         alloc r8=ar.pfs,2,1,0,0
  48         mov r27=ar.rsc
  49         add r2=0x98,in0         // r2 <- &jmpbuf.orig_jmp_buf_addr
  50         ;;
  51         ld8 r8=[r2],-16         // r8 <- orig_jmp_buf_addr
  52         mov r10=ar.bsp
  53         and r11=~0x3,r27        // clear ar.rsc.mode
  54         ;;
  55         flushrs                 // flush dirty regs to backing store (must be first in insn grp)
  56         ld8 r23=[r2],8          // r23 <- jmpbuf.ar_bsp
  57         sub r8=r8,in0           // r8 <- &orig_jmpbuf - &jmpbuf
  58         ;;
  59         ld8 r25=[r2]            // r25 <- jmpbuf.ar_unat
  60         extr.u r8=r8,3,6        // r8 <- (&orig_jmpbuf - &jmpbuf)/8 & 0x3f
  61         ;;
  62         cmp.lt pNeg,pPos=r8,r0
  63         mov r2=in0
  64         ;;
  65 (pPos)  mov r16=r8
  66 (pNeg)  add r16=64,r8
  67 (pPos)  sub r17=64,r8
  68 (pNeg)  sub r17=r0,r8
  69         ;;
  70         mov ar.rsc=r11          // put RSE in enforced lazy mode
  71         shr.u r8=r25,r16
  72         add r3=8,in0            // r3 <- &jmpbuf.r1
  73         shl r9=r25,r17
  74         ;;
  75         or r25=r8,r9
  76         ;;
  77         mov r26=ar.rnat
  78         mov ar.unat=r25         // setup ar.unat (NaT bits for r1, r4-r7, and r12)
  79         ;;
  80         ld8.fill.nta sp=[r2],16 // r12 (sp)
  81         ld8.fill.nta gp=[r3],16         // r1 (gp)
  82         dep r11=-1,r23,3,6      // r11 <- ia64_rse_rnat_addr(jmpbuf.ar_bsp)
  83         ;;
  84         ld8.nta r16=[r2],16             // caller's unat
  85         ld8.nta r17=[r3],16             // fpsr
  86         ;;
  87         ld8.fill.nta r4=[r2],16 // r4
  88         ld8.fill.nta r5=[r3],16         // r5 (gp)
  89         cmp.geu p8,p0=r10,r11   // p8 <- (ar.bsp >= jmpbuf.ar_bsp)
  90         ;;
  91         ld8.fill.nta r6=[r2],16 // r6
  92         ld8.fill.nta r7=[r3],16         // r7
  93         ;;
  94         mov ar.unat=r16                 // restore caller's unat
  95         mov ar.fpsr=r17                 // restore fpsr
  96         ;;
  97         ld8.nta r16=[r2],16             // b0
  98         ld8.nta r17=[r3],16             // b1
  99         ;;
 100 (p8)    ld8 r26=[r11]           // r26 <- *ia64_rse_rnat_addr(jmpbuf.ar_bsp)
 101         mov ar.bspstore=r23     // restore ar.bspstore
 102         ;;
 103         ld8.nta r18=[r2],16             // b2
 104         ld8.nta r19=[r3],16             // b3
 105         ;;
 106         ld8.nta r20=[r2],16             // b4
 107         ld8.nta r21=[r3],16             // b5
 108         ;;
 109         ld8.nta r11=[r2],16             // ar.pfs
 110         ld8.nta r22=[r3],56             // ar.lc
 111         ;;
 112         ld8.nta r24=[r2],32             // pr
 113         mov b0=r16
 114         ;;
 115         ldf.fill.nta f2=[r2],32
 116         ldf.fill.nta f3=[r3],32
 117         mov b1=r17
 118         ;;
 119         ldf.fill.nta f4=[r2],32
 120         ldf.fill.nta f5=[r3],32
 121         mov b2=r18
 122         ;;
 123         ldf.fill.nta f16=[r2],32
 124         ldf.fill.nta f17=[r3],32
 125         mov b3=r19
 126         ;;
 127         ldf.fill.nta f18=[r2],32
 128         ldf.fill.nta f19=[r3],32
 129         mov b4=r20
 130         ;;
 131         ldf.fill.nta f20=[r2],32
 132         ldf.fill.nta f21=[r3],32
 133         mov b5=r21
 134         ;;
 135         ldf.fill.nta f22=[r2],32
 136         ldf.fill.nta f23=[r3],32
 137         mov ar.lc=r22
 138         ;;
 139         ldf.fill.nta f24=[r2],32
 140         ldf.fill.nta f25=[r3],32
 141         cmp.eq p8,p9=0,in1
 142         ;;
 143         ldf.fill.nta f26=[r2],32
 144         ldf.fill.nta f27=[r3],32
 145         mov ar.pfs=r11
 146         ;;
 147         ldf.fill.nta f28=[r2],32
 148         ldf.fill.nta f29=[r3],32
 149         ;;
 150         ldf.fill.nta f30=[r2]
 151         ldf.fill.nta f31=[r3]
 152 (p8)    mov r8=1
 153
 154         mov ar.rnat=r26         // restore ar.rnat
 155         ;;
 156         mov ar.rsc=r27          // restore ar.rsc
 157 (p9)    mov r8=in1
 158
 159         invala                  // virt. -> phys. regnum mapping may change
 160         mov pr=r24,-1
 161         br.ret.dptk.few rp
 162         .endp longjmp