git.gag.com Git - debian/amanda/blob - config/gnulib/regex.m4

   1 # serial 56
   2
   3 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2003, 2004, 2005, 2006,
   4 # 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5 #
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 dnl Initially derived from code in GNU grep.
  11 dnl Mostly written by Jim Meyering.
  12
  13 AC_PREREQ([2.50])
  14
  15 AC_DEFUN([gl_REGEX],
  16 [
  17   AC_CHECK_HEADERS_ONCE([locale.h])
  18
  19   AC_ARG_WITH([included-regex],
  20     [AS_HELP_STRING([--without-included-regex],
  21                     [don't compile regex; this is the default on systems
  22                      with recent-enough versions of the GNU C Library
  23                      (use with caution on other systems).])])
  24
  25   case $with_included_regex in #(
  26   yes|no) ac_use_included_regex=$with_included_regex
  27         ;;
  28   '')
  29     # If the system regex support is good enough that it passes the
  30     # following run test, then default to *not* using the included regex.c.
  31     # If cross compiling, assume the test would fail and use the included
  32     # regex.c.
  33     AC_CACHE_CHECK([for working re_compile_pattern],
  34                    [gl_cv_func_re_compile_pattern_working],
  35       [AC_RUN_IFELSE(
  36         [AC_LANG_PROGRAM(
  37           [AC_INCLUDES_DEFAULT[
  38            #if HAVE_LOCALE_H
  39             #include <locale.h>
  40            #endif
  41            #include <limits.h>
  42            #include <regex.h>
  43            ]],
  44           [[static struct re_pattern_buffer regex;
  45             unsigned char folded_chars[UCHAR_MAX + 1];
  46             int i;
  47             const char *s;
  48             struct re_registers regs;
  49
  50             #if HAVE_LOCALE_H
  51               /* http://sourceware.org/ml/libc-hacker/2006-09/msg00008.html
  52                  This test needs valgrind to catch the bug on Debian
  53                  GNU/Linux 3.1 x86, but it might catch the bug better
  54                  on other platforms and it shouldn't hurt to try the
  55                  test here.  */
  56               if (setlocale (LC_ALL, "en_US.UTF-8"))
  57                 {
  58                   static char const pat[] = "insert into";
  59                   static char const data[] =
  60                     "\xFF\0\x12\xA2\xAA\xC4\xB1,K\x12\xC4\xB1*\xACK";
  61                   re_set_syntax (RE_SYNTAX_GREP | RE_HAT_LISTS_NOT_NEWLINE
  62                                  | RE_ICASE);
  63                   memset (&regex, 0, sizeof regex);
  64                   s = re_compile_pattern (pat, sizeof pat - 1, &regex);
  65                   if (s)
  66                     return 1;
  67                   if (re_search (&regex, data, sizeof data - 1,
  68                                  0, sizeof data - 1, &regs)
  69                       != -1)
  70                     return 1;
  71                   if (! setlocale (LC_ALL, "C"))
  72                     return 1;
  73                 }
  74             #endif
  75
  76             /* This test is from glibc bug 3957, reported by Andrew Mackey.  */
  77             re_set_syntax (RE_SYNTAX_EGREP | RE_HAT_LISTS_NOT_NEWLINE);
  78             memset (&regex, 0, sizeof regex);
  79             s = re_compile_pattern ("a[^x]b", 6, &regex);
  80             if (s)
  81               return 1;
  82
  83             /* This should fail, but succeeds for glibc-2.5.  */
  84             if (re_search (&regex, "a\nb", 3, 0, 3, &regs) != -1)
  85               return 1;
  86
  87             /* This regular expression is from Spencer ere test number 75
  88                in grep-2.3.  */
  89             re_set_syntax (RE_SYNTAX_POSIX_EGREP);
  90             memset (&regex, 0, sizeof regex);
  91             for (i = 0; i <= UCHAR_MAX; i++)
  92               folded_chars[i] = i;
  93             regex.translate = folded_chars;
  94             s = re_compile_pattern ("a[[:@:>@:]]b\n", 11, &regex);
  95             /* This should fail with _Invalid character class name_ error.  */
  96             if (!s)
  97               return 1;
  98
  99             /* Ensure that [b-a] is diagnosed as invalid, when
 100                using RE_NO_EMPTY_RANGES. */
 101             re_set_syntax (RE_SYNTAX_POSIX_EGREP | RE_NO_EMPTY_RANGES);
 102             memset (&regex, 0, sizeof regex);
 103             s = re_compile_pattern ("a[b-a]", 6, &regex);
 104             if (s == 0)
 105               return 1;
 106
 107             /* This should succeed, but does not for glibc-2.1.3.  */
 108             memset (&regex, 0, sizeof regex);
 109             s = re_compile_pattern ("{1", 2, &regex);
 110
 111             if (s)
 112               return 1;
 113
 114             /* The following example is derived from a problem report
 115                against gawk from Jorge Stolfi <stolfi@ic.unicamp.br>.  */
 116             memset (&regex, 0, sizeof regex);
 117             s = re_compile_pattern ("[an\371]*n", 7, &regex);
 118             if (s)
 119               return 1;
 120
 121             /* This should match, but does not for glibc-2.2.1.  */
 122             if (re_match (&regex, "an", 2, 0, &regs) != 2)
 123               return 1;
 124
 125             memset (&regex, 0, sizeof regex);
 126             s = re_compile_pattern ("x", 1, &regex);
 127             if (s)
 128               return 1;
 129
 130             /* glibc-2.2.93 does not work with a negative RANGE argument.  */
 131             if (re_search (&regex, "wxy", 3, 2, -2, &regs) != 1)
 132               return 1;
 133
 134             /* The version of regex.c in older versions of gnulib
 135                ignored RE_ICASE.  Detect that problem too.  */
 136             re_set_syntax (RE_SYNTAX_EMACS | RE_ICASE);
 137             memset (&regex, 0, sizeof regex);
 138             s = re_compile_pattern ("x", 1, &regex);
 139             if (s)
 140               return 1;
 141
 142             if (re_search (&regex, "WXY", 3, 0, 3, &regs) < 0)
 143               return 1;
 144
 145             /* Catch a bug reported by Vin Shelton in
 146                http://lists.gnu.org/archive/html/bug-coreutils/2007-06/msg00089.html
 147                */
 148             re_set_syntax (RE_SYNTAX_POSIX_BASIC
 149                            & ~RE_CONTEXT_INVALID_DUP
 150                            & ~RE_NO_EMPTY_RANGES);
 151             memset (&regex, 0, sizeof regex);
 152             s = re_compile_pattern ("[[:alnum:]_-]\\\\+$", 16, &regex);
 153             if (s)
 154               return 1;
 155
 156             /* REG_STARTEND was added to glibc on 2004-01-15.
 157                Reject older versions.  */
 158             if (! REG_STARTEND)
 159               return 1;
 160
 161             /* Reject hosts whose regoff_t values are too narrow.
 162                These include glibc 2.3.5 on hosts with 64-bit ptrdiff_t
 163                and 32-bit int.  */
 164             if (sizeof (regoff_t) < sizeof (ptrdiff_t)
 165                 || sizeof (regoff_t) < sizeof (ssize_t))
 166               return 1;
 167
 168             return 0;]])],
 169        [gl_cv_func_re_compile_pattern_working=yes],
 170        [gl_cv_func_re_compile_pattern_working=no],
 171        dnl When crosscompiling, assume it is not working.
 172        [gl_cv_func_re_compile_pattern_working=no])])
 173     case $gl_cv_func_re_compile_pattern_working in #(
 174     yes) ac_use_included_regex=no;; #(
 175     no) ac_use_included_regex=yes;;
 176     esac
 177     ;;
 178   *) AC_MSG_ERROR([Invalid value for --with-included-regex: $with_included_regex])
 179     ;;
 180   esac
 181
 182   if test $ac_use_included_regex = yes; then
 183     AC_DEFINE([_REGEX_LARGE_OFFSETS], [1],
 184       [Define if you want regoff_t to be at least as wide POSIX requires.])
 185     AC_DEFINE([re_syntax_options], [rpl_re_syntax_options],
 186       [Define to rpl_re_syntax_options if the replacement should be used.])
 187     AC_DEFINE([re_set_syntax], [rpl_re_set_syntax],
 188       [Define to rpl_re_set_syntax if the replacement should be used.])
 189     AC_DEFINE([re_compile_pattern], [rpl_re_compile_pattern],
 190       [Define to rpl_re_compile_pattern if the replacement should be used.])
 191     AC_DEFINE([re_compile_fastmap], [rpl_re_compile_fastmap],
 192       [Define to rpl_re_compile_fastmap if the replacement should be used.])
 193     AC_DEFINE([re_search], [rpl_re_search],
 194       [Define to rpl_re_search if the replacement should be used.])
 195     AC_DEFINE([re_search_2], [rpl_re_search_2],
 196       [Define to rpl_re_search_2 if the replacement should be used.])
 197     AC_DEFINE([re_match], [rpl_re_match],
 198       [Define to rpl_re_match if the replacement should be used.])
 199     AC_DEFINE([re_match_2], [rpl_re_match_2],
 200       [Define to rpl_re_match_2 if the replacement should be used.])
 201     AC_DEFINE([re_set_registers], [rpl_re_set_registers],
 202       [Define to rpl_re_set_registers if the replacement should be used.])
 203     AC_DEFINE([re_comp], [rpl_re_comp],
 204       [Define to rpl_re_comp if the replacement should be used.])
 205     AC_DEFINE([re_exec], [rpl_re_exec],
 206       [Define to rpl_re_exec if the replacement should be used.])
 207     AC_DEFINE([regcomp], [rpl_regcomp],
 208       [Define to rpl_regcomp if the replacement should be used.])
 209     AC_DEFINE([regexec], [rpl_regexec],
 210       [Define to rpl_regexec if the replacement should be used.])
 211     AC_DEFINE([regerror], [rpl_regerror],
 212       [Define to rpl_regerror if the replacement should be used.])
 213     AC_DEFINE([regfree], [rpl_regfree],
 214       [Define to rpl_regfree if the replacement should be used.])
 215     AC_LIBOBJ([regex])
 216     gl_PREREQ_REGEX
 217   fi
 218 ])
 219
 220 # Prerequisites of lib/regex.c and lib/regex_internal.c.
 221 AC_DEFUN([gl_PREREQ_REGEX],
 222 [
 223   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
 224   AC_REQUIRE([AC_C_INLINE])
 225   AC_REQUIRE([AC_C_RESTRICT])
 226   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 227   AC_CHECK_HEADERS([libintl.h])
 228   AC_CHECK_FUNCS_ONCE([isblank iswctype wcscoll])
 229   AC_CHECK_DECLS([isblank], [], [], [#include <ctype.h>])
 230 ])