git.gag.com Git - debian/amanda/blob - config/macro-archive/docbook-xslt.m4

   1 ##### http://autoconf-archive.cryp.to/ac_check_docbook_xslt.html
   2 #
   3 # SYNOPSIS
   4 #
   5 #   AC_CHECK_DOCBOOK_XSLT([xslt-version])
   6 #
   7 # DESCRIPTION
   8 #
   9 #   Check for access to docbook stylesheets of a particular revision.
  10 #
  11 #   This macro can be used for multiple versions within the same script.
  12 #
  13 #   Input:
  14 #    $1 is the version of docbook to search for; default 'current'
  15 #   Output:
  16 #    $HAVE_DOCBOOK_XSLT_VERS will be set to 'yes' or 'no' depending
  17 #    on the results of the test, where VERS is $1, with '_' substituted
  18 #    for '.'  $HAVE_DOCBOOK_XSLT will also be set to the same value.
  19 #
  20 #   Example:
  21 #    AC_CHECK_DOCBOOK_XSLT(1.72.0)
  22 #    if test "x$HAVE_DOCBOOK_XSLT_1_72_0" = "xyes"; then
  23 #      ..
  24 #
  25 # LAST MODIFICATION
  26 #
  27 #   2007-06-28
  28 #
  29 # AUTHOR
  30 #
  31 #   Dustin J. Mitchell <dustin@zmanda.com>
  32 #
  33 # COPYRIGHT
  34 #
  35 #   Copyright (c) 2007-2012 Zmanda, Inc.  All Rights Reserved.
  36 #
  37 #   This program is free software; you can redistribute it and/or
  38 #   modify it under the terms of the GNU General Public License
  39 #   as published by the Free Software Foundation; either version 2
  40 #   of the License, or (at your option) any later version.
  41 #
  42 #   This program is distributed in the hope that it will be useful, but
  43 #   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  44 #   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  45 #   for more details.
  46 #
  47 #   You should have received a copy of the GNU General Public License along
  48 #   with this program; if not, write to the Free Software Foundation, Inc.,
  49 #   59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  50 #
  51 #   This special exception to the GPL applies to versions of the
  52 #   Autoconf Macro released by the Autoconf Macro Archive. When you
  53 #   make and distribute a modified version of the Autoconf Macro, you
  54 #   may extend this special exception to the GPL to apply to your
  55 #   modified version as well.
  56 #
  57 #   Contact information: Zmanda Inc., 465 S. Mathilda Ave., Suite 300
  58 #   Sunnyvale, CA 94086, USA, or: http://www.zmanda.com
  59
  60 AC_DEFUN([AC_CHECK_DOCBOOK_XSLT],
  61 [
  62     AC_REQUIRE([AC_PROG_XSLTPROC])
  63
  64     dnl define a temporary variable for the version, so this macro can be
  65     dnl used with multiple versions
  66     define([_VERS], $1)
  67     ifelse(_VERS, [], [define([_VERS], [current])])
  68
  69     dnl define variable names ending in _VERS which will actually have the
  70     dnl version number as a suffix
  71     define([ac_cv_docbook_xslt_VERS], patsubst([ac_cv_docbook_xslt_]_VERS, [\.], [_]))
  72     define([HAVE_DOCBOOK_XSLT_VERS], patsubst([HAVE_DOCBOOK_XSLT_]_VERS, [\.], [_]))
  73
  74     AC_CACHE_CHECK([for Docbook XSLT version ]_VERS, [ac_cv_docbook_xslt_VERS],
  75     [
  76         ac_cv_docbook_xslt_VERS=no
  77         if test -n "$XSLTPROC"; then
  78             echo "Trying '$XSLTPROC $XSLTPROC_FLAGS http://docbook.sourceforge.net/release/xsl/_VERS/xhtml/docbook.xsl'" >&AS_MESSAGE_LOG_FD
  79             $XSLTPROC $XSLTPROC_FLAGS http://docbook.sourceforge.net/release/xsl/_VERS/xhtml/docbook.xsl >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD
  80
  81             if test "$?" = 0; then
  82                 ac_cv_docbook_xslt_VERS=yes
  83             fi
  84         fi
  85     ])
  86
  87     HAVE_DOCBOOK_XSLT_VERS="$ac_cv_docbook_xslt_VERS"
  88     HAVE_DOCBOOK_XSLT="$HAVE_DOCBOOK_XSLT_VERS"
  89
  90     dnl clean up m4 namespace
  91     undefine([_VERS])
  92     undefine([ac_cv_docbook_xslt_VERS])
  93     undefine([HAVE_DOCBOOK_XSLT_VERS])
  94 ])