git.gag.com Git - debian/amanda/blob - perl/Amanda/Taper/Scan/oldest.pm

   1 # Copyright (c) 2010 Zmanda, Inc.  All Rights Reserved.
   2 #
   3 # This program is free software; you can redistribute it and/or modify it
   4 # under the terms of the GNU General Public License version 2 as published
   5 # by the Free Software Foundation.
   6 #
   7 # This program is distributed in the hope that it will be useful, but
   8 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
   9 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  10 # for more details.
  11 #
  12 # You should have received a copy of the GNU General Public License along
  13 # with this program; if not, write to the Free Software Foundation, Inc.,
  14 # 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  15 #
  16 # Contact information: Zmanda Inc., 465 S. Mathilda Ave., Suite 300
  17 # Sunnyvale, CA 94085, USA, or: http://www.zmanda.com
  18
  19 package Amanda::Taper::Scan::oldest;
  20
  21 =head1 NAME
  22
  23 Amanda::Taper::Scan::oldest
  24
  25 =head1 SYNOPSIS
  26
  27 This package implements the "oldest" taperscan algorithm.  See
  28 C<amanda-taperscan(7)>.
  29
  30 =cut
  31
  32 use strict;
  33 use warnings;
  34 use base qw( Amanda::ScanInventory Amanda::Taper::Scan );
  35 use Amanda::Tapelist;
  36 use Carp;
  37 use POSIX ();
  38 use Data::Dumper;
  39 use vars qw( @ISA );
  40 use base qw(Exporter);
  41 our @EXPORT_OK = qw($DEFAULT_CHANGER);
  42
  43 use Amanda::Paths;
  44 use Amanda::Util;
  45 use Amanda::Device qw( :constants );
  46 use Amanda::Debug qw( debug );
  47 use Amanda::Changer;
  48 use Amanda::MainLoop;
  49 use Amanda::Interactivity;
  50 use Amanda::Taper::Scan::traditional;
  51
  52 our $DEFAULT_CHANGER = {};
  53
  54 sub new {
  55     my $class = shift;
  56     my %params = @_;
  57
  58     my $chg = $params{'changer'};
  59     if (!defined $chg) {
  60         $chg = Amanda::Changer->new();
  61         $params{'changer'} = $chg;
  62     }
  63     if (!$chg->have_inventory()) {
  64         return Amanda::Taper::Scan::traditional->new(%params);
  65     }
  66     my $self = Amanda::ScanInventory->new(%params);
  67     return bless ($self, $class);
  68 }
  69
  70 sub most_prefered {
  71     my $self = shift;
  72     return $self->oldest_reusable_volume();
  73 }
  74
  75 sub first_reusable_label {
  76     my $self = shift;
  77
  78     my $label;
  79
  80     for my $tle (@{$self->{'tapelist'}->{'tles'}}) {
  81         $label = $tle->{'label'} if $self->is_reusable_volume(label => $tle->{'label'});
  82     }
  83     return $label;
  84 }
  85
  86 sub last_use_label {
  87     my $self = shift;
  88
  89     my $tles = $self->{'tapelist'}->{tles};
  90     my $label = $tles->[0]->{'label'};
  91 }
  92
  93 sub analyze {
  94     my $self = shift;
  95     my $inventory  = shift;
  96     my $seen  = shift;
  97     my $res = shift;
  98
  99     my $most_prefered;
 100     my @reusable;
 101     my @new_labeled;
 102     my $first_new_volume;
 103     my $new_volume;
 104     my @new_volume;
 105     my $first_unknown;
 106     my $unknown;
 107     my $current;
 108     my $label = $self->most_prefered();
 109     $self->{'most_prefered_label'} = $label;
 110
 111     for my $i (0..(scalar(@$inventory)-1)) {
 112         my $sl = $inventory->[$i];
 113         if ($sl->{current}) {
 114             $current = $sl;
 115         }
 116         next if $seen->{$sl->{slot}} and (!$res || $res->{'this_slot'} ne $sl->{'slot'});
 117
 118         if (!defined $sl->{'state'} ||
 119             $sl->{'state'} == Amanda::Changer::SLOT_UNKNOWN) {
 120             $first_unknown = $sl if !$first_unknown;
 121             $unknown = $sl if $current && !$unknown;
 122         } elsif ($sl->{'state'} == Amanda::Changer::SLOT_EMPTY) {
 123         } elsif (defined $sl->{'label'}) {
 124             if ($label && $sl->{'label'} eq $label) {
 125                 $most_prefered = $sl;
 126             } elsif ($self->is_reusable_volume(label => $sl->{'label'})) {
 127                 push @reusable, $sl;
 128             } else {
 129                 my $vol_tle = $self->{'tapelist'}->lookup_tapelabel($sl->{'label'});
 130                 if ($vol_tle) {
 131                     if ($vol_tle->{'datestamp'} eq '0') {
 132                         push @new_labeled, $sl;
 133                     }
 134                 } elsif ($self->volume_is_labelable($sl)) {
 135                     $first_new_volume = $sl if !$first_new_volume;
 136                     $new_volume = $sl if $current && !$new_volume;
 137                     push @new_volume, $sl;
 138                 }
 139             }
 140         } elsif ($self->volume_is_labelable($sl)) {
 141             $first_new_volume = $sl if !$first_new_volume;
 142             $new_volume = $sl if $current && !$new_volume;
 143             push @new_volume, $sl;
 144         } elsif (!defined($sl->{device_status}) && !defined($sl->{label})) {
 145             $first_unknown = $sl if !$first_unknown;
 146             $unknown = $sl if $current && !$unknown;
 147         } else {
 148         }
 149     }
 150     $unknown = $first_unknown if !defined $unknown;
 151     $new_volume = $first_new_volume if !defined $new_volume;
 152
 153     my $first_label = $self->first_reusable_label();
 154     my $last_label = $self->last_use_label();
 155
 156     my $reusable;
 157     for my $sl (@reusable) {
 158         my $tle = $self->{'tapelist'}->lookup_tapelabel($sl->{'label'});
 159         $sl->{'datestamp'} = $tle->{'datestamp'};
 160         $reusable = $sl if !defined $reusable or
 161                            $sl->{'datestamp'} < $reusable->{'datestamp'};
 162     }
 163
 164     my $new_labeled;
 165     for my $sl (@new_labeled) {
 166         $new_labeled = $sl if !defined $new_labeled or
 167                               (!$last_label and
 168                                $sl->{'label'} lt $new_labeled->{'label'}) or
 169                               ($last_label and
 170                                $sl->{'label'} gt $last_label and
 171                                $sl->{'label'} lt $new_labeled->{'label'}) or
 172                               ($last_label and
 173                                $sl->{'label'} gt $last_label and
 174                                $new_labeled->{'label'} lt $last_label) or
 175                               ($last_label and
 176                                $new_labeled->{'label'} lt $last_label and
 177                                $sl->{'label'} lt $new_labeled->{'label'});
 178     }
 179
 180     for my $sl (@new_volume) {
 181         $sl->{'label'} = $self->{'chg'}->make_new_tape_label(
 182                                         barcode => $sl->{'barcode'},
 183                                         slot => $sl->{'slot'},
 184                                         meta => $sl->{'meta'});
 185         $new_volume = $sl if defined $last_label and
 186                              $new_volume->{'label'} ne $sl->{'label'} and
 187                              (($sl->{'label'} gt $last_label and
 188                                $sl->{'label'} lt $new_volume->{'label'}) or
 189                               ($sl->{'label'} gt $last_label and
 190                                $new_volume->{'label'} lt $last_label) or
 191                               ($new_volume->{'label'} lt $last_label and
 192                                $sl->{'label'} lt $new_volume->{'label'}));
 193     }
 194
 195     my $use;
 196     if ($new_labeled && $self->{'scan_conf'}->{'new_labeled'} eq 'soon') {
 197         $use = $new_labeled;
 198     } elsif ($new_volume && $self->{'scan_conf'}->{'new_volume'} eq 'soon') {
 199         $use = $new_volume;
 200     } elsif ($new_labeled &&
 201               $self->{'scan_conf'}->{'new_labeled'} eq 'order' and
 202               (!$label || !$first_label || !$last_label || !$most_prefered or
 203                ($last_label and $most_prefered and
 204                 $new_labeled->{'label'} gt $last_label and
 205                 $new_labeled->{'label'} lt $most_prefered->{'label'}) or
 206                ($last_label and $most_prefered and
 207                 $new_labeled->{'label'} gt $last_label and
 208                 $most_prefered->{'label'} lt $last_label) or
 209                ($first_label and $most_prefered and
 210                 $new_labeled->{'label'} lt $first_label and
 211                 $new_labeled->{'label'} lt $most_prefered->{'label'}))) {
 212         $use = $new_labeled;
 213     } elsif ($new_volume and
 214              $self->{'scan_conf'}->{'new_volume'} eq 'order' and
 215              (!$label || !$first_label || !$last_label || !$most_prefered or
 216               ($last_label and $most_prefered and
 217                $new_volume->{'label'} gt $last_label and
 218                $new_volume->{'label'} lt $most_prefered->{'label'}) or
 219               ($last_label and $most_prefered and
 220                $new_volume->{'label'} gt $last_label and
 221                $most_prefered->{'label'} lt $last_label) or
 222               ($first_label and $most_prefered and
 223                $new_volume->{'label'} lt $first_label and
 224                $new_volume->{'label'} lt $most_prefered->{'label'}))) {
 225         $use = $new_volume;
 226     } elsif (defined $most_prefered) {
 227         $use = $most_prefered;
 228     } elsif (defined $reusable) {
 229         $use = $reusable;
 230     } elsif ($new_labeled and $self->{'scan_conf'}->{'new_labeled'} eq 'last') {
 231         $use = $new_labeled;
 232     } elsif ($new_volume and $self->{'scan_conf'}->{'new_volume'} eq 'last') {
 233         $use = $new_volume;
 234     }
 235
 236     if ($use) {
 237         if (defined $res and $res->{'this_slot'} eq $use->{'slot'}) {
 238             return (Amanda::ScanInventory::SCAN_DONE);
 239         } else {
 240             return (Amanda::ScanInventory::SCAN_LOAD,
 241                     $use->{'slot'});
 242         }
 243     } elsif ($unknown and $self->{'scan_conf'}->{'scan'}) {
 244         return (Amanda::ScanInventory::SCAN_LOAD,
 245                 $unknown->{'slot'});
 246     } elsif ($self->{'scan_conf'}->{'ask'}) {
 247         return (Amanda::ScanInventory::SCAN_ASK_POLL);
 248     } else {
 249         return (Amanda::ScanInventory::SCAN_FAIL);
 250     }
 251 }
 252
 253 1;