git.gag.com Git - debian/amanda/blob - config/gnulib/fcntl-o.m4

   1 # fcntl-o.m4 serial 2
   2 dnl Copyright (C) 2006, 2009-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Paul Eggert.
   8
   9 # Test whether the flags O_NOATIME and O_NOFOLLOW actually work.
  10 # Define HAVE_WORKING_O_NOATIME to 1 if O_NOATIME works, or to 0 otherwise.
  11 # Define HAVE_WORKING_O_NOFOLLOW to 1 if O_NOFOLLOW works, or to 0 otherwise.
  12 AC_DEFUN([gl_FCNTL_O_FLAGS],
  13 [
  14   dnl Persuade glibc <fcntl.h> to define O_NOATIME and O_NOFOLLOW.
  15   dnl AC_USE_SYSTEM_EXTENSIONS was introduced in autoconf 2.60 and obsoletes
  16   dnl AC_GNU_SOURCE.
  17   m4_ifdef([AC_USE_SYSTEM_EXTENSIONS],
  18     [AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])],
  19     [AC_REQUIRE([AC_GNU_SOURCE])])
  20   AC_CACHE_CHECK([for working fcntl.h], [gl_cv_header_working_fcntl_h],
  21     [AC_RUN_IFELSE(
  22        [AC_LANG_PROGRAM(
  23           [[#include <sys/types.h>
  24            #include <sys/stat.h>
  25            #include <unistd.h>
  26            #include <fcntl.h>
  27            #ifndef O_NOATIME
  28             #define O_NOATIME 0
  29            #endif
  30            #ifndef O_NOFOLLOW
  31             #define O_NOFOLLOW 0
  32            #endif
  33            static int const constants[] =
  34             {
  35               O_CREAT, O_EXCL, O_NOCTTY, O_TRUNC, O_APPEND,
  36               O_NONBLOCK, O_SYNC, O_ACCMODE, O_RDONLY, O_RDWR, O_WRONLY
  37             };
  38           ]],
  39           [[
  40             int status = !constants;
  41             {
  42               static char const sym[] = "conftest.sym";
  43               if (symlink (".", sym) != 0
  44                   || close (open (sym, O_RDONLY | O_NOFOLLOW)) == 0)
  45                 status |= 32;
  46               unlink (sym);
  47             }
  48             {
  49               static char const file[] = "confdefs.h";
  50               int fd = open (file, O_RDONLY | O_NOATIME);
  51               char c;
  52               struct stat st0, st1;
  53               if (fd < 0
  54                   || fstat (fd, &st0) != 0
  55                   || sleep (1) != 0
  56                   || read (fd, &c, 1) != 1
  57                   || close (fd) != 0
  58                   || stat (file, &st1) != 0
  59                   || st0.st_atime != st1.st_atime)
  60                 status |= 64;
  61             }
  62             return status;]])],
  63        [gl_cv_header_working_fcntl_h=yes],
  64        [case $? in #(
  65         32) gl_cv_header_working_fcntl_h='no (bad O_NOFOLLOW)';; #(
  66         64) gl_cv_header_working_fcntl_h='no (bad O_NOATIME)';; #(
  67         96) gl_cv_header_working_fcntl_h='no (bad O_NOATIME, O_NOFOLLOW)';; #(
  68          *) gl_cv_header_working_fcntl_h='no';;
  69         esac],
  70        [gl_cv_header_working_fcntl_h=cross-compiling])])
  71
  72   case $gl_cv_header_working_fcntl_h in #(
  73   *O_NOATIME* | no | cross-compiling) ac_val=0;; #(
  74   *) ac_val=1;;
  75   esac
  76   AC_DEFINE_UNQUOTED([HAVE_WORKING_O_NOATIME], [$ac_val],
  77     [Define to 1 if O_NOATIME works.])
  78
  79   case $gl_cv_header_working_fcntl_h in #(
  80   *O_NOFOLLOW* | no | cross-compiling) ac_val=0;; #(
  81   *) ac_val=1;;
  82   esac
  83   AC_DEFINE_UNQUOTED([HAVE_WORKING_O_NOFOLLOW], [$ac_val],
  84     [Define to 1 if O_NOFOLLOW works.])
  85 ])