git.gag.com Git - debian/amanda/blob - config/gnulib/wcrtomb.m4

   1 # wcrtomb.m4 serial 6
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCRTOMB],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10
  11   AC_REQUIRE([AC_TYPE_MBSTATE_T])
  12   gl_MBSTATE_T_BROKEN
  13
  14   AC_CHECK_FUNCS_ONCE([wcrtomb])
  15   if test $ac_cv_func_wcrtomb = no; then
  16     HAVE_WCRTOMB=0
  17   else
  18     if test $REPLACE_MBSTATE_T = 1; then
  19       REPLACE_WCRTOMB=1
  20     else
  21       dnl On AIX 4.3, OSF/1 5.1 and Solaris 10, wcrtomb (NULL, 0, NULL) sometimes
  22       dnl returns 0 instead of 1.
  23       AC_REQUIRE([AC_PROG_CC])
  24       AC_REQUIRE([gt_LOCALE_FR])
  25       AC_REQUIRE([gt_LOCALE_FR_UTF8])
  26       AC_REQUIRE([gt_LOCALE_JA])
  27       AC_REQUIRE([gt_LOCALE_ZH_CN])
  28       AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  29       AC_CACHE_CHECK([whether wcrtomb return value is correct],
  30         [gl_cv_func_wcrtomb_retval],
  31         [
  32           dnl Initial guess, used when cross-compiling or when no suitable locale
  33           dnl is present.
  34 changequote(,)dnl
  35           case "$host_os" in
  36                                      # Guess no on AIX 4, OSF/1 and Solaris.
  37             aix4* | osf* | solaris*) gl_cv_func_wcrtomb_retval="guessing no" ;;
  38                                      # Guess yes otherwise.
  39             *)                       gl_cv_func_wcrtomb_retval="guessing yes" ;;
  40           esac
  41 changequote([,])dnl
  42           if test $LOCALE_FR != none || test $LOCALE_FR_UTF8 != none || test $LOCALE_JA != none || test $LOCALE_ZH_CN != none; then
  43             AC_RUN_IFELSE(
  44               [AC_LANG_SOURCE([[
  45 #include <locale.h>
  46 #include <stdio.h>
  47 #include <string.h>
  48 #include <wchar.h>
  49 int main ()
  50 {
  51   if (setlocale (LC_ALL, "$LOCALE_FR") != NULL)
  52     {
  53       if (wcrtomb (NULL, 0, NULL) != 1)
  54         return 1;
  55     }
  56   if (setlocale (LC_ALL, "$LOCALE_FR_UTF8") != NULL)
  57     {
  58       if (wcrtomb (NULL, 0, NULL) != 1)
  59         return 1;
  60     }
  61   if (setlocale (LC_ALL, "$LOCALE_JA") != NULL)
  62     {
  63       if (wcrtomb (NULL, 0, NULL) != 1)
  64         return 1;
  65     }
  66   if (setlocale (LC_ALL, "$LOCALE_ZH_CN") != NULL)
  67     {
  68       if (wcrtomb (NULL, 0, NULL) != 1)
  69         return 1;
  70     }
  71   return 0;
  72 }]])],
  73               [gl_cv_func_wcrtomb_retval=yes],
  74               [gl_cv_func_wcrtomb_retval=no],
  75               [:])
  76           fi
  77         ])
  78       case "$gl_cv_func_wcrtomb_retval" in
  79         *yes) ;;
  80         *) REPLACE_WCRTOMB=1 ;;
  81       esac
  82     fi
  83   fi
  84   if test $HAVE_WCRTOMB = 0 || test $REPLACE_WCRTOMB = 1; then
  85     gl_REPLACE_WCHAR_H
  86     AC_LIBOBJ([wcrtomb])
  87     gl_PREREQ_WCRTOMB
  88   fi
  89 ])
  90
  91 # Prerequisites of lib/wcrtomb.c.
  92 AC_DEFUN([gl_PREREQ_WCRTOMB], [
  93   :
  94 ])