git.gag.com Git - debian/amanda/blob - config/gnulib/btowc.m4

   1 # btowc.m4 serial 7
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_BTOWC],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10
  11   dnl Check whether <wchar.h> is usable at all, first. Otherwise the test
  12   dnl program below may lead to an endless loop. See
  13   dnl <http://gcc.gnu.org/bugzilla/show_bug.cgi?id=42440>.
  14   AC_REQUIRE([gl_WCHAR_H_INLINE_OK])
  15
  16   AC_CHECK_FUNCS_ONCE([btowc])
  17   if test $ac_cv_func_btowc = no; then
  18     HAVE_BTOWC=0
  19   else
  20
  21     AC_REQUIRE([AC_PROG_CC])
  22     AC_REQUIRE([gt_LOCALE_FR])
  23     AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  24
  25     dnl Cygwin 1.7.2 btowc('\0') is WEOF, not 0.
  26     AC_CACHE_CHECK([whether btowc(0) is correct],
  27       [gl_cv_func_btowc_nul],
  28       [
  29         AC_RUN_IFELSE(
  30           [AC_LANG_SOURCE([[
  31 #include <stdio.h>
  32 #include <string.h>
  33 #include <wchar.h>
  34 int main ()
  35 {
  36   if (btowc ('\0') != 0)
  37     return 1;
  38   return 0;
  39 }]])],
  40           [gl_cv_func_btowc_nul=yes],
  41           [gl_cv_func_btowc_nul=no],
  42           [
  43 changequote(,)dnl
  44            case "$host_os" in
  45                       # Guess no on Cygwin.
  46              cygwin*) gl_cv_func_btowc_nul="guessing no" ;;
  47                       # Guess yes otherwise.
  48              *)       gl_cv_func_btowc_nul="guessing yes" ;;
  49            esac
  50 changequote([,])dnl
  51           ])
  52       ])
  53
  54     dnl IRIX 6.5 btowc(EOF) is 0xFF, not WEOF.
  55     AC_CACHE_CHECK([whether btowc(EOF) is correct],
  56       [gl_cv_func_btowc_eof],
  57       [
  58         dnl Initial guess, used when cross-compiling or when no suitable locale
  59         dnl is present.
  60 changequote(,)dnl
  61         case "$host_os" in
  62                  # Guess no on IRIX.
  63           irix*) gl_cv_func_btowc_eof="guessing no" ;;
  64                  # Guess yes otherwise.
  65           *)     gl_cv_func_btowc_eof="guessing yes" ;;
  66         esac
  67 changequote([,])dnl
  68         if test $LOCALE_FR != none; then
  69           AC_RUN_IFELSE(
  70             [AC_LANG_SOURCE([[
  71 #include <locale.h>
  72 #include <stdio.h>
  73 #include <string.h>
  74 #include <wchar.h>
  75 int main ()
  76 {
  77   if (setlocale (LC_ALL, "$LOCALE_FR") != NULL)
  78     {
  79       if (btowc (EOF) != WEOF)
  80         return 1;
  81     }
  82   return 0;
  83 }]])],
  84             [gl_cv_func_btowc_eof=yes],
  85             [gl_cv_func_btowc_eof=no],
  86             [:])
  87         fi
  88       ])
  89
  90     case "$gl_cv_func_btowc_nul" in
  91       *yes) ;;
  92       *) REPLACE_BTOWC=1 ;;
  93     esac
  94     case "$gl_cv_func_btowc_eof" in
  95       *yes) ;;
  96       *) REPLACE_BTOWC=1 ;;
  97     esac
  98   fi
  99   if test $HAVE_BTOWC = 0 || test $REPLACE_BTOWC = 1; then
 100     gl_REPLACE_WCHAR_H
 101     AC_LIBOBJ([btowc])
 102     gl_PREREQ_BTOWC
 103   fi
 104 ])
 105
 106 # Prerequisites of lib/btowc.c.
 107 AC_DEFUN([gl_PREREQ_BTOWC], [
 108   :
 109 ])