git.gag.com Git - debian/amanda/blob - installcheck/Amanda_Changer_single.pl

   1 # Copyright (c) 2008-2012 Zmanda, Inc.  All Rights Reserved.
   2 #
   3 # This program is free software; you can redistribute it and/or
   4 # modify it under the terms of the GNU General Public License
   5 # as published by the Free Software Foundation; either version 2
   6 # of the License, or (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful, but
   9 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  10 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  11 # for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License along
  14 # with this program; if not, write to the Free Software Foundation, Inc.,
  15 # 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  16 #
  17 # Contact information: Zmanda Inc, 465 S. Mathilda Ave., Suite 300
  18 # Sunnyvale, CA 94086, USA, or: http://www.zmanda.com
  19
  20 use Test::More tests => 6;
  21 use File::Path;
  22 use strict;
  23 use warnings;
  24
  25 use lib "@amperldir@";
  26 use Installcheck::Config;
  27 use Installcheck::Changer;
  28 use Amanda::Paths;
  29 use Amanda::Device;
  30 use Amanda::Debug;
  31 use Amanda::MainLoop;
  32 use Amanda::Config qw( :init :getconf config_dir_relative );
  33 use Amanda::Changer;
  34
  35 # set up debugging so debug output doesn't interfere with test results
  36 Amanda::Debug::dbopen("installcheck");
  37 Installcheck::log_test_output();
  38
  39 # and disable Debug's die() and warn() overrides
  40 Amanda::Debug::disable_die_override();
  41
  42 my $testconf = Installcheck::Config->new();
  43 $testconf->write();
  44
  45 my $cfg_result = config_init($CONFIG_INIT_EXPLICIT_NAME, 'TESTCONF');
  46 if ($cfg_result != $CFGERR_OK) {
  47     my ($level, @errors) = Amanda::Config::config_errors();
  48     die(join "\n", @errors);
  49 }
  50
  51 my $chg = Amanda::Changer->new("chg-single:null:/foo");
  52 die "$chg" if $chg->isa("Amanda::Changer::Error");
  53
  54 {
  55     my ($held_res);
  56     my ($get_info, $get_res, $got_res, $got_second_res);
  57
  58     $get_info = make_cb('get_info' => sub {
  59         $chg->info(info_cb => $get_res, info => [ 'num_slots', 'fast_search' ]);
  60     });
  61
  62     $get_res = make_cb('get_res' => sub {
  63         my $err = shift;
  64         my %results = @_;
  65         die($err) if defined($err);
  66
  67         is($results{'num_slots'}, 1, "info() returns the correct num_slots");
  68         is($results{'fast_search'}, 0, "info() returns the correct fast_slots");
  69
  70         $chg->load(relative_slot => "current",
  71                    res_cb => $got_res);
  72     });
  73
  74     $got_res = make_cb('got_res' => sub {
  75         my ($err, $res) = @_;
  76         ok(!$err, "no error loading relative slot 'current'")
  77             or diag($err);
  78         is($res->{'device'}->device_name(), 'null:/foo',
  79             "returns correct device name");
  80
  81         $held_res = $res; # hang onto it while loading another slot
  82
  83         $chg->load(label => "FOO!",
  84                    res_cb => $got_second_res);
  85     });
  86
  87     $got_second_res = make_cb('got_second_res' => sub {
  88         my ($err, $res) = @_;
  89         chg_err_like($err,
  90             { message => qr{'null:/foo' is already reserved},
  91               type => 'failed',
  92               reason => 'volinuse' },
  93             "second simultaneous reservation rejected");
  94
  95         # release the first reservation
  96         $held_res->release(finished_cb => sub {
  97             my ($err) = @_;
  98             die $err if $err;
  99
 100             Amanda::MainLoop::quit();
 101         });
 102     });
 103
 104     # start the loop
 105     $get_info->();
 106     Amanda::MainLoop::run();
 107 }
 108 $chg->quit();
 109
 110 $chg = Amanda::Changer->new("chg-single:bogus:device");
 111 is("$chg",
 112     "chg-single: error opening device 'bogus:device': Device type bogus is not known.",
 113     "bogus device name detected early");
 114 $chg->quit();