git.gag.com Git - debian/amanda/blob - config/gnulib/alloca.m4

   1 # alloca.m4 serial 9
   2 dnl Copyright (C) 2002-2004, 2006-2007, 2009-2010 Free Software Foundation,
   3 dnl Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_FUNC_ALLOCA],
   9 [
  10   dnl Work around a bug of AC_EGREP_CPP in autoconf-2.57.
  11   AC_REQUIRE([AC_PROG_CPP])
  12   AC_REQUIRE([AC_PROG_EGREP])
  13
  14   AC_REQUIRE([AC_FUNC_ALLOCA])
  15   if test $ac_cv_func_alloca_works = no; then
  16     gl_PREREQ_ALLOCA
  17   fi
  18
  19   # Define an additional variable used in the Makefile substitution.
  20   if test $ac_cv_working_alloca_h = yes; then
  21     AC_CACHE_CHECK([for alloca as a compiler built-in], [gl_cv_rpl_alloca], [
  22       AC_EGREP_CPP([Need own alloca], [
  23 #if defined __GNUC__ || defined _AIX || defined _MSC_VER
  24         Need own alloca
  25 #endif
  26         ], [gl_cv_rpl_alloca=yes], [gl_cv_rpl_alloca=no])
  27     ])
  28     if test $gl_cv_rpl_alloca = yes; then
  29       dnl OK, alloca can be implemented through a compiler built-in.
  30       AC_DEFINE([HAVE_ALLOCA], [1],
  31         [Define to 1 if you have 'alloca' after including <alloca.h>,
  32          a header that may be supplied by this distribution.])
  33       ALLOCA_H=alloca.h
  34     else
  35       dnl alloca exists as a library function, i.e. it is slow and probably
  36       dnl a memory leak. Don't define HAVE_ALLOCA in this case.
  37       ALLOCA_H=
  38     fi
  39   else
  40     ALLOCA_H=alloca.h
  41   fi
  42   AC_SUBST([ALLOCA_H])
  43 ])
  44
  45 # Prerequisites of lib/alloca.c.
  46 # STACK_DIRECTION is already handled by AC_FUNC_ALLOCA.
  47 AC_DEFUN([gl_PREREQ_ALLOCA], [:])