git.gag.com Git - debian/amanda/blob - perl/Amanda/Recovery/Scan.pm

   1 # Copyright (c) 2010 Zmanda, Inc.  All Rights Reserved.
   2 #
   3 # This program is free software; you can redistribute it and/or modify it
   4 # under the terms of the GNU General Public License version 2 as published
   5 # by the Free Software Foundation.
   6 #
   7 # This program is distributed in the hope that it will be useful, but
   8 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
   9 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  10 # for more details.
  11 #
  12 # You should have received a copy of the GNU General Public License along
  13 # with this program; if not, write to the Free Software Foundation, Inc.,
  14 # 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  15 #
  16 # Contact information: Zmanda Inc., 465 S. Mathilda Ave., Suite 300
  17 # Sunnyvale, CA 94085, USA, or: http://www.zmanda.com
  18
  19 package Amanda::Recovery::Scan;
  20
  21 use strict;
  22 use warnings;
  23 use Carp;
  24 use POSIX ();
  25 use Data::Dumper;
  26 use vars qw( @ISA );
  27 use base qw(Exporter);
  28 our @EXPORT_OK = qw($DEFAULT_CHANGER);
  29
  30 use Amanda::Paths;
  31 use Amanda::Util;
  32 use Amanda::Device qw( :constants );
  33 use Amanda::Debug qw( debug );
  34 use Amanda::Changer;
  35 use Amanda::MainLoop;
  36 use Amanda::Interactivity;
  37
  38 use constant SCAN_ASK  => 1;     # call Amanda::Interactivity module
  39 use constant SCAN_POLL => 2;     # wait 'poll_delay' and retry the scan.
  40 use constant SCAN_FAIL => 3;     # abort
  41 use constant SCAN_CONTINUE => 4; # continue to the next step
  42 use constant SCAN_ASK_POLL => 5; # call Amanda::Interactivity module and
  43                                  # poll at the same time.
  44
  45 =head1 NAME
  46
  47 Amanda::Recovery::Scan -- interface to scan algorithm
  48
  49 =head1 SYNOPSIS
  50
  51     use Amanda::Recovey::Scan;
  52
  53     # scan the default changer with no interactivity
  54     my $scan = Amanda::Recovery::Scan->new();
  55     # ..or scan the changer $chg, using $interactivity for interactivity
  56     $scan = Amanda::Recovery::Scan->new(chg => $chg,
  57                                         interactivity => $interactivity);
  58
  59     $scan->find_volume(
  60         label => "TAPE-012",
  61         res_cb => sub {
  62             my ($err, $reservation) = @_;
  63             if ($err) {
  64                 die "$err";
  65             }
  66             $dev = $reservation->{device};
  67             # use device..
  68         });
  69
  70     # later..
  71     $reservation->release(finished_cb => $start_next_volume);
  72
  73     # later..
  74     $scan->quit(); # also quit the changer
  75
  76
  77 =head1 OVERVIEW
  78
  79 This package provides a way for programs that need to read data from volumes
  80 (loosely called "recovery" programs) to find the volumes they need in a
  81 configurable way.  It takes care of prompting for volumes when they are not
  82 available, juggling multiple changers, and any other unpredictabilities.
  83
  84 =head1 INTERFACE
  85
  86 Like L<Amanda::Changer>, this package operates asynchronously, and thus
  87 requires that the caller use L<Amanda::MainLoop> to poll for events.
  88
  89 A new Scan object is created with the C<new> function as follows:
  90
  91   my $scan = Amanda::Recovery::Scan->new(scan_conf     => $scan_conf,
  92                                          chg           => $chg,
  93                                          interactivity => $interactivity);
  94
  95 C<scan_conf> is the configuration for the scan, which at this point should be
  96 omitted, as configuration is not yet supported.  The C<chg> parameter specifies
  97 the changer to start the scan with. The default changer is used if C<chg> is
  98 omitted. The C<interactivity> parameter gives an C<Amanda::Interactivity> object.
  99
 100 =head2 CALLBACKS
 101
 102 Many of the callbacks used by this package are identical to the callbacks of
 103 the same name in L<Amanda::Changer>.
 104
 105 When a callback is called with an error, it is an object of type
 106 C<Amanda::Changer::Error>.  The C<volinuse> reason has a different meaning: it
 107 means that the volume with that label is present in the changer, but is in use
 108 by another program.
 109
 110 =head2 Scan object
 111
 112 =head3 find_volume
 113
 114   $scan->find_volume(label       => $label,
 115                      res_cb      => $res_cb,
 116                      user_msg_fn => $user_msg_fn,
 117                      set_current => 0)
 118
 119 Find the volume labelled C<$label> and call C<$res_cb>.  C<$user_msg_fn> is
 120 used to send progress information, The argumnet it takes are describe in
 121 the next section.  As with the C<load> method
 122 of the changer API, C<set_current> should be set to 1 if you want the scan to
 123 set the current slot.
 124
 125 =head3 quit
 126
 127   $scan->quit()
 128
 129 The cleanly terminate a scan objet, the changer quit is also called.
 130
 131 =head3 user_msg_fn
 132
 133 The user_msg_fn take various arguments
 134
 135 Initiate the scan of the slot $slot:
 136   $self->user_msg_fn(scan_slot => 1,
 137                      slot      => $slot);
 138
 139 Initiate the scan of the slot $slot which should have the label $label:
 140   $self->user_msg_fn(scan_slot => 1,
 141                      slot      => $slot,
 142                      label     => $label);
 143
 144 The result of scanning slot $slot:
 145   $self->user_msg_fn(slot_result => 1,
 146                      slot        => $slot,
 147                      err         => $err,
 148                      res         => $res);
 149
 150 Other options can be added at any time.  The function can ignore them.
 151
 152 =cut
 153
 154 our $DEFAULT_CHANGER = {};
 155
 156 sub new {
 157     my $class = shift;
 158     my %params = @_;
 159     my $scan_conf = $params{'scan_conf'};
 160     my $chg = $params{'chg'};
 161     my $interactivity = $params{'interactivity'};
 162
 163     #until we have a config for it.
 164     $scan_conf = Amanda::Recovery::Scan::Config->new();
 165     $chg = Amanda::Changer->new() if !defined $chg;
 166     return $chg if $chg->isa("Amanda::Changer::Error");
 167
 168     my $self = {
 169         initial_chg   => $chg,
 170         chg           => $chg,
 171         scan_conf     => $scan_conf,
 172         interactivity => $interactivity,
 173     };
 174     return bless ($self, $class);
 175 }
 176
 177 sub DESTROY {
 178     my $self = shift;
 179
 180     die("Recovery::Scan detroyed without quit") if defined $self->{'scan_conf'};
 181 }
 182
 183 sub quit {
 184     my $self = shift;
 185
 186     $self->{'chg'}->quit() if defined $self->{'chg'};
 187
 188     foreach (keys %$self) {
 189         delete $self->{$_};
 190     }
 191
 192 }
 193
 194 sub find_volume {
 195     my $self = shift;
 196     my %params = @_;
 197
 198     my $label = $params{'label'};
 199     my $user_msg_fn = $params{'user_msg_fn'} || \&_user_msg_fn;
 200     my $res;
 201     my %seen = ();
 202     my $inventory;
 203     my $current;
 204     my $new_slot;
 205     my $poll_src;
 206     my $scan_running = 0;
 207     my $interactivity_running = 0;
 208     my $restart_scan = 0;
 209     my $abort_scan = undef;
 210     my $last_err = undef; # keep the last meaningful error, the one reported
 211                           # to the user, most scan end with the notfound error,
 212                           # it's more interesting to report an error from the
 213                           # device or ...
 214     my $slot_scanned;
 215     my $remove_undef_state = 0;
 216     my $load_for_label = 0; # 1 = Try to load the slot with the correct label
 217                             # 0 = Load a slot with an unknown label
 218
 219     my $steps = define_steps
 220         cb_ref => \$params{'res_cb'};
 221
 222     step get_first_inventory => sub {
 223         Amanda::Debug::debug("find_volume labeled '$label'");
 224
 225         $scan_running = 1;
 226         $self->{'chg'}->inventory(inventory_cb => $steps->{'got_first_inventory'});
 227     };
 228
 229     step got_first_inventory => sub {
 230         (my $err, $inventory) = @_;
 231
 232         if ($err && $err->notimpl) {
 233             #inventory not implemented
 234             return $self->_find_volume_no_inventory(%params);
 235         } elsif ($err) {
 236             #inventory fail
 237             return $steps->{'call_res_cb'}->($err, undef);
 238         }
 239
 240         # find current slot and keep a private copy of the value
 241         for my $i (0..(scalar(@$inventory)-1)) {
 242             if ($inventory->[$i]->{current}) {
 243                 $current = $inventory->[$i]->{slot};
 244                 last;
 245             }
 246         }
 247
 248         if (!defined $current) {
 249             if (scalar(@$inventory) == 0) {
 250                 $current = 0;
 251             } else {
 252                 $current = $inventory->[0]->{slot};
 253             }
 254         }
 255
 256         # continue parsing the inventory
 257         $steps->{'parse_inventory'}->($err, $inventory);
 258     };
 259
 260     step restart_scan => sub {
 261         $restart_scan = 0;
 262         return $steps->{'get_inventory'}->();
 263     };
 264
 265     step get_inventory => sub {
 266         $self->{'chg'}->inventory(inventory_cb => $steps->{'parse_inventory'});
 267     };
 268
 269     step parse_inventory => sub {
 270         (my $err, $inventory) = @_;
 271
 272         if ($err && $err->notimpl) {
 273             #inventory not implemented
 274             return $self->_find_volume_no_inventory(%params);
 275         }
 276         return $steps->{'handle_error'}->($err, undef) if $err;
 277
 278         # throw out the inventory result and move on if the situation has
 279         # changed while we were waiting
 280         return $steps->{'abort_scan'}->() if $abort_scan;
 281         return $steps->{'restart_scan'}->() if $restart_scan;
 282
 283         # check if label is in the inventory
 284         for my $i (0..(scalar(@$inventory)-1)) {
 285             my $sl = $inventory->[$i];
 286             if (defined $sl->{'label'} &&
 287                 $sl->{'label'} eq $label) {
 288                 $slot_scanned = $sl->{'slot'};
 289                 if ($sl->{'reserved'}) {
 290                     return $steps->{'handle_error'}->(
 291                             Amanda::Changer::Error->new('failed',
 292                                 reason => 'volinuse',
 293                                 message => "Volume '$label' in slot $slot_scanned is reserved"),
 294                             undef);
 295                 }
 296                 Amanda::Debug::debug("parse_inventory: load slot $slot_scanned with label '$label'");
 297                 $user_msg_fn->(scan_slot => 1,
 298                                slot      => $slot_scanned,
 299                                label     => $label);
 300                 $seen{$slot_scanned} = { device_status => $sl->{'device_status'},
 301                                          f_type        => $sl->{'f_type'},
 302                                          label         => $sl->{'label'} };
 303                 $load_for_label = 1;
 304                 return $self->{'chg'}->load(slot => $slot_scanned,
 305                                   res_cb => $steps->{'slot_loaded'},
 306                                   set_current => $params{'set_current'});
 307             }
 308         }
 309
 310         # Remove from seen all slot that have state == SLOT_UNKNOWN
 311         # It is done when as scan is restarted from interactivity object.
 312         if ($remove_undef_state) {
 313             for my $i (0..(scalar(@$inventory)-1)) {
 314                 my $slot = $inventory->[$i]->{slot};
 315                 if (exists($seen{$slot}) &&
 316                     !defined($inventory->[$i]->{state})) {
 317                     delete $seen{$slot}
 318                 }
 319             }
 320             $remove_undef_state = 0;
 321         }
 322
 323         # remove any slots where the state has changed from the list of seen slots
 324         for my $i (0..(scalar(@$inventory)-1)) {
 325             my $sl = $inventory->[$i];
 326             my $slot = $sl->{slot};
 327             if ($seen{$slot} &&
 328                 defined($sl->{'state'}) &&
 329                 (($seen{$slot}->{'device_status'} != $sl->{'device_status'}) ||
 330                  (defined $seen{$slot}->{'device_status'} &&
 331                   $seen{$slot}->{'device_status'} == $DEVICE_STATUS_SUCCESS &&
 332                   $seen{$slot}->{'f_type'} != $sl->{'f_type'}) ||
 333                  (defined $seen{$slot}->{'device_status'} &&
 334                   $seen{$slot}->{'device_status'} == $DEVICE_STATUS_SUCCESS &&
 335                   defined $seen{$slot}->{'f_type'} &&
 336                   $seen{$slot}->{'f_type'} == $Amanda::Header::F_TAPESTART &&
 337                   $seen{$slot}->{'label'} ne $sl->{'label'}))) {
 338                 delete $seen{$slot};
 339             }
 340         }
 341
 342         # scan any unseen slot already in a drive, if configured to do so
 343         if ($self->{'scan_conf'}->{'scan_drive'}) {
 344             for my $sl (@$inventory) {
 345                 my $slot = $sl->{'slot'};
 346                 if (defined $sl->{'loaded_in'} &&
 347                     !$sl->{'reserved'} &&
 348                     !$seen{$slot}) {
 349                     $slot_scanned = $slot;
 350                     $user_msg_fn->(scan_slot => 1, slot => $slot_scanned);
 351                     $seen{$slot_scanned} = { device_status => $sl->{'device_status'},
 352                                              f_type        => $sl->{'f_type'},
 353                                              label         => $sl->{'label'} };
 354                     $load_for_label = 0;
 355                     return $self->{'chg'}->load(slot => $slot_scanned,
 356                                       res_cb => $steps->{'slot_loaded'},
 357                                       set_current => $params{'set_current'});
 358                 }
 359             }
 360         }
 361
 362         # scan slot
 363         if ($self->{'scan_conf'}->{'scan_unknown_slot'}) {
 364             #find index for current slot
 365             my $current_index = undef;
 366             for my $i (0..(scalar(@$inventory)-1)) {
 367                 my $slot = $inventory->[$i]->{slot};
 368                 if ($slot eq $current) {
 369                     $current_index = $i;
 370                 }
 371             }
 372
 373             #scan next slot to scan
 374             $current_index = 0 if !defined $current_index;
 375             for my $i ($current_index..(scalar(@$inventory)-1), 0..($current_index-1)) {
 376                 my $sl = $inventory->[$i];
 377                 my $slot = $sl->{slot};
 378                 # skip slots we've seen
 379                 next if defined($seen{$slot});
 380                 # skip slots that are empty
 381                 next if defined $sl->{'state'} &&
 382                         $sl->{'state'} == Amanda::Changer::SLOT_EMPTY;
 383                 # skip slots for which we have a known label, since it's not the
 384                 # one we want
 385                 next if defined $sl->{'f_type'} &&
 386                         $sl->{'f_type'} == $Amanda::Header::F_TAPESTART;
 387                 next if defined $sl->{'label'};
 388
 389                 # found a slot to check - reset our current slot
 390                 $current = $slot;
 391                 $slot_scanned = $current;
 392                 Amanda::Debug::debug("parse_inventory: load slot $current");
 393                 $user_msg_fn->(scan_slot => 1, slot => $slot_scanned);
 394                 $seen{$slot_scanned} = { device_status => $sl->{'device_status'},
 395                                          f_type        => $sl->{'f_type'},
 396                                          label         => $sl->{'label'} };
 397                 $load_for_label = 0;
 398                 return $self->{'chg'}->load(slot => $slot_scanned,
 399                                 res_cb => $steps->{'slot_loaded'},
 400                                 set_current => $params{'set_current'});
 401             }
 402         }
 403
 404         #All slots are seen or empty.
 405         if ($last_err) {
 406             return $steps->{'handle_error'}->($last_err, undef);
 407         } else {
 408             return $steps->{'handle_error'}->(
 409                     Amanda::Changer::Error->new('failed',
 410                             reason => 'notfound',
 411                             message => "Volume '$label' not found"),
 412                     undef);
 413         }
 414     };
 415
 416     step slot_loaded => sub {
 417         (my $err, $res) = @_;
 418
 419         # we don't responsd to abort_scan or restart_scan here, since we
 420         # have an open reservation that we should deal with.
 421
 422         $user_msg_fn->(slot_result => 1,
 423                        slot => $slot_scanned,
 424                        err  => $err,
 425                        res  => $res);
 426         if ($res) {
 427             if ($res->{device}->status == $DEVICE_STATUS_SUCCESS &&
 428                 $res->{device}->volume_label &&
 429                 $res->{device}->volume_label eq $label) {
 430                 my $volume_label = $res->{device}->volume_label;
 431                 return $steps->{'call_res_cb'}->(undef, $res);
 432             }
 433             my $f_type;
 434             if (defined $res->{device}->volume_header) {
 435                 $f_type = $res->{device}->volume_header->{type};
 436             } else {
 437                 $f_type = undef;
 438             }
 439
 440             # The slot did not contain the volume we wanted, so mark it
 441             # as seen and try again.
 442             $seen{$slot_scanned} = {
 443                         device_status => $res->{device}->status,
 444                         f_type => $f_type,
 445                         label  => $res->{device}->volume_label
 446             };
 447
 448             # notify the user
 449             if ($res->{device}->status == $DEVICE_STATUS_SUCCESS) {
 450                 $last_err = undef;
 451             } else {
 452                 $last_err = Amanda::Changer::Error->new('fatal',
 453                                 message => $res->{device}->error_or_status());
 454             }
 455             return $res->release(finished_cb => $steps->{'load_released'});
 456         } else {
 457             if ($load_for_label == 0 && $err->volinuse) {
 458                 # Scan semantics for volinuse is different than changer.
 459                 # If a slot with unknown label is loaded then we map
 460                 # volinuse to driveinuse.
 461                 $err->{reason} = "driveinuse";
 462             }
 463             $last_err = $err if $err->fatal || !$err->notfound;
 464             if ($load_for_label == 1 && $err->failed && $err->volinuse) {
 465                 # volinuse is an error
 466                 return $steps->{'handle_error'}->($err, $steps->{'load_released'});
 467             }
 468             return $steps->{'load_released'}->();
 469         }
 470     };
 471
 472     step load_released => sub {
 473         my ($err) = @_;
 474
 475         # TODO: handle error
 476
 477         $res = undef;
 478
 479         # throw out the inventory result and move on if the situation has
 480         # changed while we were loading a volume
 481         return $steps->{'abort_scan'}->() if $abort_scan;
 482         return $steps->{'restart_scan'}->() if $restart_scan;
 483
 484         $new_slot = $current;
 485         $steps->{'get_inventory'}->();
 486     };
 487
 488     step handle_error => sub {
 489         my ($err, $continue_cb) = @_;
 490
 491         my $scan_method = undef;
 492         $scan_running = 0;
 493         my $message;
 494
 495
 496         $poll_src->remove() if defined $poll_src;
 497         $poll_src = undef;
 498
 499         # prefer to use scan method for $last_err, if present
 500         if ($last_err && $err->failed && $err->notfound) {
 501             $message = "$last_err";
 502
 503             if ($last_err->isa("Amanda::Changer::Error")) {
 504                 if ($last_err->fatal) {
 505                     $scan_method = $self->{'scan_conf'}->{'fatal'};
 506                 } else {
 507                     $scan_method = $self->{'scan_conf'}->{$last_err->{'reason'}};
 508                 }
 509             } elsif ($continue_cb) {
 510                 $scan_method = SCAN_CONTINUE;
 511             }
 512         }
 513
 514         #use scan method for $err
 515         if (!defined $scan_method) {
 516             if ($err) {
 517                 $message = "$err" if !defined $message;
 518                 if ($err->fatal) {
 519                     $scan_method = $self->{'scan_conf'}->{'fatal'};
 520                 } else {
 521                     $scan_method = $self->{'scan_conf'}->{$err->{'reason'}};
 522                 }
 523             } else {
 524                 die("error not defined");
 525                 $scan_method = SCAN_ASK_POLL;
 526             }
 527         }
 528
 529         ## implement the desired scan method
 530
 531         if ($scan_method == SCAN_CONTINUE && !defined $continue_cb) {
 532             $scan_method = $self->{'scan_conf'}->{'notfound'};
 533             if ($scan_method == SCAN_CONTINUE) {
 534                 $scan_method = SCAN_FAIL;
 535             }
 536         }
 537
 538         if ($scan_method == SCAN_ASK && !defined $self->{'interactivity'}) {
 539             $scan_method = SCAN_FAIL;
 540         }
 541
 542         if ($scan_method == SCAN_ASK_POLL && !defined $self->{'interactivity'}) {
 543             $scan_method = SCAN_FAIL;
 544         }
 545
 546         if ($scan_method == SCAN_ASK) {
 547             return $steps->{'scan_interactivity'}->("$message");
 548         } elsif ($scan_method == SCAN_POLL) {
 549             $poll_src = Amanda::MainLoop::call_after(
 550                                 $self->{'scan_conf'}->{'poll_delay'},
 551                                 $steps->{'after_poll'});
 552             return;
 553         } elsif ($scan_method == SCAN_ASK_POLL) {
 554             $steps->{'scan_interactivity'}->("$message\n");
 555             $poll_src = Amanda::MainLoop::call_after(
 556                                 $self->{'scan_conf'}->{'poll_delay'},
 557                                 $steps->{'after_poll'});
 558             return;
 559         } elsif ($scan_method == SCAN_FAIL) {
 560             return $steps->{'call_res_cb'}->($err, undef);
 561         } elsif ($scan_method == SCAN_CONTINUE) {
 562             return $continue_cb->($err, undef);
 563         } else {
 564             die("Invalid SCAN_* value:$err:$err->{'reason'}:$scan_method");
 565         }
 566     };
 567
 568     step after_poll => sub {
 569         $poll_src->remove() if defined $poll_src;
 570         $poll_src = undef;
 571         return $steps->{'restart_scan'}->();
 572     };
 573
 574     step scan_interactivity => sub {
 575         my ($err_message) = @_;
 576         if (!$interactivity_running) {
 577             $interactivity_running = 1;
 578             my $message = "$err_message\nInsert volume labeled '$label' in changer and type <enter>\nor type \"^D\" to abort\n";
 579             $self->{'interactivity'}->user_request(
 580                                 message     => $message,
 581                                 label       => $label,
 582                                 err         => "$err_message",
 583                                 chg_name    => $self->{'chg'}->{'chg_name'},
 584                                 request_cb  => $steps->{'scan_interactivity_cb'});
 585         }
 586         return;
 587     };
 588
 589     step scan_interactivity_cb => sub {
 590         my ($err, $message) = @_;
 591         $interactivity_running = 0;
 592         $poll_src->remove() if defined $poll_src;
 593         $poll_src = undef;
 594         $last_err = undef;
 595
 596         if ($err) {
 597             if ($scan_running) {
 598                 $abort_scan = $err;
 599                 return;
 600             } else {
 601                 return $steps->{'call_res_cb'}->($err, undef);
 602             }
 603         }
 604
 605         if ($message ne '') {
 606             # use a new changer
 607             my $new_chg;
 608             if (ref($message) eq 'HASH' and $message == $DEFAULT_CHANGER) {
 609                 $new_chg = Amanda::Changer->new();
 610             } else {
 611                 $new_chg = Amanda::Changer->new($message);
 612             }
 613             if ($new_chg->isa("Amanda::Changer::Error")) {
 614                 return $steps->{'scan_interactivity'}->("$new_chg");
 615             }
 616             $self->{'chg'}->quit();
 617             $self->{'chg'} = $new_chg;
 618             %seen = ();
 619         } else {
 620             $remove_undef_state = 1;
 621         }
 622
 623         if ($scan_running) {
 624             $restart_scan = 1;
 625             return;
 626         } else {
 627             return $steps->{'restart_scan'}->();
 628         }
 629     };
 630
 631     step abort_scan => sub {
 632         $steps->{'call_res_cb'}->($abort_scan, undef);
 633     };
 634
 635     step call_res_cb => sub {
 636         (my $err, $res) = @_;
 637
 638         # TODO: what happens if the search was aborted or
 639         # restarted in the interim?
 640
 641         $abort_scan = undef;
 642         $poll_src->remove() if defined $poll_src;
 643         $poll_src = undef;
 644         $interactivity_running = 0;
 645         $self->{'interactivity'}->abort() if defined $self->{'interactivity'};
 646         $params{'res_cb'}->($err, $res);
 647     };
 648 }
 649
 650 #
 651 sub _find_volume_no_inventory {
 652     my $self = shift;
 653     my %params = @_;
 654
 655     my $label = $params{'label'};
 656     my $res;
 657     my %seen_slots = ();
 658     my $inventory;
 659     my $current;
 660     my $new_slot;
 661     my $last_slot;
 662
 663     my $steps = define_steps
 664         cb_ref => \$params{'res_cb'};
 665
 666     step load_label => sub {
 667         return $self->{'chg'}->load(relative_slot => "current",
 668                                     res_cb => $steps->{'load_label_cb'});
 669     };
 670
 671     step load_label_cb => sub {
 672         (my $err, $res) = @_;
 673
 674         if ($err) {
 675             if ($err->failed && $err->notfound) {
 676                 if ($err->{'message'} eq "all slots have been loaded") {
 677                     $err->{'message'} = "label '$label' not found";
 678                 }
 679                 return $params{'res_cb'}->($err, undef);
 680             } elsif ($err->failed && $err->volinuse and defined $err->{'slot'}) {
 681                 $last_slot = $err->{'slot'};
 682             } else {
 683                 #no interactivity yet.
 684                 return $params{'res_cb'}->($err, undef);
 685             }
 686         } else {
 687             $last_slot = $res->{'this_slot'}
 688         }
 689
 690         $seen_slots{$last_slot} = 1 if defined $last_slot;
 691         if ($res) {
 692             my $dev = $res->{'device'};
 693             if (defined $dev->volume_label && $dev->volume_label eq $label) {
 694                 return $params{'res_cb'}->(undef, $res);
 695             }
 696             return $res->release(finished_cb => $steps->{'released'});
 697         } else {
 698             return $steps->{'released'}->()
 699         }
 700     };
 701
 702     step released => sub {
 703         $self->{'chg'}->load(relative_slot => "next",
 704                    except_slots => \%seen_slots,
 705                    res_cb => $steps->{'load_label_cb'},
 706                    set_current => 1);
 707     };
 708 }
 709
 710 sub _user_msg_fn {
 711     my %params = @_;
 712 }
 713
 714 package Amanda::Recovery::Scan::Config;
 715
 716 sub new {
 717     my $class = shift;
 718     my ($cc) = @_;
 719
 720     my $self = bless {}, $class;
 721
 722     $self->{'scan_drive'} = 0;
 723     $self->{'scan_unknown_slot'} = 1;
 724     $self->{'poll_delay'} = 10000; #10 seconds
 725
 726     $self->{'fatal'} = Amanda::Recovery::Scan::SCAN_CONTINUE;
 727     $self->{'driveinuse'} = Amanda::Recovery::Scan::SCAN_ASK_POLL;
 728     $self->{'volinuse'} = Amanda::Recovery::Scan::SCAN_ASK_POLL;
 729     $self->{'notfound'} = Amanda::Recovery::Scan::SCAN_ASK_POLL;
 730     $self->{'unknown'} = Amanda::Recovery::Scan::SCAN_FAIL;
 731     $self->{'notimpl'} = Amanda::Recovery::Scan::SCAN_FAIL;
 732     $self->{'invalid'} = Amanda::Recovery::Scan::SCAN_CONTINUE;
 733
 734     return $self;
 735 }
 736
 737 1;